IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 eval q{use Locale::Po4a::Common qw(nowrapi18n !/.*/)};
  14 if ($@) {
  15         print STDERR gettext("warning: Old po4a detected! Recommend upgrade to 0.35.")."\n";
  16         eval q{use Locale::Po4a::Common qw(!/.*/)};
  17         die $@ if $@;
  18 }
  19 use Locale::Po4a::Chooser;
  20 use Locale::Po4a::Po;
  21 use File::Basename;
  22 use File::Copy;
  23 use File::Spec;
  24 use File::Temp;
  25 use Memoize;
  26 use UNIVERSAL;
  27
  28 my %translations;
  29 my @origneedsbuild;
  30 my %origsubs;
  31 my @slavelanguages; # language codes ordered as in config po_slave_languages
  32
  33 memoize("istranslatable");
  34 memoize("_istranslation");
  35 memoize("percenttranslated");
  36
  37 sub import {
  38         hook(type => "getsetup", id => "po", call => \&getsetup);
  39         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  40         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  41         hook(type => "scan", id => "po", call => \&scan, last => 1);
  42         hook(type => "rescan", id => "po", call => \&rescan);
  43         hook(type => "filter", id => "po", call => \&filter);
  44         hook(type => "htmlize", id => "po", call => \&htmlize);
  45         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  46         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  47         hook(type => "delete", id => "po", call => \&mydelete);
  48         hook(type => "change", id => "po", call => \&change);
  49         hook(type => "checkcontent", id => "po", call => \&checkcontent);
  50         hook(type => "canremove", id => "po", call => \&canremove);
  51         hook(type => "canrename", id => "po", call => \&canrename);
  52         hook(type => "editcontent", id => "po", call => \&editcontent);
  53         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  54         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  55
  56         if (! %origsubs) {
  57                 $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  58                 inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  59                 $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  60                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  61                 $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  62                 inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  63                 $origsubs{'urlto'}=\&IkiWiki::urlto;
  64                 inject(name => "IkiWiki::urlto", call => \&myurlto);
  65                 $origsubs{'cgiurl'}=\&IkiWiki::cgiurl;
  66                 inject(name => "IkiWiki::cgiurl", call => \&mycgiurl);
  67                 $origsubs{'rootpage'}=\&IkiWiki::rootpage;
  68                 inject(name => "IkiWiki::rootpage", call => \&myrootpage);
  69                 $origsubs{'isselflink'}=\&IkiWiki::isselflink;
  70                 inject(name => "IkiWiki::isselflink", call => \&myisselflink);
  71         }
  72 }
  73
  74
  75 # ,----
  76 # | Table of contents
  77 # `----
  78
  79 # 1. Hooks
  80 # 2. Injected functions
  81 # 3. Blackboxes for private data
  82 # 4. Helper functions
  83 # 5. PageSpecs
  84
  85
  86 # ,----
  87 # | Hooks
  88 # `----
  89
  90 sub getsetup () {
  91         return
  92                 plugin => {
  93                         safe => 0,
  94                         rebuild => 1, # format plugin
  95                         section => "format",
  96                 },
  97                 po_master_language => {
  98                         type => "string",
  99                         example => {
 100                                 'code' => 'en',
 101                                 'name' => 'English'
 102                         },
 103                         description => "master language (non-PO files)",
 104                         safe => 1,
 105                         rebuild => 1,
 106                 },
 107                 po_slave_languages => {
 108                         type => "string",
 109                         example => [
 110                                 'fr|Français',
 111                                 'es|Español',
 112                                 'de|Deutsch'
 113                         ],
 114                         description => "slave languages (PO files)",
 115                         safe => 1,
 116                         rebuild => 1,
 117                 },
 118                 po_translatable_pages => {
 119                         type => "pagespec",
 120                         example => "* and !*/Discussion",
 121                         description => "PageSpec controlling which pages are translatable",
 122                         link => "ikiwiki/PageSpec",
 123                         safe => 1,
 124                         rebuild => 1,
 125                 },
 126                 po_link_to => {
 127                         type => "string",
 128                         example => "current",
 129                         description => "internal linking behavior (default/current/negotiated)",
 130                         safe => 1,
 131                         rebuild => 1,
 132                 },
 133 }
 134
 135 sub checkconfig () {
 136         foreach my $field (qw{po_master_language}) {
 137                 if (! exists $config{$field} || ! defined $config{$field}) {
 138                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 139                                       $field, 'po'));
 140                 }
 141         }
 142
 143         if (ref $config{po_slave_languages} eq 'ARRAY') {
 144                 my %slaves;
 145                 foreach my $pair (@{$config{po_slave_languages}}) {
 146                         my ($code, $name) = ( $pair =~ /^([a-z]{2})\|(.+)$/ );
 147                         if (!defined $code || !defined $name) {
 148                                 error(sprintf(gettext("%s has invalid syntax: must use CODE|NAME"),
 149                                               $pair));
 150                         }
 151                         $slaves{$code} = $name;
 152                         push @slavelanguages, $code;
 153
 154                 }
 155                 $config{po_slave_languages} = \%slaves;
 156         }
 157         elsif (ref $config{po_slave_languages} eq 'HASH') {
 158                 @slavelanguages = sort {
 159                         $config{po_slave_languages}->{$a} cmp $config{po_slave_languages}->{$b};
 160                 } keys %{$config{po_slave_languages}};
 161         }
 162
 163         delete $config{po_slave_languages}{$config{po_master_language}{code}};;
 164
 165         map {
 166                 islanguagecode($_)
 167                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 168         } ($config{po_master_language}{code}, @slavelanguages);
 169
 170         if (! exists $config{po_translatable_pages} ||
 171             ! defined $config{po_translatable_pages}) {
 172                 $config{po_translatable_pages}="";
 173         }
 174         if (! exists $config{po_link_to} ||
 175             ! defined $config{po_link_to}) {
 176                 $config{po_link_to}='default';
 177         }
 178         elsif ($config{po_link_to} !~ /^(default|current|negotiated)$/) {
 179                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 180                              $config{po_link_to}));
 181                 $config{po_link_to}='default';
 182         }
 183         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 184                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 185                 $config{po_link_to}='default';
 186         }
 187
 188         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 189
 190         # Translated versions of the underlays are added if available.
 191         foreach my $underlay ("basewiki",
 192                               map { m/^\Q$config{underlaydirbase}\E\/*(.*)/ }
 193                                   reverse @{$config{underlaydirs}}) {
 194                 next if $underlay=~/^locale\//;
 195
 196                 # Underlays containing the po files for slave languages.
 197                 foreach my $ll (@slavelanguages) {
 198                         add_underlay("po/$ll/$underlay")
 199                                 if -d "$config{underlaydirbase}/po/$ll/$underlay";
 200                 }
 201
 202                 if ($config{po_master_language}{code} ne 'en') {
 203                         # Add underlay containing translated source files
 204                         # for the master language.
 205                         add_underlay("locale/$config{po_master_language}{code}/$underlay")
 206                                 if -d "$config{underlaydirbase}/locale/$config{po_master_language}{code}/$underlay";
 207                 }
 208         }
 209 }
 210
 211 sub needsbuild () {
 212         my $needsbuild=shift;
 213
 214         # backup @needsbuild content so that change() can know whether
 215         # a given master page was rendered because its source file was changed
 216         @origneedsbuild=(@$needsbuild);
 217
 218         flushmemoizecache();
 219         buildtranslationscache();
 220
 221         # make existing translations depend on the corresponding master page
 222         foreach my $master (keys %translations) {
 223                 map add_depends($_, $master), values %{otherlanguages_pages($master)};
 224         }
 225 }
 226
 227 # Massage the recorded state of internal links so that:
 228 # - it matches the actually generated links, rather than the links as written
 229 #   in the pages' source
 230 # - backlinks are consistent in all cases
 231 sub scan (@) {
 232         my %params=@_;
 233         my $page=$params{page};
 234         my $content=$params{content};
 235
 236         if (istranslation($page)) {
 237                 # replace the occurence of $destpage in $links{$page}
 238                 my @orig_links = @{$links{$page}};
 239                 $links{$page} = [];
 240                 foreach my $destpage (@orig_links) {
 241                         if (istranslatedto($destpage, lang($page))) {
 242                                 add_link($page, $destpage . '.' . lang($page));
 243                         }
 244                         else {
 245                                 add_link($page, $destpage);
 246                         }
 247                 }
 248         }
 249         elsif (! istranslatable($page) && ! istranslation($page)) {
 250                 foreach my $destpage (@{$links{$page}}) {
 251                         if (istranslatable($destpage)) {
 252                                 # make sure any destpage's translations has
 253                                 # $page in its backlinks
 254                                 foreach my $link (values %{otherlanguages_pages($destpage)}) {
 255                                         add_link($page, $link);
 256                                 }
 257                         }
 258                 }
 259         }
 260 }
 261
 262 # We use filter to convert PO to the master page's format,
 263 # since the rest of ikiwiki should not work on PO files.
 264 sub filter (@) {
 265         my %params = @_;
 266
 267         my $page = $params{page};
 268         my $destpage = $params{destpage};
 269         my $content = $params{content};
 270         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 271                 $content = po_to_markup($page, $content);
 272                 setalreadyfiltered($page, $destpage);
 273         }
 274         return $content;
 275 }
 276
 277 # re-run the scan hooks and run the preprocess ones in scan
 278 # mode on the po-to-markup converted content
 279 sub rescan (@) {
 280         my %params=@_;
 281         my $page=$params{page};
 282         my $content=$params{content};
 283
 284         return unless istranslation($page);
 285
 286         $content = po_to_markup($page, $content);
 287         require IkiWiki;
 288         IkiWiki::run_hooks(scan => sub {
 289                 shift->(
 290                         page => $page,
 291                         content => $content,
 292                 );
 293         });
 294         IkiWiki::preprocess($page, $page, $content, 1);
 295 }
 296
 297 sub htmlize (@) {
 298         my %params=@_;
 299
 300         my $page = $params{page};
 301         my $content = $params{content};
 302
 303         # ignore PO files this plugin did not create
 304         return $content unless istranslation($page);
 305
 306         # force content to be htmlize'd as if it was the same type as the master page
 307         return IkiWiki::htmlize($page, $page,
 308                 pagetype(srcfile($pagesources{masterpage($page)})),
 309                 $content);
 310 }
 311
 312 sub pagetemplate (@) {
 313         my %params=@_;
 314         my $page=$params{page};
 315         my $destpage=$params{destpage};
 316         my $template=$params{template};
 317
 318         my ($masterpage, $lang) = istranslation($page);
 319
 320         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 321                 $template->param(percenttranslated => percenttranslated($page));
 322         }
 323         if ($template->query(name => "istranslation")) {
 324                 $template->param(istranslation => scalar istranslation($page));
 325         }
 326         if ($template->query(name => "istranslatable")) {
 327                 $template->param(istranslatable => istranslatable($page));
 328         }
 329         if ($template->query(name => "HOMEPAGEURL")) {
 330                 $template->param(homepageurl => homepageurl($page));
 331         }
 332         if ($template->query(name => "otherlanguages")) {
 333                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 334                 map add_depends($page, $_), (values %{otherlanguages_pages($page)});
 335         }
 336         if ($config{discussion} && istranslation($page)) {
 337                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 338                    (length $config{cgiurl} ||
 339                     exists $links{$masterpage."/".lc($config{discussionpage})})) {
 340                         $template->param('discussionlink' => htmllink(
 341                                 $page,
 342                                 $destpage,
 343                                 $masterpage . '/' . $config{discussionpage},
 344                                 noimageinline => 1,
 345                                 forcesubpage => 0,
 346                                 linktext => $config{discussionpage},
 347                 ));
 348                 }
 349         }
 350         # Remove broken parentlink to ./index.html on home page's translations.
 351         # It works because this hook has the "last" parameter set, to ensure it
 352         # runs after parentlinks' own pagetemplate hook.
 353         if ($template->param('parentlinks')
 354             && istranslation($page)
 355             && $masterpage eq "index") {
 356                 $template->param('parentlinks' => []);
 357         }
 358         if (ishomepage($page) && $template->query(name => "title")) {
 359                 $template->param(title => $config{wikiname});
 360         }
 361 }
 362
 363 # Add the renamed page translations to the list of to-be-renamed pages.
 364 sub renamepages (@) {
 365         my %params = @_;
 366
 367         my %torename = %{$params{torename}};
 368         my $session = $params{session};
 369
 370         # Save the page(s) the user asked to rename, so that our
 371         # canrename hook can tell the difference between:
 372         #  - a translation being renamed as a consequence of its master page
 373         #    being renamed
 374         #  - a user trying to directly rename a translation
 375         # This is why this hook has to be run first, before the list of pages
 376         # to rename is modified by other plugins.
 377         my @orig_torename;
 378         @orig_torename=@{$session->param("po_orig_torename")}
 379                 if defined $session->param("po_orig_torename");
 380         push @orig_torename, $torename{src};
 381         $session->param(po_orig_torename => \@orig_torename);
 382         IkiWiki::cgi_savesession($session);
 383
 384         return () unless istranslatable($torename{src});
 385
 386         my @ret;
 387         my %otherpages=%{otherlanguages_pages($torename{src})};
 388         while (my ($lang, $otherpage) = each %otherpages) {
 389                 push @ret, {
 390                         src => $otherpage,
 391                         srcfile => $pagesources{$otherpage},
 392                         dest => otherlanguage_page($torename{dest}, $lang),
 393                         destfile => $torename{dest}.".".$lang.".po",
 394                         required => 0,
 395                 };
 396         }
 397         return @ret;
 398 }
 399
 400 sub mydelete (@) {
 401         my @deleted=@_;
 402
 403         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 404 }
 405
 406 sub change (@) {
 407         my @rendered=@_;
 408
 409         my $updated_po_files=0;
 410
 411         # Refresh/create POT and PO files as needed.
 412         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 413                 my $masterfile=srcfile($file);
 414                 my $page=pagename($file);
 415                 my $updated_pot_file=0;
 416
 417                 # Avoid touching underlay files.
 418                 next if $masterfile ne "$config{srcdir}/$file";
 419
 420                 # Only refresh POT file if it does not exist, or if
 421                 # the source was changed: don't if only the HTML was
 422                 # refreshed, e.g. because of a dependency.
 423                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild) ||
 424                     ! -e potfile($masterfile)) {
 425                         refreshpot($masterfile);
 426                         $updated_pot_file=1;
 427                 }
 428                 my @pofiles;
 429                 foreach my $po (pofiles($masterfile)) {
 430                         next if ! $updated_pot_file && -e $po;
 431                         next if grep { $po=~/\Q$_\E/ } @{$config{underlaydirs}};
 432                         push @pofiles, $po;
 433                 }
 434                 if (@pofiles) {
 435                         refreshpofiles($masterfile, @pofiles);
 436                         map { s/^\Q$config{srcdir}\E\/*//; IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 437                         $updated_po_files=1;
 438                 }
 439         }
 440
 441         if ($updated_po_files) {
 442                 commit_and_refresh(
 443                         gettext("updated PO files"));
 444         }
 445 }
 446
 447 sub checkcontent (@) {
 448         my %params=@_;
 449
 450         if (istranslation($params{page})) {
 451                 my $res = isvalidpo($params{content});
 452                 if ($res) {
 453                         return undef;
 454                 }
 455                 else {
 456                         return "$res";
 457                 }
 458         }
 459         return undef;
 460 }
 461
 462 sub canremove (@) {
 463         my %params = @_;
 464
 465         if (istranslation($params{page})) {
 466                 return gettext("Can not remove a translation. If the master page is removed, ".
 467                                "however, its translations will be removed as well.");
 468         }
 469         return undef;
 470 }
 471
 472 sub canrename (@) {
 473         my %params = @_;
 474         my $session = $params{session};
 475
 476         if (istranslation($params{src})) {
 477                 my $masterpage = masterpage($params{src});
 478                 # Tell the difference between:
 479                 #  - a translation being renamed as a consequence of its master page
 480                 #    being renamed, which is allowed
 481                 #  - a user trying to directly rename a translation, which is forbidden
 482                 # by looking for the master page in the list of to-be-renamed pages we
 483                 # saved early in the renaming process.
 484                 my $orig_torename = $session->param("po_orig_torename");
 485                 unless (grep { $_ eq $masterpage } @{$orig_torename}) {
 486                         return gettext("Can not rename a translation. If the master page is renamed, ".
 487                                        "however, its translations will be renamed as well.");
 488                 }
 489         }
 490         return undef;
 491 }
 492
 493 # As we're previewing or saving a page, the content may have
 494 # changed, so tell the next filter() invocation it must not be lazy.
 495 sub editcontent () {
 496         my %params=@_;
 497
 498         unsetalreadyfiltered($params{page}, $params{page});
 499         return $params{content};
 500 }
 501
 502 sub formbuilder_setup (@) {
 503         my %params=@_;
 504         my $form=$params{form};
 505         my $q=$params{cgi};
 506
 507         return unless defined $form->field("do");
 508
 509         if ($form->field("do") eq "create") {
 510                 # Warn the user: new pages must be written in master language.
 511                 my $template=template("pocreatepage.tmpl");
 512                 $template->param(LANG => $config{po_master_language}{name});
 513                 $form->tmpl_param(message => $template->output);
 514         }
 515         elsif ($form->field("do") eq "edit") {
 516                 # Remove the rename/remove buttons on slave pages.
 517                 # This has to be done after the rename/remove plugins have added
 518                 # their buttons, which is why this hook must be run last.
 519                 # The canrename/canremove hooks already ensure this is forbidden
 520                 # at the backend level, so this is only UI sugar.
 521                 if (istranslation($form->field("page"))) {
 522                         map {
 523                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 524                                         if (@{$params{buttons}}[$i] eq $_) {
 525                                                 delete  @{$params{buttons}}[$i];
 526                                                 last;
 527                                         }
 528                                 }
 529                         } qw(Rename Remove);
 530                 }
 531         }
 532 }
 533
 534 sub formbuilder (@) {
 535         my %params=@_;
 536         my $form=$params{form};
 537         my $q=$params{cgi};
 538
 539         return unless defined $form->field("do");
 540
 541         # Do not allow to create pages of type po: they are automatically created.
 542         # The main reason to do so is to bypass the "favor the type of linking page
 543         # on page creation" logic, which is unsuitable when a broken link is clicked
 544         # on a slave (PO) page.
 545         # This cannot be done in the formbuilder_setup hook as the list of types is
 546         # computed later.
 547         if ($form->field("do") eq "create") {
 548                 foreach my $field ($form->field) {
 549                         next unless "$field" eq "type";
 550                         next unless $field->type eq 'select';
 551                         my $orig_value = $field->value;
 552                         # remove po from the list of types
 553                         my @types = grep { $_->[0] ne 'po' } $field->options;
 554                         $field->options(\@types) if @types;
 555                         # favor the type of linking page's masterpage
 556                         if ($orig_value eq 'po') {
 557                                 my ($from, $type);
 558                                 if (defined $form->field('from')) {
 559                                         ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 560                                         $from = masterpage($from);
 561                                 }
 562                                 if (defined $from && exists $pagesources{$from}) {
 563                                         $type=pagetype($pagesources{$from});
 564                                 }
 565                                 $type=$config{default_pageext} unless defined $type;
 566                                 $field->value($type) ;
 567                         }
 568                 }
 569         }
 570 }
 571
 572 # ,----
 573 # | Injected functions
 574 # `----
 575
 576 # Implement po_link_to 'current' and 'negotiated' settings.
 577 sub mybestlink ($$) {
 578         my $page=shift;
 579         my $link=shift;
 580
 581         return $origsubs{'bestlink'}->($page, $link)
 582                 if defined $config{po_link_to} && $config{po_link_to} eq "default";
 583
 584         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 585         my @caller = caller(1);
 586         if (length $res
 587             && istranslatedto($res, lang($page))
 588             && istranslation($page)
 589             &&  !(exists $caller[3] && defined $caller[3]
 590                   && ($caller[3] eq "IkiWiki::PageSpec::match_link"))) {
 591                 return $res . "." . lang($page);
 592         }
 593         return $res;
 594 }
 595
 596 sub mybeautify_urlpath ($) {
 597         my $url=shift;
 598
 599         my $res=$origsubs{'beautify_urlpath'}->($url);
 600         if (defined $config{po_link_to} && $config{po_link_to} eq "negotiated") {
 601                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 602                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 603                 map {
 604                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 605                 } @slavelanguages;
 606         }
 607         return $res;
 608 }
 609
 610 sub mytargetpage ($$) {
 611         my $page=shift;
 612         my $ext=shift;
 613
 614         if (istranslation($page) || istranslatable($page)) {
 615                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 616                 if (! $config{usedirs} || $masterpage eq 'index') {
 617                         return $masterpage . "." . $lang . "." . $ext;
 618                 }
 619                 else {
 620                         return $masterpage . "/index." . $lang . "." . $ext;
 621                 }
 622         }
 623         return $origsubs{'targetpage'}->($page, $ext);
 624 }
 625
 626 sub myurlto ($$;$) {
 627         my $to=shift;
 628         my $from=shift;
 629         my $absolute=shift;
 630
 631         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 632         if (! length $to
 633             && $config{po_link_to} eq "current"
 634             && istranslatable('index')) {
 635                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 636         }
 637         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 638         # so that one is redirected to the just-edited page rather than to the
 639         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 640         # we only do so when our beautify_urlpath would actually do what we want to
 641         # avoid, i.e. when po_link_to = negotiated.
 642         # also avoid doing so when run by cgi_goto, so that the links on recentchanges
 643         # page actually lead to the exact page they pretend to.
 644         if ($config{po_link_to} eq "negotiated") {
 645                 my @caller = caller(1);
 646                 my $use_orig = 0;
 647                 $use_orig = 1 if (exists $caller[3] && defined $caller[3]
 648                                  && ($caller[3] eq "IkiWiki::cgi_editpage" ||
 649                                      $caller[3] eq "IkiWiki::Plugin::goto::cgi_goto")
 650                                  );
 651                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 652                         if $use_orig;
 653                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 654                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 655                         if $use_orig;
 656                 return $res;
 657         }
 658         else {
 659                 return $origsubs{'urlto'}->($to,$from,$absolute)
 660         }
 661 }
 662
 663 sub mycgiurl (@) {
 664         my %params=@_;
 665
 666         # slave pages have no subpages
 667         if (istranslation($params{'from'})) {
 668                 $params{'from'} = masterpage($params{'from'});
 669         }
 670         return $origsubs{'cgiurl'}->(%params);
 671 }
 672
 673 sub myrootpage (@) {
 674         my %params=@_;
 675
 676         my $rootpage;
 677         if (exists $params{rootpage}) {
 678                 $rootpage=$origsubs{'bestlink'}->($params{page}, $params{rootpage});
 679                 if (!length $rootpage) {
 680                         $rootpage=$params{rootpage};
 681                 }
 682         }
 683         else {
 684                 $rootpage=masterpage($params{page});
 685         }
 686         return $rootpage;
 687 }
 688
 689 sub myisselflink ($$) {
 690         my $page=shift;
 691         my $link=shift;
 692
 693         return 1 if $origsubs{'isselflink'}->($page, $link);
 694         if (istranslation($page)) {
 695                 return $origsubs{'isselflink'}->(masterpage($page), $link);
 696         }
 697         return;
 698 }
 699
 700 # ,----
 701 # | Blackboxes for private data
 702 # `----
 703
 704 {
 705         my %filtered;
 706
 707         sub alreadyfiltered($$) {
 708                 my $page=shift;
 709                 my $destpage=shift;
 710
 711                 return exists $filtered{$page}{$destpage}
 712                          && $filtered{$page}{$destpage} eq 1;
 713         }
 714
 715         sub setalreadyfiltered($$) {
 716                 my $page=shift;
 717                 my $destpage=shift;
 718
 719                 $filtered{$page}{$destpage}=1;
 720         }
 721
 722         sub unsetalreadyfiltered($$) {
 723                 my $page=shift;
 724                 my $destpage=shift;
 725
 726                 if (exists $filtered{$page}{$destpage}) {
 727                         delete $filtered{$page}{$destpage};
 728                 }
 729         }
 730
 731         sub resetalreadyfiltered() {
 732                 undef %filtered;
 733         }
 734 }
 735
 736 # ,----
 737 # | Helper functions
 738 # `----
 739
 740 sub maybe_add_leading_slash ($;$) {
 741         my $str=shift;
 742         my $add=shift;
 743         $add=1 unless defined $add;
 744         return '/' . $str if $add;
 745         return $str;
 746 }
 747
 748 sub istranslatablefile ($) {
 749         my $file=shift;
 750
 751         return 0 unless defined $file;
 752         my $type=pagetype($file);
 753         return 0 if ! defined $type || $type eq 'po';
 754         return 0 if $file =~ /\.pot$/;
 755         return 0 if ! defined $config{po_translatable_pages};
 756         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 757         return;
 758 }
 759
 760 sub istranslatable ($) {
 761         my $page=shift;
 762
 763         $page=~s#^/##;
 764         return 1 if istranslatablefile($pagesources{$page});
 765         return;
 766 }
 767
 768 sub istranslatedto ($$) {
 769         my $page=shift;
 770         my $destlang = shift;
 771
 772         $page=~s#^/##;
 773         return 0 unless istranslatable($page);
 774         exists $pagesources{otherlanguage_page($page, $destlang)};
 775 }
 776
 777 sub _istranslation ($) {
 778         my $page=shift;
 779
 780         $page='' unless defined $page && length $page;
 781         my $hasleadingslash = ($page=~s#^/##);
 782         my $file=$pagesources{$page};
 783         return 0 unless defined $file
 784                          && defined pagetype($file)
 785                          && pagetype($file) eq 'po';
 786         return 0 if $file =~ /\.pot$/;
 787
 788         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 789         return 0 unless defined $masterpage && defined $lang
 790                          && length $masterpage && length $lang
 791                          && defined $pagesources{$masterpage}
 792                          && defined $config{po_slave_languages}{$lang};
 793
 794         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 795                 if istranslatable($masterpage);
 796 }
 797
 798 sub istranslation ($) {
 799         my $page=shift;
 800
 801         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 802                 my $hasleadingslash = ($masterpage=~s#^/##);
 803                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 804                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 805         }
 806         return "";
 807 }
 808
 809 sub masterpage ($) {
 810         my $page=shift;
 811
 812         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 813                 return $masterpage;
 814         }
 815         return $page;
 816 }
 817
 818 sub lang ($) {
 819         my $page=shift;
 820
 821         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 822                 return $lang;
 823         }
 824         return $config{po_master_language}{code};
 825 }
 826
 827 sub islanguagecode ($) {
 828         my $code=shift;
 829
 830         return $code =~ /^[a-z]{2}$/;
 831 }
 832
 833 sub otherlanguage_page ($$) {
 834         my $page=shift;
 835         my $code=shift;
 836
 837         return masterpage($page) if $code eq $config{po_master_language}{code};
 838         return masterpage($page) . '.' . $code;
 839 }
 840
 841 # Returns the list of other languages codes: the master language comes first,
 842 # then the codes are ordered the same way as in po_slave_languages, if it is
 843 # an array, or in the language name lexical order, if it is a hash.
 844 sub otherlanguages_codes ($) {
 845         my $page=shift;
 846
 847         my @ret;
 848         return \@ret unless istranslation($page) || istranslatable($page);
 849         my $curlang=lang($page);
 850         foreach my $lang
 851                 ($config{po_master_language}{code}, @slavelanguages) {
 852                 next if $lang eq $curlang;
 853                 if ($lang eq $config{po_master_language}{code} ||
 854                     istranslatedto(masterpage($page), $lang)) {
 855                         push @ret, $lang;
 856                 }
 857         }
 858         return \@ret;
 859 }
 860
 861 sub otherlanguages_pages ($) {
 862         my $page=shift;
 863
 864         my %ret;
 865         map {
 866                 $ret{$_} = otherlanguage_page($page, $_)
 867         } @{otherlanguages_codes($page)};
 868
 869         return \%ret;
 870 }
 871
 872 sub potfile ($) {
 873         my $masterfile=shift;
 874
 875         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 876         $dir='' if $dir eq './';
 877         return File::Spec->catpath('', $dir, $name . ".pot");
 878 }
 879
 880 sub pofile ($$) {
 881         my $masterfile=shift;
 882         my $lang=shift;
 883
 884         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 885         $dir='' if $dir eq './';
 886         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 887 }
 888
 889 sub pofiles ($) {
 890         my $masterfile=shift;
 891
 892         return map pofile($masterfile, $_), @slavelanguages;
 893 }
 894
 895 sub refreshpot ($) {
 896         my $masterfile=shift;
 897
 898         my $potfile=potfile($masterfile);
 899         my $doc=Locale::Po4a::Chooser::new(po4a_type($masterfile),
 900                                            po4a_options($masterfile));
 901         $doc->{TT}{utf_mode} = 1;
 902         $doc->{TT}{file_in_charset} = 'UTF-8';
 903         $doc->{TT}{file_out_charset} = 'UTF-8';
 904         $doc->read($masterfile);
 905         # let's cheat a bit to force porefs option to be passed to
 906         # Locale::Po4a::Po; this is undocument use of internal
 907         # Locale::Po4a::TransTractor's data, compulsory since this module
 908         # prevents us from using the porefs option.
 909         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 910         $doc->{TT}{po_out}->set_charset('UTF-8');
 911         # do the actual work
 912         $doc->parse;
 913         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 914         $doc->writepo($potfile);
 915 }
 916
 917 sub refreshpofiles ($@) {
 918         my $masterfile=shift;
 919         my @pofiles=@_;
 920
 921         my $potfile=potfile($masterfile);
 922         if (! -e $potfile) {
 923                 error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"), $potfile));
 924         }
 925
 926         foreach my $pofile (@pofiles) {
 927                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 928
 929                 if (! -e $pofile) {
 930                         # If the po file exists in an underlay, copy it
 931                         # from there.
 932                         my ($pobase)=$pofile=~/^\Q$config{srcdir}\E\/?(.*)$/;
 933                         foreach my $dir (@{$config{underlaydirs}}) {
 934                                 if (-e "$dir/$pobase") {
 935                                         File::Copy::syscopy("$dir/$pobase",$pofile)
 936                                                 or error("po(refreshpofiles) ".
 937                                                          sprintf(gettext("failed to copy underlay PO file to %s"),
 938                                                                  $pofile));
 939                                 }
 940                         }
 941                 }
 942
 943                 if (-e $pofile) {
 944                         system("msgmerge", "--previous", "-q", "-U", "--backup=none", $pofile, $potfile) == 0
 945                                 or error("po(refreshpofiles) ".
 946                                          sprintf(gettext("failed to update %s"),
 947                                                  $pofile));
 948                 }
 949                 else {
 950                         File::Copy::syscopy($potfile,$pofile)
 951                                 or error("po(refreshpofiles) ".
 952                                          sprintf(gettext("failed to copy the POT file to %s"),
 953                                                  $pofile));
 954                 }
 955         }
 956 }
 957
 958 sub buildtranslationscache() {
 959         # use istranslation's side-effect
 960         map istranslation($_), (keys %pagesources);
 961 }
 962
 963 sub resettranslationscache() {
 964         undef %translations;
 965 }
 966
 967 sub flushmemoizecache() {
 968         Memoize::flush_cache("istranslatable");
 969         Memoize::flush_cache("_istranslation");
 970         Memoize::flush_cache("percenttranslated");
 971 }
 972
 973 sub urlto_with_orig_beautiful_urlpath($$) {
 974         my $to=shift;
 975         my $from=shift;
 976
 977         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 978         my $res=urlto($to, $from);
 979         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 980
 981         return $res;
 982 }
 983
 984 sub percenttranslated ($) {
 985         my $page=shift;
 986
 987         $page=~s/^\///;
 988         return gettext("N/A") unless istranslation($page);
 989         my $file=srcfile($pagesources{$page});
 990         my $masterfile = srcfile($pagesources{masterpage($page)});
 991         my $doc=Locale::Po4a::Chooser::new(po4a_type($masterfile),
 992                                            po4a_options($masterfile));
 993         $doc->process(
 994                 'po_in_name'    => [ $file ],
 995                 'file_in_name'  => [ $masterfile ],
 996                 'file_in_charset'  => 'UTF-8',
 997                 'file_out_charset' => 'UTF-8',
 998         ) or error("po(percenttranslated) ".
 999                    sprintf(gettext("failed to translate %s"), $page));
1000         my ($percent,$hit,$queries) = $doc->stats();
1001         $percent =~ s/\.[0-9]+$//;
1002         return $percent;
1003 }
1004
1005 sub languagename ($) {
1006         my $code=shift;
1007
1008         return $config{po_master_language}{name}
1009                 if $code eq $config{po_master_language}{code};
1010         return $config{po_slave_languages}{$code}
1011                 if defined $config{po_slave_languages}{$code};
1012         return;
1013 }
1014
1015 sub otherlanguagesloop ($) {
1016         my $page=shift;
1017
1018         my @ret;
1019         if (istranslation($page)) {
1020                 push @ret, {
1021                         url => urlto_with_orig_beautiful_urlpath(masterpage($page), $page),
1022                         code => $config{po_master_language}{code},
1023                         language => $config{po_master_language}{name},
1024                         master => 1,
1025                 };
1026         }
1027         foreach my $lang (@{otherlanguages_codes($page)}) {
1028                 next if $lang eq $config{po_master_language}{code};
1029                 my $otherpage = otherlanguage_page($page, $lang);
1030                 push @ret, {
1031                         url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
1032                         code => $lang,
1033                         language => languagename($lang),
1034                         percent => percenttranslated($otherpage),
1035                 }
1036         }
1037         return @ret;
1038 }
1039
1040 sub homepageurl (;$) {
1041         my $page=shift;
1042
1043         return urlto('', $page);
1044 }
1045
1046 sub ishomepage ($) {
1047         my $page = shift;
1048
1049         return 1 if $page eq 'index';
1050         map { return 1 if $page eq 'index.'.$_ } @slavelanguages;
1051         return undef;
1052 }
1053
1054 sub deletetranslations ($) {
1055         my $deletedmasterfile=shift;
1056
1057         my $deletedmasterpage=pagename($deletedmasterfile);
1058         my @todelete;
1059         map {
1060                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
1061                 my $absfile = "$config{srcdir}/$file";
1062                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
1063                         push @todelete, $file;
1064                 }
1065         } @slavelanguages;
1066
1067         map {
1068                 if ($config{rcs}) {
1069                         IkiWiki::rcs_remove($_);
1070                 }
1071                 else {
1072                         IkiWiki::prune("$config{srcdir}/$_");
1073                 }
1074         } @todelete;
1075
1076         if (@todelete) {
1077                 commit_and_refresh(
1078                         gettext("removed obsolete PO files"));
1079         }
1080 }
1081
1082 sub commit_and_refresh ($) {
1083         my $msg = shift;
1084
1085         if ($config{rcs}) {
1086                 IkiWiki::disable_commit_hook();
1087                 IkiWiki::rcs_commit_staged(
1088                         message => $msg,
1089                 );
1090                 IkiWiki::enable_commit_hook();
1091                 IkiWiki::rcs_update();
1092         }
1093         # Reinitialize module's private variables.
1094         resetalreadyfiltered();
1095         resettranslationscache();
1096         flushmemoizecache();
1097         # Trigger a wiki refresh.
1098         require IkiWiki::Render;
1099         # without preliminary saveindex/loadindex, refresh()
1100         # complains about a lot of uninitialized variables
1101         IkiWiki::saveindex();
1102         IkiWiki::loadindex();
1103         IkiWiki::refresh();
1104         IkiWiki::saveindex();
1105 }
1106
1107 sub po_to_markup ($$) {
1108         my ($page, $content) = (shift, shift);
1109
1110         $content = '' unless defined $content;
1111         $content = decode_utf8(encode_utf8($content));
1112         # CRLF line terminators make poor Locale::Po4a feel bad
1113         $content=~s/\r\n/\n/g;
1114
1115         # There are incompatibilities between some File::Temp versions
1116         # (including 0.18, bundled with Lenny's perl-modules package)
1117         # and others (e.g. 0.20, previously present in the archive as
1118         # a standalone package): under certain circumstances, some
1119         # return a relative filename, whereas others return an absolute one;
1120         # we here use this module in a way that is at least compatible
1121         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1122         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
1123                                     DIR => File::Spec->tmpdir,
1124                                     UNLINK => 1)->filename;
1125         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
1126                                      DIR => File::Spec->tmpdir,
1127                                      UNLINK => 1)->filename;
1128
1129         my $fail = sub ($) {
1130                 my $msg = "po(po_to_markup) - $page : " . shift;
1131                 error($msg, sub { unlink $infile, $outfile});
1132         };
1133
1134         writefile(basename($infile), File::Spec->tmpdir, $content)
1135                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1136
1137         my $masterfile = srcfile($pagesources{masterpage($page)});
1138         my $doc=Locale::Po4a::Chooser::new(po4a_type($masterfile),
1139                                            po4a_options($masterfile));
1140         $doc->process(
1141                 'po_in_name'    => [ $infile ],
1142                 'file_in_name'  => [ $masterfile ],
1143                 'file_in_charset'  => 'UTF-8',
1144                 'file_out_charset' => 'UTF-8',
1145         ) or return $fail->(gettext("failed to translate"));
1146         $doc->write($outfile)
1147                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1148
1149         $content = readfile($outfile);
1150
1151         # Unlinking should happen automatically, thanks to File::Temp,
1152         # but it does not work here, probably because of the way writefile()
1153         # and Locale::Po4a::write() work.
1154         unlink $infile, $outfile;
1155
1156         return $content;
1157 }
1158
1159 # returns a SuccessReason or FailReason object
1160 sub isvalidpo ($) {
1161         my $content = shift;
1162
1163         # NB: we don't use po_to_markup here, since Po4a parser does
1164         # not mind invalid PO content
1165         $content = '' unless defined $content;
1166         $content = decode_utf8(encode_utf8($content));
1167
1168         # There are incompatibilities between some File::Temp versions
1169         # (including 0.18, bundled with Lenny's perl-modules package)
1170         # and others (e.g. 0.20, previously present in the archive as
1171         # a standalone package): under certain circumstances, some
1172         # return a relative filename, whereas others return an absolute one;
1173         # we here use this module in a way that is at least compatible
1174         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1175         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1176                                     DIR => File::Spec->tmpdir,
1177                                     UNLINK => 1)->filename;
1178
1179         my $fail = sub ($) {
1180                 my $msg = '[po/isvalidpo] ' . shift;
1181                 unlink $infile;
1182                 return IkiWiki::FailReason->new("$msg");
1183         };
1184
1185         writefile(basename($infile), File::Spec->tmpdir, $content)
1186                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1187
1188         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1189
1190         # Unlinking should happen automatically, thanks to File::Temp,
1191         # but it does not work here, probably because of the way writefile()
1192         # and Locale::Po4a::write() work.
1193         unlink $infile;
1194
1195         if ($res) {
1196                 return IkiWiki::SuccessReason->new("valid gettext data");
1197         }
1198         return IkiWiki::FailReason->new(gettext("invalid gettext data, go back ".
1199                                         "to previous page to continue edit"));
1200 }
1201
1202 sub po4a_type ($) {
1203         my $file = shift;
1204
1205         my $pagetype = pagetype($file);
1206         if ($pagetype eq 'html') {
1207                 return 'xhtml';
1208         }
1209         return 'text';
1210 }
1211
1212 sub po4a_options($) {
1213         my $file = shift;
1214
1215         my %options;
1216         my $pagetype = pagetype($file);
1217
1218         if ($pagetype eq 'html') {
1219                 # how to disable options is not consistent across po4a modules
1220                 $options{includessi} = '';
1221                 $options{includeexternal} = 0;
1222         }
1223         elsif ($pagetype eq 'mdwn') {
1224                 $options{markdown} = 1;
1225         }
1226         else {
1227                 $options{markdown} = 0;
1228         }
1229
1230         return %options;
1231 }
1232
1233 # ,----
1234 # | PageSpecs
1235 # `----
1236
1237 package IkiWiki::PageSpec;
1238
1239 sub match_istranslation ($;@) {
1240         my $page=shift;
1241
1242         if (IkiWiki::Plugin::po::istranslation($page)) {
1243                 return IkiWiki::SuccessReason->new("is a translation page");
1244         }
1245         else {
1246                 return IkiWiki::FailReason->new("is not a translation page");
1247         }
1248 }
1249
1250 sub match_istranslatable ($;@) {
1251         my $page=shift;
1252
1253         if (IkiWiki::Plugin::po::istranslatable($page)) {
1254                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1255         }
1256         else {
1257                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1258         }
1259 }
1260
1261 sub match_lang ($$;@) {
1262         my $page=shift;
1263         my $wanted=shift;
1264
1265         my $regexp=IkiWiki::glob2re($wanted);
1266         my $lang=IkiWiki::Plugin::po::lang($page);
1267         if ($lang !~ /^$regexp$/i) {
1268                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1269         }
1270         else {
1271                 return IkiWiki::SuccessReason->new("file language is $wanted");
1272         }
1273 }
1274
1275 sub match_currentlang ($$;@) {
1276         my $page=shift;
1277         shift;
1278         my %params=@_;
1279
1280         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1281
1282         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1283         my $lang=IkiWiki::Plugin::po::lang($page);
1284
1285         if ($lang eq $currentlang) {
1286                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1287         }
1288         else {
1289                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1290         }
1291 }
1292
1293 sub match_needstranslation ($$;@) {
1294         my $page=shift;
1295         my $wanted=shift;
1296
1297         if (defined $wanted && $wanted ne "") {
1298                 if ($wanted !~ /^\d+$/) {
1299                         return IkiWiki::FailReason->new("parameter is not an integer");
1300                 }
1301                 elsif ($wanted > 100) {
1302                         return IkiWiki::FailReason->new("parameter is greater than 100");
1303                 }
1304         }
1305         else {
1306                 $wanted=100;
1307         }
1308
1309         my $percenttranslated=IkiWiki::Plugin::po::percenttranslated($page);
1310         if ($percenttranslated eq 'N/A') {
1311                 return IkiWiki::FailReason->new("file is not a translatable page");
1312         }
1313         elsif ($percenttranslated < $wanted) {
1314                 return IkiWiki::SuccessReason->new("file has $percenttranslated translated");
1315         }
1316         else {
1317                 return IkiWiki::FailReason->new("file is translated enough");
1318         }
1319 }
1320
1321 1