IkiWiki/Plugin/attachment.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::attachment;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         add_underlay("attachment");
  10         add_underlay("javascript");
  11         add_underlay("jquery");
  12         hook(type => "getsetup", id => "attachment", call => \&getsetup);
  13         hook(type => "checkconfig", id => "attachment", call => \&checkconfig);
  14         hook(type => "formbuilder_setup", id => "attachment", call => \&formbuilder_setup);
  15         hook(type => "formbuilder", id => "attachment", call => \&formbuilder, last => 1);
  16         IkiWiki::loadplugin("filecheck");
  17 }
  18
  19 sub getsetup () {
  20         return
  21                 plugin => {
  22                         safe => 1,
  23                         rebuild => 0,
  24                         section => "web",
  25                 },
  26                 allowed_attachments => {
  27                         type => "pagespec",
  28                         example => "virusfree() and mimetype(image/*) and maxsize(50kb)",
  29                         description => "enhanced PageSpec specifying what attachments are allowed",
  30                         link => "ikiwiki/PageSpec/attachment",
  31                         safe => 1,
  32                         rebuild => 0,
  33                 },
  34                 virus_checker => {
  35                         type => "string",
  36                         example => "clamdscan -",
  37                         description => "virus checker program (reads STDIN, returns nonzero if virus found)",
  38                         safe => 0, # executed
  39                         rebuild => 0,
  40                 },
  41 }
  42
  43 sub check_canattach ($$;$) {
  44         my $session=shift;
  45         my $dest=shift; # where it's going to be put, under the srcdir
  46         my $file=shift; # the path to the attachment currently
  47
  48         # Don't allow an attachment to be uploaded with the same name as an
  49         # existing page.
  50         if (exists $IkiWiki::pagesources{$dest} &&
  51             $IkiWiki::pagesources{$dest} ne $dest) {
  52                 error(sprintf(gettext("there is already a page named %s"), $dest));
  53         }
  54
  55         # Use a special pagespec to test that the attachment is valid.
  56         my $allowed=1;
  57         if (defined $config{allowed_attachments} &&
  58             length $config{allowed_attachments}) {
  59                 $allowed=pagespec_match($dest,
  60                         $config{allowed_attachments},
  61                         file => $file,
  62                         user => $session->param("name"),
  63                         ip => $session->remote_addr(),
  64                 );
  65         }
  66
  67         if (! $allowed) {
  68                 error(gettext("prohibited by allowed_attachments")." ($allowed)");
  69         }
  70         else {
  71                 return 1;
  72         }
  73 }
  74
  75 sub checkconfig () {
  76         $config{cgi_disable_uploads}=0;
  77 }
  78
  79 sub formbuilder_setup (@) {
  80         my %params=@_;
  81         my $form=$params{form};
  82         my $q=$params{cgi};
  83
  84         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  85             $form->field("do") eq "create")) {
  86                 # Add attachment field, set type to multipart.
  87                 $form->enctype(&CGI::MULTIPART);
  88                 $form->field(name => 'attachment', type => 'file');
  89                 # These buttons are not put in the usual place, so
  90                 # are not added to the normal formbuilder button list.
  91                 $form->tmpl_param("field-upload" => '<input name="_submit" type="submit" value="Upload Attachment" />');
  92                 $form->tmpl_param("field-link" => '<input name="_submit" type="submit" value="Insert Links" />');
  93
  94                 # Add all the javascript used by the attachments interface.
  95                 require IkiWiki::Plugin::toggle;
  96                 my $js=IkiWiki::Plugin::toggle::include_javascript($params{page});
  97                 $js.='<link rel="stylesheet" href="'.urlto("ikiwiki/jquery-ui.min.css", $params{page}).'" id="theme">'."\n";
  98                 my @jsfiles=qw{jquery.min jquery-ui.min
  99                         jquery.tmpl.min jquery.iframe-transport
 100                         jquery.fileupload jquery.fileupload-ui
 101                 };
 102                 foreach my $file (@jsfiles) {
 103                         $js.='<script src="'.urlto("ikiwiki/$file.js", $params{page}).
 104                              '" type="text/javascript" charset="utf-8"></script>'."\n";
 105                 }
 106                 $form->tmpl_param("javascript" => $js);
 107
 108                 # Start with the attachments interface toggled invisible,
 109                 # but if it was used, keep it open.
 110                 if ($form->submitted ne "Upload Attachment" &&
 111                     (! defined $q->param("attachment_select") ||
 112                     ! length $q->param("attachment_select"))) {
 113                         $form->tmpl_param("attachments-class" => "toggleable");
 114                 }
 115                 else {
 116                         $form->tmpl_param("attachments-class" => "toggleable-open");
 117                 }
 118
 119                 # Save attachments in holding area before previewing and
 120                 # saving.
 121                 if ($form->submitted eq "Preview" ||
 122                     $form->submitted eq "Save Page") {
 123                         attachments_save($form, $params{session});
 124                 }
 125         }
 126 }
 127
 128 sub formbuilder (@) {
 129         my %params=@_;
 130         my $form=$params{form};
 131         my $q=$params{cgi};
 132
 133         return if ! defined $form->field("do") || ($form->field("do") ne "edit" && $form->field("do") ne "create") ;
 134
 135         my $filename=Encode::decode_utf8($q->param('attachment'));
 136         if (defined $filename && length $filename) {
 137                 attachment_store($filename, $form, $q, $params{session});
 138         }
 139
 140         if ($form->submitted eq "Save Page") {
 141                 attachments_save($form, $params{session});
 142         }
 143
 144         if ($form->submitted eq "Insert Links") {
 145                 my $page=quotemeta(Encode::decode_utf8($q->param("page")));
 146                 my $add="";
 147                 foreach my $f ($q->param("attachment_select")) {
 148                         $f=Encode::decode_utf8($f);
 149                         $f=~s/^$page\///;
 150                         if (IkiWiki::isinlinableimage($f) &&
 151                             UNIVERSAL::can("IkiWiki::Plugin::img", "import")) {
 152                                 $add.='[[!img '.$f.' align="right" size="" alt=""]]';
 153                         }
 154                         else {
 155                                 $add.="[[$f]]";
 156                         }
 157                         $add.="\n";
 158                 }
 159                 $form->field(name => 'editcontent',
 160                         value => $form->field('editcontent')."\n\n".$add,
 161                         force => 1) if length $add;
 162         }
 163
 164         # Generate the attachment list only after having added any new
 165         # attachments.
 166         $form->tmpl_param("attachment_list" => [attachment_list($form->field('page'))]);
 167 }
 168
 169 sub attachment_holding_location {
 170         my $page=attachment_location(shift);
 171
 172         my $dir=$config{wikistatedir}."/attachments/".
 173                 IkiWiki::possibly_foolish_untaint(linkpage($page));
 174         $dir=~s/\/$//;
 175         return $dir;
 176 }
 177
 178 sub is_held_attachment {
 179         my $attachment=shift;
 180
 181         my $f=attachment_holding_location($attachment);
 182         if (-f $f) {
 183                 return $f
 184         }
 185         else {
 186                 return undef;
 187         }
 188 }
 189
 190 # Stores the attachment in a holding area, not yet in the wiki proper.
 191 sub attachment_store {
 192         my $filename=shift;
 193         my $form=shift;
 194         my $q=shift;
 195         my $session=shift;
 196
 197         # This is an (apparently undocumented) way to get the name
 198         # of the temp file that CGI writes the upload to.
 199         my $tempfile=$q->tmpFileName($filename);
 200         if (! defined $tempfile || ! length $tempfile) {
 201                 # perl 5.8 needs an alternative, awful method
 202                 if ($q =~ /HASH/ && exists $q->{'.tmpfiles'}) {
 203                         foreach my $key (keys(%{$q->{'.tmpfiles'}})) {
 204                                 $tempfile=$q->tmpFileName(\$key);
 205                                 last if defined $tempfile && length $tempfile;
 206                         }
 207                 }
 208                 if (! defined $tempfile || ! length $tempfile) {
 209                         error("CGI::tmpFileName failed to return the uploaded file name");
 210                 }
 211         }
 212
 213         $filename=IkiWiki::basename($filename);
 214         $filename=~s/.*\\+(.+)/$1/; # hello, windows
 215         $filename=IkiWiki::possibly_foolish_untaint(linkpage($filename));
 216         my $dest=attachment_holding_location($form->field('page'));
 217
 218         # Check that the user is allowed to edit the attachment.
 219         my $final_filename=
 220                 linkpage(IkiWiki::possibly_foolish_untaint(
 221                         attachment_location($form->field('page')))).
 222                 $filename;
 223         eval {
 224                 if (IkiWiki::file_pruned($final_filename)) {
 225                         error(gettext("bad attachment filename"));
 226                 }
 227                 IkiWiki::check_canedit($final_filename, $q, $session);
 228                 # And that the attachment itself is acceptable.
 229                 check_canattach($session, $final_filename, $tempfile);
 230         };
 231         if ($@) {
 232                 json_response($q, $form, $dest."/".$filename, $@);
 233                 error $@;
 234         }
 235
 236         # Move the attachment into holding directory.
 237         # Try to use a fast rename; fall back to copying.
 238         IkiWiki::prep_writefile($filename, $dest);
 239         unlink($dest."/".$filename);
 240         if (rename($tempfile, $dest."/".$filename)) {
 241                 # The temp file has tight permissions; loosen up.
 242                 chmod(0666 & ~umask, $dest."/".$filename);
 243         }
 244         else {
 245                 my $fh=$q->upload('attachment');
 246                 if (! defined $fh || ! ref $fh) {
 247                         # needed by old CGI versions
 248                         $fh=$q->param('attachment');
 249                         if (! defined $fh || ! ref $fh) {
 250                                 # even that doesn't always work,
 251                                 # fall back to opening the tempfile
 252                                 $fh=undef;
 253                                 open($fh, "<", $tempfile) || error("failed to open \"$tempfile\": $!");
 254                         }
 255                 }
 256                 binmode($fh);
 257                 require IkiWiki::Render;
 258                 writefile($filename, $dest, undef, 1, sub {
 259                         IkiWiki::fast_file_copy($tempfile, $filename, $fh, @_);
 260                 });
 261         }
 262
 263         json_response($q, $form, $dest."/".$filename, stored_msg());
 264 }
 265
 266 # Save all stored attachments for a page.
 267 sub attachments_save {
 268         my $form=shift;
 269         my $session=shift;
 270
 271         # Move attachments out of holding directory.
 272         my @attachments;
 273         my $dir=attachment_holding_location($form->field('page'));
 274         foreach my $filename (glob("$dir/*")) {
 275                 next unless -f $filename;
 276                 my $dest=$config{srcdir}."/".
 277                         linkpage(IkiWiki::possibly_foolish_untaint(
 278                                 attachment_location($form->field('page')))).
 279                         IkiWiki::basename($filename);
 280                 unlink($dest);
 281                 rename($filename, $dest);
 282                 push @attachments, $dest;
 283         }
 284         return unless @attachments;
 285         require IkiWiki::Render;
 286         IkiWiki::prune($dir);
 287
 288         # Check the attachments in and trigger a wiki refresh.
 289         if ($config{rcs}) {
 290                 IkiWiki::rcs_add($_) foreach @attachments;
 291                 IkiWiki::disable_commit_hook();
 292                 IkiWiki::rcs_commit_staged(
 293                         message => gettext("attachment upload"),
 294                         session => $session,
 295                 );
 296                 IkiWiki::enable_commit_hook();
 297                 IkiWiki::rcs_update();
 298         }
 299         IkiWiki::refresh();
 300         IkiWiki::saveindex();
 301 }
 302
 303 sub attachment_location ($) {
 304         my $page=shift;
 305
 306         # Put the attachment in a subdir of the page it's attached
 307         # to, unless that page is the "index" page.
 308         return "" if $page eq 'index';
 309         $page.="/" if length $page;
 310
 311         return $page;
 312 }
 313
 314 sub attachment_list ($) {
 315         my $page=shift;
 316         my $loc=attachment_location($page);
 317
 318         my $std=sub {
 319                 my $file=shift;
 320                 my $mtime=shift;
 321                 my $date=shift;
 322                 my $size=shift;
 323
 324                 name => $file,
 325                 size => IkiWiki::Plugin::filecheck::humansize($size),
 326                 mtime => $date,
 327                 mtime_raw => $mtime,
 328         };
 329
 330         # attachments already in the wiki
 331         my %attachments;
 332         foreach my $f (values %pagesources) {
 333                 if (! defined pagetype($f) &&
 334                     $f=~m/^\Q$loc\E[^\/]+$/) {
 335                         $attachments{$f}={
 336                                 $std->($f, $IkiWiki::pagemtime{$f}, displaytime($IkiWiki::pagemtime{$f}), (stat($f))[7]),
 337                                 link => htmllink($page, $page, $f, noimageinline => 1),
 338                         };
 339                 }
 340         }
 341
 342         # attachments in holding directory
 343         my $dir=attachment_holding_location($page);
 344         my $heldmsg=gettext("this attachment is not yet saved");
 345         foreach my $file (glob("$dir/*")) {
 346                 next unless -f $file;
 347                 my $base=IkiWiki::basename($file);
 348                 my $f=$loc.$base;
 349                 $attachments{$f}={
 350                         $std->($f, (stat($file))[9]*2, stored_msg(), (stat(_))[7]),
 351                         link => $base,
 352                 }
 353         }
 354
 355         # Sort newer attachments to the end of the list.
 356         return sort { $a->{mtime_raw} <=> $b->{mtime_raw} || $a->{link} cmp $b->{link} }
 357                 values %attachments;
 358 }
 359
 360 sub stored_msg {
 361         gettext("just uploaded");
 362 }
 363
 364 sub json_response ($$$$) {
 365         my $q=shift;
 366         my $form=shift;
 367         my $filename=shift;
 368         my $stored_msg=shift;
 369
 370         if (! defined $form->submitted ||
 371             $form->submitted ne "Upload Attachment") {
 372                 eval q{use JSON};
 373                 error $@ if $@;
 374                 print "Content-type: text/html\n\n";
 375                 my $size=-s $filename;
 376                 print to_json([
 377                         {
 378                                 name => IkiWiki::basename($filename),
 379                                 size => $size,
 380                                 humansize => IkiWiki::Plugin::filecheck::humansize($size),
 381                                 stored_msg => $stored_msg,
 382
 383                         }
 384                 ]);
 385                 exit 0;
 386         }
 387 }
 388
 389 1