IkiWiki/Plugin/aggregate.pm

   1 #!/usr/bin/perl
   2 # Blog aggregation plugin.
   3 package IkiWiki::Plugin::aggregate;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8 use HTML::Entities;
   9 use HTML::Parser;
  10 use HTML::Tagset;
  11 use URI;
  12 use open qw{:utf8 :std};
  13
  14 my %feeds;
  15 my %guids;
  16
  17 sub import { #{{{
  18         hook(type => "getopt", id => "aggregate", call => \&getopt);
  19         hook(type => "checkconfig", id => "aggregate", call => \&checkconfig);
  20         hook(type => "needsbuild", id => "aggregate", call => \&needsbuild);
  21         hook(type => "preprocess", id => "aggregate", call => \&preprocess);
  22         hook(type => "delete", id => "aggregate", call => \&delete);
  23         hook(type => "savestate", id => "aggregate", call => \&savestate);
  24 } # }}}
  25
  26 sub getopt () { #{{{
  27         eval q{use Getopt::Long};
  28         error($@) if $@;
  29         Getopt::Long::Configure('pass_through');
  30         GetOptions("aggregate" => \$config{aggregate});
  31 } #}}}
  32
  33 sub checkconfig () { #{{{
  34         if ($config{aggregate} && ! ($config{post_commit} &&
  35                                      IkiWiki::commit_hook_enabled())) {
  36                 if (! IkiWiki::lockwiki(0)) {
  37                         debug("wiki is locked by another process, not aggregating");
  38                         exit 1;
  39                 }
  40
  41                 loadstate();
  42                 IkiWiki::loadindex();
  43                 aggregate();
  44                 expire();
  45                 savestate();
  46                 clearstate();
  47
  48                 IkiWiki::unlockwiki();
  49         }
  50 } #}}}
  51
  52 sub needsbuild (@) { #{{{
  53         my $needsbuild=shift;
  54
  55         loadstate(); # if not already loaded
  56
  57         foreach my $feed (values %feeds) {
  58                 if (exists $pagesources{$feed->{sourcepage}} &&
  59                     grep { $_ eq $pagesources{$feed->{sourcepage}} } @$needsbuild) {
  60                         # Mark all feeds originating on this page as removable;
  61                         # preprocess will unmark those that still exist.
  62                         remove_feeds($feed->{sourcepage});
  63                 }
  64         }
  65 } # }}}
  66
  67 sub preprocess (@) { #{{{
  68         my %params=@_;
  69
  70         foreach my $required (qw{name url}) {
  71                 if (! exists $params{$required}) {
  72                         return "[[aggregate ".sprintf(gettext("missing %s parameter"), $required)."]]";
  73                 }
  74         }
  75
  76         my $feed={};
  77         my $name=$params{name};
  78         if (exists $feeds{$name}) {
  79                 $feed=$feeds{$name};
  80         }
  81         else {
  82                 $feeds{$name}=$feed;
  83         }
  84         $feed->{name}=$name;
  85         $feed->{sourcepage}=$params{page};
  86         $feed->{url}=$params{url};
  87         my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".IkiWiki::titlepage($params{name});
  88         $dir=~s/^\/+//;
  89         ($dir)=$dir=~/$config{wiki_file_regexp}/;
  90         $feed->{dir}=$dir;
  91         $feed->{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
  92         $feed->{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
  93         $feed->{expireage}=defined $params{expireage} ? $params{expireage} : 0;
  94         $feed->{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
  95         delete $feed->{remove};
  96         delete $feed->{expired};
  97         $feed->{lastupdate}=0 unless defined $feed->{lastupdate};
  98         $feed->{numposts}=0 unless defined $feed->{numposts};
  99         $feed->{newposts}=0 unless defined $feed->{newposts};
 100         $feed->{message}=gettext("new feed") unless defined $feed->{message};
 101         $feed->{error}=0 unless defined $feed->{error};
 102         $feed->{tags}=[];
 103         while (@_) {
 104                 my $key=shift;
 105                 my $value=shift;
 106                 if ($key eq 'tag') {
 107                         push @{$feed->{tags}}, $value;
 108                 }
 109         }
 110
 111         return "<a href=\"".$feed->{url}."\">".$feed->{name}."</a>: ".
 112                ($feed->{error} ? "<em>" : "").$feed->{message}.
 113                ($feed->{error} ? "</em>" : "").
 114                " (".$feed->{numposts}." ".gettext("posts").
 115                ($feed->{newposts} ? "; ".$feed->{newposts}.
 116                                     " ".gettext("new") : "").
 117                ")";
 118 } # }}}
 119
 120 sub delete (@) { #{{{
 121         my @files=@_;
 122
 123         # Remove feed data for removed pages.
 124         foreach my $file (@files) {
 125                 my $page=pagename($file);
 126                 remove_feeds($page);
 127         }
 128 } #}}}
 129
 130 my $state_loaded=0;
 131 sub loadstate () { #{{{
 132         return if $state_loaded;
 133         $state_loaded=1;
 134         if (-e "$config{wikistatedir}/aggregate") {
 135                 open(IN, "<", "$config{wikistatedir}/aggregate") ||
 136                         die "$config{wikistatedir}/aggregate: $!";
 137                 while (<IN>) {
 138                         $_=IkiWiki::possibly_foolish_untaint($_);
 139                         chomp;
 140                         my $data={};
 141                         foreach my $i (split(/ /, $_)) {
 142                                 my ($field, $val)=split(/=/, $i, 2);
 143                                 if ($field eq "name" || $field eq "feed" ||
 144                                     $field eq "guid" || $field eq "message") {
 145                                         $data->{$field}=decode_entities($val, " \t\n");
 146                                 }
 147                                 elsif ($field eq "tag") {
 148                                         push @{$data->{tags}}, $val;
 149                                 }
 150                                 else {
 151                                         $data->{$field}=$val;
 152                                 }
 153                         }
 154
 155                         if (exists $data->{name}) {
 156                                 $feeds{$data->{name}}=$data;
 157                         }
 158                         elsif (exists $data->{guid}) {
 159                                 $guids{$data->{guid}}=$data;
 160                         }
 161                 }
 162
 163                 close IN;
 164         }
 165 } #}}}
 166
 167 sub savestate () { #{{{
 168         return unless $state_loaded;
 169         eval q{use HTML::Entities};
 170         error($@) if $@;
 171         my $newfile="$config{wikistatedir}/aggregate.new";
 172         my $cleanup = sub { unlink($newfile) };
 173         open (OUT, ">", $newfile) || error("open $newfile: $!", $cleanup);
 174         foreach my $data (values %feeds, values %guids) {
 175                 if ($data->{remove}) {
 176                         if ($data->{name}) {
 177                                 foreach my $guid (values %guids) {
 178                                         if ($guid->{feed} eq $data->{name}) {
 179                                                 $guid->{remove}=1;
 180                                         }
 181                                 }
 182                         }
 183                         else {
 184                                 unlink pagefile($data->{page})
 185                                         if exists $data->{page};
 186                         }
 187                         next;
 188                 }
 189                 elsif ($data->{expired} && exists $data->{page}) {
 190                         unlink pagefile($data->{page});
 191                         delete $data->{page};
 192                         delete $data->{md5};
 193                 }
 194
 195                 my @line;
 196                 foreach my $field (keys %$data) {
 197                         if ($field eq "name" || $field eq "feed" ||
 198                             $field eq "guid" || $field eq "message") {
 199                                 push @line, "$field=".encode_entities($data->{$field}, " \t\n");
 200                         }
 201                         elsif ($field eq "tags") {
 202                                 push @line, "tag=$_" foreach @{$data->{tags}};
 203                         }
 204                         else {
 205                                 push @line, "$field=".$data->{$field};
 206                         }
 207                 }
 208                 print OUT join(" ", @line)."\n" || error("write $newfile: $!", $cleanup);
 209         }
 210         close OUT || error("save $newfile: $!", $cleanup);
 211         rename($newfile, "$config{wikistatedir}/aggregate") ||
 212                 error("rename $newfile: $!", $cleanup);
 213 } #}}}
 214
 215 sub clearstate () { #{{{
 216         %feeds=();
 217         %guids=();
 218         $state_loaded=0;
 219 } #}}}
 220
 221 sub expire () { #{{{
 222         foreach my $feed (values %feeds) {
 223                 next unless $feed->{expireage} || $feed->{expirecount};
 224                 my $count=0;
 225                 my %seen;
 226                 foreach my $item (sort { $IkiWiki::pagectime{$b->{page}} <=> $IkiWiki::pagectime{$a->{page}} }
 227                                   grep { exists $_->{page} && $_->{feed} eq $feed->{name} && $IkiWiki::pagectime{$_->{page}} }
 228                                   values %guids) {
 229                         if ($feed->{expireage}) {
 230                                 my $days_old = (time - $IkiWiki::pagectime{$item->{page}}) / 60 / 60 / 24;
 231                                 if ($days_old > $feed->{expireage}) {
 232                                         debug(sprintf(gettext("expiring %s (%s days old)"),
 233                                                 $item->{page}, int($days_old)));
 234                                         $item->{expired}=1;
 235                                 }
 236                         }
 237                         elsif ($feed->{expirecount} &&
 238                                $count >= $feed->{expirecount}) {
 239                                 debug(sprintf(gettext("expiring %s"), $item->{page}));
 240                                 $item->{expired}=1;
 241                         }
 242                         else {
 243                                 if (! $seen{$item->{page}}) {
 244                                         $seen{$item->{page}}=1;
 245                                         $count++;
 246                                 }
 247                         }
 248                 }
 249         }
 250 } #}}}
 251
 252 sub aggregate () { #{{{
 253         eval q{use XML::Feed};
 254         error($@) if $@;
 255         eval q{use URI::Fetch};
 256         error($@) if $@;
 257         eval q{use HTML::Entities};
 258         error($@) if $@;
 259
 260         foreach my $feed (values %feeds) {
 261                 next unless $config{rebuild} ||
 262                         time - $feed->{lastupdate} >= $feed->{updateinterval};
 263                 $feed->{lastupdate}=time;
 264                 $feed->{newposts}=0;
 265                 $feed->{message}=sprintf(gettext("processed ok at %s"),
 266                         displaytime($feed->{lastupdate}));
 267                 $feed->{error}=0;
 268                 $IkiWiki::forcerebuild{$feed->{sourcepage}}=1;
 269
 270                 debug(sprintf(gettext("checking feed %s ..."), $feed->{name}));
 271
 272                 if (! length $feed->{feedurl}) {
 273                         my @urls=XML::Feed->find_feeds($feed->{url});
 274                         if (! @urls) {
 275                                 $feed->{message}=sprintf(gettext("could not find feed at %s"), $feed->{url});
 276                                 $feed->{error}=1;
 277                                 debug($feed->{message});
 278                                 next;
 279                         }
 280                         $feed->{feedurl}=pop @urls;
 281                 }
 282                 my $res=URI::Fetch->fetch($feed->{feedurl});
 283                 if (! $res) {
 284                         $feed->{message}=URI::Fetch->errstr;
 285                         $feed->{error}=1;
 286                         debug($feed->{message});
 287                         next;
 288                 }
 289                 if ($res->status == URI::Fetch::URI_GONE()) {
 290                         $feed->{message}=gettext("feed not found");
 291                         $feed->{error}=1;
 292                         debug($feed->{message});
 293                         next;
 294                 }
 295                 my $content=$res->content;
 296                 my $f=eval{XML::Feed->parse(\$content)};
 297                 if ($@) {
 298                         # One common cause of XML::Feed crashing is a feed
 299                         # that contains invalid UTF-8 sequences. Convert
 300                         # feed to ascii to try to work around.
 301                         $feed->{message}.=" ".sprintf(gettext("(invalid UTF-8 stripped from feed)"));
 302                         $content=Encode::decode_utf8($content);
 303                         $f=eval{XML::Feed->parse(\$content)};
 304                 }
 305                 if ($@) {
 306                         # Another possibility is badly escaped entities.
 307                         $feed->{message}.=" ".sprintf(gettext("(feed entities escaped)"));
 308                         $content=~s/\&(?!amp)(\w+);/&amp;$1;/g;
 309                         $content=Encode::decode_utf8($content);
 310                         $f=eval{XML::Feed->parse(\$content)};
 311                 }
 312                 if ($@) {
 313                         $feed->{message}=gettext("feed crashed XML::Feed!")." ($@)";
 314                         $feed->{error}=1;
 315                         debug($feed->{message});
 316                         next;
 317                 }
 318                 if (! $f) {
 319                         $feed->{message}=XML::Feed->errstr;
 320                         $feed->{error}=1;
 321                         debug($feed->{message});
 322                         next;
 323                 }
 324
 325                 foreach my $entry ($f->entries) {
 326                         add_page(
 327                                 feed => $feed,
 328                                 copyright => $f->copyright,
 329                                 title => defined $entry->title ? decode_entities($entry->title) : "untitled",
 330                                 link => $entry->link,
 331                                 content => defined $entry->content->body ? $entry->content->body : "",
 332                                 guid => defined $entry->id ? $entry->id : time."_".$feed->name,
 333                                 ctime => $entry->issued ? ($entry->issued->epoch || time) : time,
 334                         );
 335                 }
 336         }
 337 } #}}}
 338
 339 sub add_page (@) { #{{{
 340         my %params=@_;
 341
 342         my $feed=$params{feed};
 343         my $guid={};
 344         my $mtime;
 345         if (exists $guids{$params{guid}}) {
 346                 # updating an existing post
 347                 $guid=$guids{$params{guid}};
 348                 return if $guid->{expired};
 349         }
 350         else {
 351                 # new post
 352                 $guid->{guid}=$params{guid};
 353                 $guids{$params{guid}}=$guid;
 354                 $mtime=$params{ctime};
 355                 $feed->{numposts}++;
 356                 $feed->{newposts}++;
 357
 358                 # assign it an unused page
 359                 my $page=IkiWiki::titlepage($params{title});
 360                 # escape slashes and periods in title so it doesn't specify
 361                 # directory name or trigger ".." disallowing code.
 362                 $page=~s!([/.])!"__".ord($1)."__"!eg;
 363                 $page=$feed->{dir}."/".$page;
 364                 ($page)=$page=~/$config{wiki_file_regexp}/;
 365                 if (! defined $page || ! length $page) {
 366                         $page=$feed->{dir}."/item";
 367                 }
 368                 my $c="";
 369                 while (exists $IkiWiki::pagecase{lc $page.$c} ||
 370                        -e pagefile($page.$c)) {
 371                         $c++
 372                 }
 373
 374                 # Make sure that the file name isn't too long.
 375                 # NB: This doesn't check for path length limits.
 376                 my $max=POSIX::pathconf($config{srcdir}, &POSIX::_PC_NAME_MAX);
 377                 if (defined $max && length(htmlfn($page)) >= $max) {
 378                         $c="";
 379                         $page=$feed->{dir}."/item";
 380                         while (exists $IkiWiki::pagecase{lc $page.$c} ||
 381                                -e pagefile($page.$c)) {
 382                                 $c++
 383                         }
 384                 }
 385
 386                 $guid->{page}=$page;
 387                 debug(sprintf(gettext("creating new page %s"), $page));
 388         }
 389         $guid->{feed}=$feed->{name};
 390
 391         # To write or not to write? Need to avoid writing unchanged pages
 392         # to avoid unneccessary rebuilding. The mtime from rss cannot be
 393         # trusted; let's use a digest.
 394         eval q{use Digest::MD5 'md5_hex'};
 395         error($@) if $@;
 396         require Encode;
 397         my $digest=md5_hex(Encode::encode_utf8($params{content}));
 398         return unless ! exists $guid->{md5} || $guid->{md5} ne $digest || $config{rebuild};
 399         $guid->{md5}=$digest;
 400
 401         # Create the page.
 402         my $template=template("aggregatepost.tmpl", blind_cache => 1);
 403         $template->param(title => $params{title})
 404                 if defined $params{title} && length($params{title});
 405         $template->param(content => htmlescape(htmlabs($params{content}, $feed->{feedurl})));
 406         $template->param(name => $feed->{name});
 407         $template->param(url => $feed->{url});
 408         $template->param(copyright => $params{copyright})
 409                 if defined $params{copyright} && length $params{copyright};
 410         $template->param(permalink => urlabs($params{link}, $feed->{feedurl}))
 411                 if defined $params{link};
 412         if (ref $feed->{tags}) {
 413                 $template->param(tags => [map { tag => $_ }, @{$feed->{tags}}]);
 414         }
 415         writefile(htmlfn($guid->{page}), $config{srcdir},
 416                 $template->output);
 417
 418         # Set the mtime, this lets the build process get the right creation
 419         # time on record for the new page.
 420         utime $mtime, $mtime, pagefile($guid->{page})
 421                 if defined $mtime && $mtime <= time;
 422 } #}}}
 423
 424 sub htmlescape ($) { #{{{
 425         # escape accidental wikilinks and preprocessor stuff
 426         my $html=shift;
 427         $html=~s/(?<!\\)\[\[/\\\[\[/g;
 428         return $html;
 429 } #}}}
 430
 431 sub urlabs ($$) { #{{{
 432         my $url=shift;
 433         my $urlbase=shift;
 434
 435         URI->new_abs($url, $urlbase)->as_string;
 436 } #}}}
 437
 438 sub htmlabs ($$) { #{{{
 439         # Convert links in html from relative to absolute.
 440         # Note that this is a heuristic, which is not specified by the rss
 441         # spec and may not be right for all feeds. Also, see Debian
 442         # bug #381359.
 443         my $html=shift;
 444         my $urlbase=shift;
 445
 446         my $ret="";
 447         my $p = HTML::Parser->new(api_version => 3);
 448         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 449         $p->handler(start => sub {
 450                 my ($tagname, $pos, $text) = @_;
 451                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 452                         while (4 <= @$pos) {
 453                                 # use attribute sets from right to left
 454                                 # to avoid invalidating the offsets
 455                                 # when replacing the values
 456                                 my($k_offset, $k_len, $v_offset, $v_len) =
 457                                         splice(@$pos, -4);
 458                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 459                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 460                                 next unless $v_offset; # 0 v_offset means no value
 461                                 my $v = substr($text, $v_offset, $v_len);
 462                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 463                                 my $new_v=urlabs($v, $urlbase);
 464                                 $new_v =~ s/\"/&quot;/g; # since we quote with ""
 465                                 substr($text, $v_offset, $v_len) = qq("$new_v");
 466                         }
 467                 }
 468                 $ret.=$text;
 469         }, "tagname, tokenpos, text");
 470         $p->parse($html);
 471         $p->eof;
 472
 473         return $ret;
 474 } #}}}
 475
 476 sub remove_feeds () { #{{{
 477         my $page=shift;
 478
 479         my %removed;
 480         foreach my $id (keys %feeds) {
 481                 if ($feeds{$id}->{sourcepage} eq $page) {
 482                         $feeds{$id}->{remove}=1;
 483                         $removed{$id}=1;
 484                 }
 485         }
 486 } #}}}
 487
 488 sub pagefile ($) { #{{{
 489         my $page=shift;
 490
 491         return "$config{srcdir}/".htmlfn($page);
 492 } #}}}
 493
 494 sub htmlfn ($) { #{{{
 495         return shift().".".$config{htmlext};
 496 } #}}}
 497
 498 my $aggregatelock;
 499
 500 sub lockaggregate () { #{{{
 501         # Take an exclusive lock to prevent multiple concurrent aggregators.
 502         # Returns true if the lock was aquired.
 503         if (! -d $config{wikistatedir}) {
 504                 mkdir($config{wikistatedir});
 505         }
 506         open($aggregatelock, '>', "$config{wikistatedir}/aggregatelock") ||
 507                 error ("cannot open to $config{wikistatedir}/aggregatelock: $!");
 508         if (! flock($aggregatelock, 2 | 4)) { # LOCK_EX | LOCK_NB
 509                 close($aggregatelock) || error("failed closing aggregatelock: $!");
 510                 return 0;
 511         }
 512         return 1;
 513 } #}}}
 514
 515 sub unlockaggregate () { #{{{
 516         return close($aggregatelock) if $aggregatelock;
 517         return;
 518 } #}}}
 519
 520 1