IkiWiki/Plugin/calendar.pm

   1 #! /usr/bin/perl
   2 # Copyright (c) 2006, 2007 Manoj Srivastava <srivasta@debian.org>
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 require 5.002;
  19 package IkiWiki::Plugin::calendar;
  20
  21 use warnings;
  22 use strict;
  23 use IkiWiki 3.00;
  24 use Time::Local;
  25 use POSIX;
  26
  27 my %cache;
  28 my %linkcache;
  29 my $time=time;
  30 my @now=localtime($time);
  31
  32 sub import {
  33         hook(type => "getsetup", id => "calendar", call => \&getsetup);
  34         hook(type => "needsbuild", id => "calendar", call => \&needsbuild);
  35         hook(type => "preprocess", id => "calendar", call => \&preprocess);
  36 }
  37
  38 sub getsetup () {
  39         return
  40                 plugin => {
  41                         safe => 1,
  42                         rebuild => undef,
  43                 },
  44                 archivebase => {
  45                         type => "string",
  46                         example => "archives",
  47                         description => "base of the archives hierarchy",
  48                         safe => 1,
  49                         rebuild => 1,
  50                 },
  51 }
  52
  53 sub is_leap_year (@) {
  54         my %params=@_;
  55         return ($params{year} % 4 == 0 && (($params{year} % 100 != 0) || $params{year} % 400 == 0));
  56 }
  57
  58 sub month_days {
  59         my %params=@_;
  60         my $days_in_month = (31,28,31,30,31,30,31,31,30,31,30,31)[$params{month}-1];
  61         if ($params{month} == 2 && is_leap_year(%params)) {
  62                 $days_in_month++;
  63         }
  64         return $days_in_month;
  65 }
  66
  67 sub format_month (@) {
  68         my %params=@_;
  69
  70         my $pagespec = $params{pages};
  71         my $year     = $params{year};
  72         my $month    = $params{month};
  73         my $pmonth   = $params{pmonth};
  74         my $nmonth   = $params{nmonth};
  75         my $pyear    = $params{pyear};
  76         my $nyear    = $params{nyear};
  77
  78         my @list;
  79         my $calendar="\n";
  80
  81         # When did this month start?
  82         my @monthstart = localtime(timelocal(0,0,0,1,$month-1,$year-1900));
  83
  84         my $future_dom = 0;
  85         my $today      = 0;
  86         if ($year == $now[5]+1900 && $month == $now[4]+1) {
  87                 $future_dom = $now[3]+1;
  88                 $today      = $now[3];
  89         }
  90
  91         # Find out month names for this, next, and previous months
  92         my $monthname=POSIX::strftime("%B", @monthstart);
  93         my $pmonthname=POSIX::strftime("%B", localtime(timelocal(0,0,0,1,$pmonth-1,$pyear-1900)));
  94         my $nmonthname=POSIX::strftime("%B", localtime(timelocal(0,0,0,1,$nmonth-1,$nyear-1900)));
  95
  96         my $archivebase = 'archives';
  97         $archivebase = $config{archivebase} if defined $config{archivebase};
  98         $archivebase = $params{archivebase} if defined $params{archivebase};
  99
 100         # Calculate URL's for monthly archives.
 101         my ($url, $purl, $nurl)=("$monthname",'','');
 102         if (exists $cache{$pagespec}{"$year/$month"}) {
 103                 $url = htmllink($params{page}, $params{destpage},
 104                         "$archivebase/$year/".sprintf("%02d", $month),
 105                         linktext => " $monthname ");
 106         }
 107         add_depends($params{page}, "$archivebase/$year/".sprintf("%02d", $month),
 108                 deptype("presence"));
 109         if (exists $cache{$pagespec}{"$pyear/$pmonth"}) {
 110                 $purl = htmllink($params{page}, $params{destpage},
 111                         "$archivebase/$pyear/" . sprintf("%02d", $pmonth),
 112                         linktext => " $pmonthname ");
 113         }
 114         add_depends($params{page}, "$archivebase/$pyear/".sprintf("%02d", $pmonth),
 115                 deptype("presence"));
 116         if (exists $cache{$pagespec}{"$nyear/$nmonth"}) {
 117                 $nurl = htmllink($params{page}, $params{destpage},
 118                         "$archivebase/$nyear/" . sprintf("%02d", $nmonth),
 119                         linktext => " $nmonthname ");
 120         }
 121         add_depends($params{page}, "$archivebase/$nyear/".sprintf("%02d", $nmonth),
 122                 deptype("presence"));
 123
 124         # Start producing the month calendar
 125         $calendar=<<EOF;
 126 <table class="month-calendar">
 127         <caption class="month-calendar-head">
 128         $purl
 129         $url
 130         $nurl
 131         </caption>
 132         <tr>
 133 EOF
 134
 135         # Suppose we want to start the week with day $week_start_day
 136         # If $monthstart[6] == 1
 137         my $week_start_day = $params{week_start_day};
 138
 139         my $start_day = 1 + (7 - $monthstart[6] + $week_start_day) % 7;
 140         my %downame;
 141         my %dowabbr;
 142         for my $dow ($week_start_day..$week_start_day+6) {
 143                 my @day=localtime(timelocal(0,0,0,$start_day++,$month-1,$year-1900));
 144                 my $downame = POSIX::strftime("%A", @day);
 145                 my $dowabbr = POSIX::strftime("%a", @day);
 146                 $downame{$dow % 7}=$downame;
 147                 $dowabbr{$dow % 7}=$dowabbr;
 148                 $calendar.= qq{\t\t<th class="month-calendar-day-head $downame">$dowabbr</th>\n};
 149         }
 150
 151         $calendar.=<<EOF;
 152         </tr>
 153 EOF
 154
 155         my $wday;
 156         # we start with a week_start_day, and skip until we get to the first
 157         for ($wday=$week_start_day; $wday != $monthstart[6]; $wday++, $wday %= 7) {
 158                 $calendar.=qq{\t<tr>\n} if $wday == $week_start_day;
 159                 $calendar.=qq{\t\t<td class="month-calendar-day-noday $downame{$wday}">&nbsp;</td>\n};
 160         }
 161
 162         # At this point, either the first is a week_start_day, in which case
 163         # nothing has been printed, or else we are in the middle of a row.
 164         for (my $day = 1; $day <= month_days(year => $year, month => $month);
 165              $day++, $wday++, $wday %= 7) {
 166                 # At tihs point, on a week_start_day, we close out a row,
 167                 # and start a new one -- unless it is week_start_day on the
 168                 # first, where we do not close a row -- since none was started.
 169                 if ($wday == $week_start_day) {
 170                         $calendar.=qq{\t</tr>\n} unless $day == 1;
 171                         $calendar.=qq{\t<tr>\n};
 172                 }
 173
 174                 my $tag;
 175                 my $mtag = sprintf("%02d", $month);
 176                 if (defined $cache{$pagespec}{"$year/$mtag/$day"}) {
 177                         if ($day == $today) {
 178                                 $tag='month-calendar-day-this-day';
 179                         }
 180                         else {
 181                                 $tag='month-calendar-day-link';
 182                         }
 183                         $calendar.=qq{\t\t<td class="$tag $downame{$wday}">};
 184                         $calendar.=htmllink($params{page}, $params{destpage},
 185                                             pagename($linkcache{"$year/$mtag/$day"}),
 186                                             "linktext" => "$day");
 187                         push @list, pagename($linkcache{"$year/$mtag/$day"});
 188                         $calendar.=qq{</td>\n};
 189                 }
 190                 else {
 191                         if ($day == $today) {
 192                                 $tag='month-calendar-day-this-day';
 193                         }
 194                         elsif ($day == $future_dom) {
 195                                 $tag='month-calendar-day-future';
 196                         }
 197                         else {
 198                                 $tag='month-calendar-day-nolink';
 199                         }
 200                         $calendar.=qq{\t\t<td class="$tag $downame{$wday}">$day</td>\n};
 201                 }
 202         }
 203
 204         # finish off the week
 205         for (; $wday != $week_start_day; $wday++, $wday %= 7) {
 206                 $calendar.=qq{\t\t<td class="month-calendar-day-noday $downame{$wday}">&nbsp;</td>\n};
 207         }
 208         $calendar.=<<EOF;
 209         </tr>
 210 </table>
 211 EOF
 212
 213         # Add dependencies to update the calendar whenever pages
 214         # matching the pagespec are added or removed.
 215         add_depends($params{page}, $params{pages}, deptype("presence"));
 216
 217         return $calendar;
 218 }
 219
 220 sub format_year (@) {
 221         my %params=@_;
 222
 223         my $pagespec = $params{pages};
 224         my $year     = $params{year};
 225         my $month    = $params{month};
 226         my $pmonth   = $params{pmonth};
 227         my $nmonth   = $params{nmonth};
 228         my $pyear    = $params{pyear};
 229         my $nyear    = $params{nyear};
 230
 231         my $calendar="\n";
 232
 233         my $future_month = 0;
 234         $future_month = $now[4]+1 if ($year == $now[5]+1900);
 235
 236         my $archivebase = 'archives';
 237         $archivebase = $config{archivebase} if defined $config{archivebase};
 238         $archivebase = $params{archivebase} if defined $params{archivebase};
 239
 240         # calculate URL's for previous and next years
 241         my ($url, $purl, $nurl)=("$year",'','');
 242         if (exists $cache{$pagespec}{"$year"}) {
 243                 $url = htmllink($params{page}, $params{destpage},
 244                         "$archivebase/$year",
 245                         linktext => "$year");
 246         }
 247         add_depends($params{page}, "$archivebase/$year", deptype("presence");
 248         if (exists $cache{$pagespec}{"$pyear"}) {
 249                 $purl = htmllink($params{page}, $params{destpage},
 250                         "$archivebase/$pyear",
 251                         linktext => "\&larr;");
 252         }
 253         add_depends($params{page}, "$archivebase/$pyear", deptype("presence"));
 254         if (exists $cache{$pagespec}{"$nyear"}) {
 255                 $nurl = htmllink($params{page}, $params{destpage},
 256                         "$archivebase/$nyear",
 257                         linktext => "\&rarr;");
 258         }
 259         add_depends($params{page}, "$archivebase/$nyear", deptype("presence"));
 260
 261         # Start producing the year calendar
 262         $calendar=<<EOF;
 263 <table class="year-calendar">
 264         <caption class="year-calendar-head">
 265         $purl
 266         $url
 267         $nurl
 268         </caption>
 269         <tr>
 270                 <th class="year-calendar-subhead" colspan="$params{months_per_row}">Months</th>
 271         </tr>
 272 EOF
 273
 274         for ($month = 1; $month <= 12; $month++) {
 275                 my @day=localtime(timelocal(0,0,0,15,$month-1,$year-1900));
 276                 my $murl;
 277                 my $monthname = POSIX::strftime("%B", @day);
 278                 my $monthabbr = POSIX::strftime("%b", @day);
 279                 $calendar.=qq{\t<tr>\n}  if ($month % $params{months_per_row} == 1);
 280                 my $tag;
 281                 my $mtag=sprintf("%02d", $month);
 282                 if ($month == $params{month}) {
 283                         if ($cache{$pagespec}{"$year/$mtag"}) {
 284                                 $tag = 'this_month_link';
 285                         }
 286                         else {
 287                                 $tag = 'this_month_nolink';
 288                         }
 289                 }
 290                 elsif ($cache{$pagespec}{"$year/$mtag"}) {
 291                         $tag = 'month_link';
 292                 }
 293                 elsif ($future_month && $month >= $future_month) {
 294                         $tag = 'month_future';
 295                 }
 296                 else {
 297                         $tag = 'month_nolink';
 298                 }
 299
 300                 if ($cache{$pagespec}{"$year/$mtag"}) {
 301                         $murl = htmllink($params{page}, $params{destpage},
 302                                 "$archivebase/$year/$mtag",
 303                                 linktext => "$monthabbr");
 304                         $calendar.=qq{\t<td class="$tag">};
 305                         $calendar.=$murl;
 306                         $calendar.=qq{\t</td>\n};
 307                 }
 308                 else {
 309                         $calendar.=qq{\t<td class="$tag">$monthabbr</td>\n};
 310                 }
 311                 add_depends($params{page}, "$archivebase/$year/$mtag",
 312                         deptype("presence"));
 313
 314                 $calendar.=qq{\t</tr>\n} if ($month % $params{months_per_row} == 0);
 315         }
 316
 317         $calendar.=<<EOF;
 318 </table>
 319 EOF
 320
 321         return $calendar;
 322 }
 323
 324 sub preprocess (@) {
 325         my %params=@_;
 326         $params{pages} = "*"            unless defined $params{pages};
 327         $params{type}  = "month"        unless defined $params{type};
 328         $params{month} = sprintf("%02d", $params{month}) if defined  $params{month};
 329         $params{week_start_day} = 0     unless defined $params{week_start_day};
 330         $params{months_per_row} = 3     unless defined $params{months_per_row};
 331
 332         if (! defined $params{year} || ! defined $params{month}) {
 333                 # Record that the calendar next changes at midnight.
 334                 $pagestate{$params{destpage}}{calendar}{nextchange}=($time
 335                         + (60 - $now[0])                # seconds
 336                         + (59 - $now[1]) * 60           # minutes
 337                         + (23 - $now[2]) * 60 * 60      # hours
 338                 );
 339
 340                 $params{year}  = 1900 + $now[5] unless defined $params{year};
 341                 $params{month} = 1    + $now[4] unless defined $params{month};
 342         }
 343         else {
 344                 delete $pagestate{$params{destpage}}{calendar};
 345         }
 346
 347         # Calculate month names for next month, and previous months
 348         my $pmonth = $params{month} - 1;
 349         my $nmonth = $params{month} + 1;
 350         my $pyear  = $params{year}  - 1;
 351         my $nyear  = $params{year}  + 1;
 352
 353         # Adjust for January and December
 354         if ($params{month} == 1) {
 355                 $pmonth = 12;
 356                 $pyear--;
 357         }
 358         if ($params{month} == 12) {
 359                 $nmonth = 1;
 360                 $nyear++;
 361         }
 362
 363         $params{pmonth}=$pmonth;
 364         $params{nmonth}=$nmonth;
 365         $params{pyear} =$pyear;
 366         $params{nyear} =$nyear;
 367
 368         my $calendar="\n";
 369         my $pagespec=$params{pages};
 370         my $page =$params{page};
 371
 372         if (! defined $cache{$pagespec}) {
 373                 foreach my $p (pagespec_match_list([keys %pagesources], $pagespec)) {
 374                         my $mtime = $IkiWiki::pagectime{$p};
 375                         my $src   = $pagesources{$p};
 376                         my @date  = localtime($mtime);
 377                         my $mday  = $date[3];
 378                         my $month = $date[4] + 1;
 379                         my $year  = $date[5] + 1900;
 380                         my $mtag  = sprintf("%02d", $month);
 381
 382                         # Only one posting per day is being linked to.
 383                         $linkcache{"$year/$mtag/$mday"} = "$src";
 384                         $cache{$pagespec}{"$year"}++;
 385                         $cache{$pagespec}{"$year/$mtag"}++;
 386                         $cache{$pagespec}{"$year/$mtag/$mday"}++;
 387                 }
 388         }
 389
 390         if ($params{type} =~ /month/i) {
 391                 $calendar=format_month(%params);
 392         }
 393         elsif ($params{type} =~ /year/i) {
 394                 $calendar=format_year(%params);
 395         }
 396
 397         return "\n<div><div class=\"calendar\">$calendar</div></div>\n";
 398 } #}}
 399
 400 sub needsbuild (@) {
 401         my $needsbuild=shift;
 402         foreach my $page (keys %pagestate) {
 403                 if (exists $pagestate{$page}{calendar}{nextchange}) {
 404                         if ($pagestate{$page}{calendar}{nextchange} <= $time) {
 405                                 # force a rebuild so the calendar shows
 406                                 # the current day
 407                                 push @$needsbuild, $pagesources{$page};
 408                         }
 409                         if (exists $pagesources{$page} &&
 410                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
 411                                 # remove state, will be re-added if
 412                                 # the calendar is still there during the
 413                                 # rebuild
 414                                 delete $pagestate{$page}{calendar};
 415                         }
 416                 }
 417         }
 418 }
 419
 420 1