IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my (%backlinks, %rendered);
  11 our %brokenlinks;
  12 my $links_calculated=0;
  13
  14 sub calculate_links () {
  15         return if $links_calculated;
  16         %backlinks=%brokenlinks=();
  17         foreach my $page (keys %links) {
  18                 foreach my $link (@{$links{$page}}) {
  19                         my $bestlink=bestlink($page, $link);
  20                         if (length $bestlink) {
  21                                 $backlinks{$bestlink}{$page}=1
  22                                         if $bestlink ne $page;
  23                         }
  24                         else {
  25                                 push @{$brokenlinks{$link}}, $page;
  26                         }
  27                 }
  28         }
  29         $links_calculated=1;
  30 }
  31
  32 sub backlink_pages ($) {
  33         my $page=shift;
  34
  35         calculate_links();
  36
  37         return keys %{$backlinks{$page}};
  38 }
  39
  40 sub backlinks ($) {
  41         my $page=shift;
  42
  43         my @links;
  44         foreach my $p (backlink_pages($page)) {
  45                 my $href=urlto($p, $page);
  46
  47                 # Trim common dir prefixes from both pages.
  48                 my $p_trimmed=$p;
  49                 my $page_trimmed=$page;
  50                 my $dir;
  51                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  52                         defined $dir &&
  53                         $p_trimmed=~s/^\Q$dir\E// &&
  54                         $page_trimmed=~s/^\Q$dir\E//;
  55
  56                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  57         }
  58         return @links;
  59 }
  60
  61 sub genpage ($$) {
  62         my $page=shift;
  63         my $content=shift;
  64
  65         run_hooks(indexhtml => sub {
  66                 shift->(page => $page, destpage => $page, content => $content);
  67         });
  68
  69         my $templatefile;
  70         run_hooks(templatefile => sub {
  71                 return if defined $templatefile;
  72                 my $file=shift->(page => $page);
  73                 if (defined $file && defined template_file($file)) {
  74                         $templatefile=$file;
  75                 }
  76         });
  77         my $template;
  78         if (defined $templatefile) {
  79                 $template=template_depends($templatefile, $page,
  80                         blind_cache => 1);
  81         }
  82         else {
  83                 # no explicit depends as special case
  84                 $template=template('page.tmpl',
  85                         blind_cache => 1);
  86         }
  87
  88         my $actions=0;
  89         if (length $config{cgiurl}) {
  90                 if (IkiWiki->can("cgi_editpage")) {
  91                         $template->param(editurl => cgiurl(do => "edit", page => $page));
  92                         $actions++;
  93                 }
  94         }
  95         if (defined $config{historyurl} && length $config{historyurl}) {
  96                 my $u=$config{historyurl};
  97                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  98                 $template->param(historyurl => $u);
  99                 $actions++;
 100         }
 101         if ($config{discussion}) {
 102                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 103                    (length $config{cgiurl} ||
 104                     exists $links{$page."/".$config{discussionpage}})) {
 105                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
 106                         $actions++;
 107                 }
 108         }
 109         if ($actions) {
 110                 $template->param(have_actions => 1);
 111         }
 112         templateactions($template, $page);
 113
 114         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 115         my ($backlinks, $more_backlinks);
 116         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 117                 $backlinks=\@backlinks;
 118                 $more_backlinks=[];
 119         }
 120         else {
 121                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 122                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 123         }
 124
 125         $template->param(
 126                 title => $page eq 'index'
 127                         ? $config{wikiname}
 128                         : pagetitle(basename($page)),
 129                 wikiname => $config{wikiname},
 130                 content => $content,
 131                 backlinks => $backlinks,
 132                 more_backlinks => $more_backlinks,
 133                 mtime => displaytime($pagemtime{$page}),
 134                 ctime => displaytime($pagectime{$page}, undef, 1),
 135                 baseurl => baseurl($page),
 136                 html5 => $config{html5},
 137         );
 138
 139         run_hooks(pagetemplate => sub {
 140                 shift->(page => $page, destpage => $page, template => $template);
 141         });
 142
 143         $content=$template->output;
 144
 145         run_hooks(format => sub {
 146                 $content=shift->(
 147                         page => $page,
 148                         content => $content,
 149                 );
 150         });
 151
 152         return $content;
 153 }
 154
 155 sub scan ($) {
 156         my $file=shift;
 157
 158         debug(sprintf(gettext("scanning %s"), $file));
 159
 160         my $type=pagetype($file);
 161         if (defined $type) {
 162                 my $srcfile=srcfile($file);
 163                 my $content=readfile($srcfile);
 164                 my $page=pagename($file);
 165                 will_render($page, htmlpage($page), 1);
 166
 167                 if ($config{discussion}) {
 168                         # Discussion links are a special case since they're
 169                         # not in the text of the page, but on its template.
 170                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 171                 }
 172                 else {
 173                         $links{$page}=[];
 174                 }
 175                 delete $typedlinks{$page};
 176
 177                 run_hooks(scan => sub {
 178                         shift->(
 179                                 page => $page,
 180                                 content => $content,
 181                         );
 182                 });
 183
 184                 # Preprocess in scan-only mode.
 185                 preprocess($page, $page, $content, 1);
 186         }
 187         else {
 188                 will_render($file, $file, 1);
 189         }
 190 }
 191
 192 sub fast_file_copy (@) {
 193         my $srcfile=shift;
 194         my $destfile=shift;
 195         my $srcfd=shift;
 196         my $destfd=shift;
 197         my $cleanup=shift;
 198
 199         my $blksize = 16384;
 200         my ($len, $buf, $written);
 201         while ($len = sysread $srcfd, $buf, $blksize) {
 202                 if (! defined $len) {
 203                         next if $! =~ /^Interrupted/;
 204                         error("failed to read $srcfile: $!", $cleanup);
 205                 }
 206                 my $offset = 0;
 207                 while ($len) {
 208                         defined($written = syswrite $destfd, $buf, $len, $offset)
 209                                 or error("failed to write $destfile: $!", $cleanup);
 210                         $len -= $written;
 211                         $offset += $written;
 212                 }
 213         }
 214 }
 215
 216 sub render ($$) {
 217         my $file=shift;
 218         return if $rendered{$file};
 219         debug(shift);
 220         $rendered{$file}=1;
 221
 222         my $type=pagetype($file);
 223         my $srcfile=srcfile($file);
 224         if (defined $type) {
 225                 my $page=pagename($file);
 226                 delete $depends{$page};
 227                 delete $depends_simple{$page};
 228                 will_render($page, htmlpage($page), 1);
 229                 return if $type=~/^_/;
 230
 231                 my $content=htmlize($page, $page, $type,
 232                         linkify($page, $page,
 233                         preprocess($page, $page,
 234                         filter($page, $page,
 235                         readfile($srcfile)))));
 236
 237                 my $output=htmlpage($page);
 238                 writefile($output, $config{destdir}, genpage($page, $content));
 239         }
 240         else {
 241                 delete $depends{$file};
 242                 delete $depends_simple{$file};
 243                 will_render($file, $file, 1);
 244
 245                 if ($config{hardlink}) {
 246                         # only hardlink if owned by same user
 247                         my @stat=stat($srcfile);
 248                         if ($stat[4] == $>) {
 249                                 prep_writefile($file, $config{destdir});
 250                                 unlink($config{destdir}."/".$file);
 251                                 if (link($srcfile, $config{destdir}."/".$file)) {
 252                                         return;
 253                                 }
 254                         }
 255                         # if hardlink fails, fall back to copying
 256                 }
 257
 258                 my $srcfd=readfile($srcfile, 1, 1);
 259                 writefile($file, $config{destdir}, undef, 1, sub {
 260                         fast_file_copy($srcfile, $file, $srcfd, @_);
 261                 });
 262         }
 263 }
 264
 265 sub prune ($) {
 266         my $file=shift;
 267
 268         unlink($file);
 269         my $dir=dirname($file);
 270         while (rmdir($dir)) {
 271                 $dir=dirname($dir);
 272         }
 273 }
 274
 275 sub srcdir_check () {
 276         # security check, avoid following symlinks in the srcdir path by default
 277         my $test=$config{srcdir};
 278         while (length $test) {
 279                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 280                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 281                 }
 282                 unless ($test=~s/\/+$//) {
 283                         $test=dirname($test);
 284                 }
 285         }
 286
 287 }
 288
 289 sub find_src_files () {
 290         my @files;
 291         my %pages;
 292         eval q{use File::Find};
 293         error($@) if $@;
 294
 295         eval q{use Cwd};
 296         die $@ if $@;
 297         my $origdir=getcwd();
 298         my $abssrcdir=Cwd::abs_path($config{srcdir});
 299
 300         my ($page, $underlay);
 301         my $helper=sub {
 302                 my $file=decode_utf8($_);
 303
 304                 return if -l $file || -d _;
 305                 $file=~s/^\.\///;
 306                 return if ! length $file;
 307                 $page = pagename($file);
 308                 if (! exists $pagesources{$page} &&
 309                     file_pruned($file)) {
 310                         $File::Find::prune=1;
 311                         return;
 312                 }
 313
 314                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 315                 if (! defined $f) {
 316                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 317                         return;
 318                 }
 319
 320                 if ($underlay) {
 321                         # avoid underlaydir override attacks; see security.mdwn
 322                         if (! -l "$abssrcdir/$f" && ! -e _) {
 323                                 if (! $pages{$page}) {
 324                                         push @files, $f;
 325                                         $pages{$page}=1;
 326                                 }
 327                         }
 328                 }
 329                 else {
 330                         push @files, $f;
 331                         if ($pages{$page}) {
 332                                 debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 333                         }
 334                         $pages{$page}=1;
 335                 }
 336         };
 337
 338         chdir($config{srcdir}) || die "chdir: $!";
 339         find({
 340                 no_chdir => 1,
 341                 wanted => $helper,
 342         }, '.');
 343         chdir($origdir) || die "chdir: $!";
 344
 345         $underlay=1;
 346         foreach (@{$config{underlaydirs}}, $config{underlaydir}) {
 347                 chdir($_) || die "chdir: $!";
 348                 find({
 349                         no_chdir => 1,
 350                         wanted => $helper,
 351                 }, '.');
 352                 chdir($origdir) || die "chdir: $!";
 353         };
 354
 355         return \@files, \%pages;
 356 }
 357
 358 sub find_new_files ($) {
 359         my $files=shift;
 360         my @new;
 361         my @internal_new;
 362
 363         my $times_noted;
 364
 365         foreach my $file (@$files) {
 366                 my $page=pagename($file);
 367
 368                 if ($config{rcs} && $config{gettime} &&
 369                     -e "$config{srcdir}/$file") {
 370                         if (! $times_noted) {
 371                                 debug(sprintf(gettext("querying %s for file creation and modification times.."), $config{rcs}));
 372                                 $times_noted=1;
 373                         }
 374
 375                         eval {
 376                                 my $ctime=rcs_getctime("$config{srcdir}/$file");
 377                                 if ($ctime > 0) {
 378                                         $pagectime{$page}=$ctime;
 379                                 }
 380                         };
 381                         if ($@) {
 382                                 print STDERR $@;
 383                         }
 384                         my $mtime;
 385                         eval {
 386                                 $mtime=rcs_getmtime("$config{srcdir}/$file");
 387                         };
 388                         if ($@) {
 389                                 print STDERR $@;
 390                         }
 391                         elsif ($mtime > 0) {
 392                                 utime($mtime, $mtime, "$config{srcdir}/$file");
 393                         }
 394                 }
 395
 396                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 397                         # the page has changed its type
 398                         $forcerebuild{$page}=1;
 399                 }
 400                 $pagesources{$page}=$file;
 401                 if (! $pagemtime{$page}) {
 402                         if (isinternal($page)) {
 403                                 push @internal_new, $file;
 404                         }
 405                         else {
 406                                 push @new, $file;
 407                         }
 408                         $pagecase{lc $page}=$page;
 409                         if (! exists $pagectime{$page}) {
 410                                 $pagectime{$page}=(srcfile_stat($file))[10];
 411                         }
 412                 }
 413         }
 414
 415         return \@new, \@internal_new;
 416 }
 417
 418 sub find_del_files ($) {
 419         my $pages=shift;
 420         my @del;
 421         my @internal_del;
 422
 423         foreach my $page (keys %pagesources) {
 424                 if (! $pages->{$page}) {
 425                         if (isinternal($page)) {
 426                                 push @internal_del, $pagesources{$page};
 427                         }
 428                         else {
 429                                 push @del, $pagesources{$page};
 430                         }
 431                         $links{$page}=[];
 432                         delete $typedlinks{$page};
 433                         $renderedfiles{$page}=[];
 434                         $pagemtime{$page}=0;
 435                 }
 436         }
 437
 438         return \@del, \@internal_del;
 439 }
 440
 441 sub remove_del (@) {
 442         foreach my $file (@_) {
 443                 my $page=pagename($file);
 444                 if (! isinternal($page)) {
 445                         debug(sprintf(gettext("removing obsolete %s"), $page));
 446                 }
 447
 448                 foreach my $old (@{$oldrenderedfiles{$page}}) {
 449                         prune($config{destdir}."/".$old);
 450                 }
 451
 452                 foreach my $source (keys %destsources) {
 453                         if ($destsources{$source} eq $page) {
 454                                 delete $destsources{$source};
 455                         }
 456                 }
 457
 458                 delete $pagecase{lc $page};
 459                 $delpagesources{$page}=$pagesources{$page};
 460                 delete $pagesources{$page};
 461         }
 462 }
 463
 464 sub find_changed ($) {
 465         my $files=shift;
 466         my @changed;
 467         my @internal_changed;
 468         foreach my $file (@$files) {
 469                 my $page=pagename($file);
 470                 my ($srcfile, @stat)=srcfile_stat($file);
 471                 if (! exists $pagemtime{$page} ||
 472                     $stat[9] > $pagemtime{$page} ||
 473                     $forcerebuild{$page}) {
 474                         $pagemtime{$page}=$stat[9];
 475
 476                         if (isinternal($page)) {
 477                                 # Preprocess internal page in scan-only mode.
 478                                 preprocess($page, $page, readfile($srcfile), 1);
 479                                 push @internal_changed, $file;
 480                         }
 481                         else {
 482                                 push @changed, $file;
 483                         }
 484                 }
 485         }
 486         return \@changed, \@internal_changed;
 487 }
 488
 489 sub calculate_old_links ($$) {
 490         my ($changed, $del)=@_;
 491         my %oldlink_targets;
 492         foreach my $file (@$changed, @$del) {
 493                 my $page=pagename($file);
 494                 if (exists $oldlinks{$page}) {
 495                         foreach my $l (@{$oldlinks{$page}}) {
 496                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 497                         }
 498                 }
 499         }
 500         return \%oldlink_targets;
 501 }
 502
 503 sub derender_internal ($) {
 504         my $file=shift;
 505         my $page=pagename($file);
 506         delete $depends{$page};
 507         delete $depends_simple{$page};
 508         foreach my $old (@{$renderedfiles{$page}}) {
 509                 delete $destsources{$old};
 510         }
 511         $renderedfiles{$page}=[];
 512 }
 513
 514 sub render_linkers ($) {
 515         my $f=shift;
 516         my $p=pagename($f);
 517         foreach my $page (keys %{$backlinks{$p}}) {
 518                 my $file=$pagesources{$page};
 519                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 520         }
 521 }
 522
 523 sub remove_unrendered () {
 524         foreach my $src (keys %rendered) {
 525                 my $page=pagename($src);
 526                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 527                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 528                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 529                                 prune($config{destdir}."/".$file);
 530                         }
 531                 }
 532         }
 533 }
 534
 535 sub link_types_changed ($$) {
 536         # each is of the form { type => { link => 1 } }
 537         my $new = shift;
 538         my $old = shift;
 539
 540         return 0 if !defined $new && !defined $old;
 541         return 1 if (!defined $new && %$old) || (!defined $old && %$new);
 542
 543         while (my ($type, $links) = each %$new) {
 544                 foreach my $link (keys %$links) {
 545                         return 1 unless exists $old->{$type}{$link};
 546                 }
 547         }
 548
 549         while (my ($type, $links) = each %$old) {
 550                 foreach my $link (keys %$links) {
 551                         return 1 unless exists $new->{$type}{$link};
 552                 }
 553         }
 554
 555         return 0;
 556 }
 557
 558 sub calculate_changed_links ($$$) {
 559         my ($changed, $del, $oldlink_targets)=@_;
 560
 561         my (%backlinkchanged, %linkchangers);
 562
 563         foreach my $file (@$changed, @$del) {
 564                 my $page=pagename($file);
 565
 566                 if (exists $links{$page}) {
 567                         foreach my $l (@{$links{$page}}) {
 568                                 my $target=bestlink($page, $l);
 569                                 if (! exists $oldlink_targets->{$page}{$l} ||
 570                                     $target ne $oldlink_targets->{$page}{$l}) {
 571                                         $backlinkchanged{$target}=1;
 572                                         $linkchangers{lc($page)}=1;
 573                                 }
 574                                 delete $oldlink_targets->{$page}{$l};
 575                         }
 576                 }
 577                 if (exists $oldlink_targets->{$page} &&
 578                     %{$oldlink_targets->{$page}}) {
 579                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 580                                 $backlinkchanged{$target}=1;
 581                         }
 582                         $linkchangers{lc($page)}=1;
 583                 }
 584
 585                 # we currently assume that changing the type of a link doesn't
 586                 # change backlinks
 587                 if (!exists $linkchangers{lc($page)}) {
 588                         if (link_types_changed($typedlinks{$page}, $oldtypedlinks{$page})) {
 589                                 $linkchangers{lc($page)}=1;
 590                         }
 591                 }
 592         }
 593
 594         return \%backlinkchanged, \%linkchangers;
 595 }
 596
 597 sub render_dependent ($$$$$$$) {
 598         my ($files, $new, $internal_new, $del, $internal_del,
 599                 $internal_changed, $linkchangers)=@_;
 600
 601         my @changed=(keys %rendered, @$del);
 602         my @exists_changed=(@$new, @$del);
 603
 604         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 605         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 606
 607         foreach my $p ("templates/page.tmpl", keys %{$depends_simple{""}}) {
 608                 if ($rendered{$p} || grep { $_ eq $p } @$del) {
 609                         foreach my $f (@$files) {
 610                                 next if $rendered{$f};
 611                                 render($f, sprintf(gettext("building %s, which depends on %s"), $f, $p));
 612                         }
 613                         return 0;
 614                 }
 615         }
 616
 617         foreach my $f (@$files) {
 618                 next if $rendered{$f};
 619                 my $p=pagename($f);
 620                 my $reason = undef;
 621
 622                 if (exists $depends_simple{$p} && ! defined $reason) {
 623                         foreach my $d (keys %{$depends_simple{$p}}) {
 624                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 625                                      $lc_changed{$d})
 626                                     ||
 627                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 628                                      $lc_exists_changed{$d})
 629                                     ||
 630                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 631                                      $linkchangers->{$d})
 632                                 ) {
 633                                         $reason = $d;
 634                                         last;
 635                                 }
 636                         }
 637                 }
 638
 639                 if (exists $depends{$p} && ! defined $reason) {
 640                         foreach my $dep (keys %{$depends{$p}}) {
 641                                 my $sub=pagespec_translate($dep);
 642                                 next unless defined $sub;
 643
 644                                 # only consider internal files
 645                                 # if the page explicitly depends
 646                                 # on such files
 647                                 my $internal_dep=$dep =~ /(?:internal|comment|comment_pending)\(/;
 648
 649                                 my $in=sub {
 650                                         my $list=shift;
 651                                         my $type=shift;
 652                                         foreach my $file (@$list) {
 653                                                 next if $file eq $f;
 654                                                 my $page=pagename($file);
 655                                                 if ($sub->($page, location => $p)) {
 656                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 657                                                                 next unless $linkchangers->{lc($page)};
 658                                                         }
 659                                                         $reason=$page;
 660                                                         return 1;
 661                                                 }
 662                                         }
 663                                         return undef;
 664                                 };
 665
 666                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 667                                         last if $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 668                                         last if $internal_dep && (
 669                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 670                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 671                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT)
 672                                         );
 673                                 }
 674                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 675                                         last if $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 676                                         last if $internal_dep && (
 677                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 678                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE)
 679                                         );
 680                                 }
 681                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 682                                         last if $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 683                                         last if $internal_dep && (
 684                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 685                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 686                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS)
 687                                         );
 688                                 }
 689                         }
 690                 }
 691
 692                 if (defined $reason) {
 693                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 694                         return 1;
 695                 }
 696         }
 697
 698         return 0;
 699 }
 700
 701 sub render_backlinks ($) {
 702         my $backlinkchanged=shift;
 703         foreach my $link (keys %$backlinkchanged) {
 704                 my $linkfile=$pagesources{$link};
 705                 if (defined $linkfile) {
 706                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 707                 }
 708         }
 709 }
 710
 711 sub gen_autofile ($$$) {
 712         my $autofile=shift;
 713         my $pages=shift;
 714         my $del=shift;
 715
 716         if (file_pruned($autofile)) {
 717                 return;
 718         }
 719
 720         my ($file)="$config{srcdir}/$autofile" =~ /$config{wiki_file_regexp}/; # untaint
 721         if (! defined $file) {
 722                 return;
 723         }
 724
 725         # Remember autofiles that were tried, and never try them again later.
 726         if (exists $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}) {
 727                 return;
 728         }
 729         $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}=1;
 730
 731         if (srcfile($autofile, 1) || file_pruned($autofile)) {
 732                 return;
 733         }
 734
 735         if (-l $file || -d _ || -e _) {
 736                 return;
 737         }
 738
 739         my $page = pagename($file);
 740         if ($pages->{$page}) {
 741                 return;
 742         }
 743
 744         if (grep { $_ eq $autofile } @$del) {
 745                 return;
 746         }
 747
 748         $autofiles{$autofile}{generator}->();
 749         $pages->{$page}=1;
 750         return 1;
 751 }
 752
 753
 754 sub refresh () {
 755         srcdir_check();
 756         run_hooks(refresh => sub { shift->() });
 757         my ($files, $pages)=find_src_files();
 758         my ($new, $internal_new)=find_new_files($files);
 759         my ($del, $internal_del)=find_del_files($pages);
 760         my ($changed, $internal_changed)=find_changed($files);
 761         run_hooks(needsbuild => sub { shift->($changed) });
 762         my $oldlink_targets=calculate_old_links($changed, $del);
 763
 764         foreach my $file (@$changed) {
 765                 scan($file);
 766         }
 767
 768         foreach my $autofile (keys %autofiles) {
 769                 if (gen_autofile($autofile, $pages, $del)) {
 770                         push @{$files}, $autofile;
 771                         push @{$new}, $autofile if find_new_files([$autofile]);
 772                         push @{$changed}, $autofile if find_changed([$autofile]);
 773
 774                         scan($autofile);
 775                 }
 776         }
 777
 778         calculate_links();
 779
 780         remove_del(@$del, @$internal_del);
 781
 782         foreach my $file (@$changed) {
 783                 render($file, sprintf(gettext("building %s"), $file));
 784         }
 785         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 786                 derender_internal($file);
 787         }
 788
 789         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 790                 $del, $oldlink_targets);
 791
 792         foreach my $file (@$new, @$del) {
 793                 render_linkers($file);
 794         }
 795
 796         if (@$changed || @$internal_changed ||
 797             @$del || @$internal_del || @$internal_new) {
 798                 1 while render_dependent($files, $new, $internal_new,
 799                         $del, $internal_del, $internal_changed,
 800                         $linkchangers);
 801         }
 802
 803         render_backlinks($backlinkchanged);
 804         remove_unrendered();
 805
 806         if (@$del || @$internal_del) {
 807                 run_hooks(delete => sub { shift->(@$del, @$internal_del) });
 808         }
 809         if (%rendered) {
 810                 run_hooks(change => sub { shift->(keys %rendered) });
 811         }
 812 }
 813
 814 sub clean_rendered {
 815         lockwiki();
 816         loadindex();
 817         remove_unrendered();
 818         foreach my $page (keys %oldrenderedfiles) {
 819                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 820                         prune($config{destdir}."/".$file);
 821                 }
 822         }
 823 }
 824
 825 sub commandline_render () {
 826         lockwiki();
 827         loadindex();
 828         unlockwiki();
 829
 830         my $srcfile=possibly_foolish_untaint($config{render});
 831         my $file=$srcfile;
 832         $file=~s/\Q$config{srcdir}\E\/?//;
 833
 834         my $type=pagetype($file);
 835         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 836         my $content=readfile($srcfile);
 837         my $page=pagename($file);
 838         $pagesources{$page}=$file;
 839         $content=filter($page, $page, $content);
 840         $content=preprocess($page, $page, $content);
 841         $content=linkify($page, $page, $content);
 842         $content=htmlize($page, $page, $type, $content);
 843         $pagemtime{$page}=(stat($srcfile))[9];
 844         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 845
 846         print genpage($page, $content);
 847         exit 0;
 848 }
 849
 850 1