t/git-cgi.t

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4
   5 use Test::More;
   6
   7 BEGIN {
   8         my $git = `which git`;
   9         chomp $git;
  10         plan(skip_all => 'git not available') unless -x $git;
  11
  12         plan(skip_all => "CGI not available")
  13                 unless eval q{
  14                         use CGI qw();
  15                         1;
  16                 };
  17
  18         plan(skip_all => "IPC::Run not available")
  19                 unless eval q{
  20                         use IPC::Run qw(run);
  21                         1;
  22                 };
  23
  24         use_ok('IkiWiki');
  25         use_ok('YAML::XS');
  26 }
  27
  28 # We check for English error messages
  29 $ENV{LC_ALL} = 'C';
  30
  31 use Cwd qw(getcwd);
  32 use Errno qw(ENOENT);
  33
  34 my $installed = $ENV{INSTALLED_TESTS};
  35
  36 my @command;
  37 if ($installed) {
  38         @command = qw(ikiwiki);
  39 }
  40 else {
  41         ok(! system("make -s ikiwiki.out"));
  42         @command = ("perl", "-I".getcwd."/blib/lib", './ikiwiki.out',
  43                 '--underlaydir='.getcwd.'/underlays/basewiki',
  44                 '--set', 'underlaydirbase='.getcwd.'/underlays',
  45                 '--templatedir='.getcwd.'/templates');
  46 }
  47
  48 sub write_old_file {
  49         my $name = shift;
  50         my $dir = shift;
  51         my $content = shift;
  52         writefile($name, $dir, $content);
  53         ok(utime(333333333, 333333333, "$dir/$name"));
  54 }
  55
  56 sub write_setup_file {
  57         my %setup = (
  58                 wikiname => 'this is the name of my wiki',
  59                 srcdir => getcwd.'/t/tmp/in/doc',
  60                 destdir => getcwd.'/t/tmp/out',
  61                 url => 'http://example.com',
  62                 cgiurl => 'http://example.com/cgi-bin/ikiwiki.cgi',
  63                 cgi_wrapper => getcwd.'/t/tmp/ikiwiki.cgi',
  64                 cgi_wrappermode => '0751',
  65                 add_plugins => [qw(anonok attachment lockedit recentchanges)],
  66                 disable_plugins => [qw(emailauth openid passwordauth)],
  67                 anonok_pagespec => 'writable/*',
  68                 locked_pages => '!writable/*',
  69                 rcs => 'git',
  70                 git_wrapper => getcwd.'/t/tmp/in/.git/hooks/post-commit',
  71                 git_wrappermode => '0754',
  72                 gitorigin_branch => '',
  73         );
  74         unless ($installed) {
  75                 $setup{ENV} = { 'PERL5LIB' => getcwd.'/blib/lib' };
  76         }
  77         writefile("test.setup", "t/tmp",
  78                 "# IkiWiki::Setup::Yaml - YAML formatted setup file\n" .
  79                 Dump(\%setup));
  80 }
  81
  82 sub thoroughly_rebuild {
  83         ok(unlink("t/tmp/ikiwiki.cgi") || $!{ENOENT});
  84         ok(unlink("t/tmp/in/.git/hooks/post-commit") || $!{ENOENT});
  85         ok(! system(@command, qw(--setup t/tmp/test.setup --rebuild --wrappers)));
  86 }
  87
  88 sub check_cgi_mode_bits {
  89         my $mode;
  90
  91         (undef, undef, $mode, undef, undef,
  92                 undef, undef, undef, undef, undef,
  93                 undef, undef, undef) = stat('t/tmp/ikiwiki.cgi');
  94         is ($mode & 07777, 0751);
  95         (undef, undef, $mode, undef, undef,
  96                 undef, undef, undef, undef, undef,
  97                 undef, undef, undef) = stat('t/tmp/in/.git/hooks/post-commit');
  98         is ($mode & 07777, 0754);
  99 }
 100
 101 sub run_cgi {
 102         my (%args) = @_;
 103         my ($in, $out);
 104         my $method = $args{method} || 'GET';
 105         my $environ = $args{environ} || {};
 106         my $params = $args{params} || { do => 'prefs' };
 107
 108         my %defaults = (
 109                 SCRIPT_NAME     => '/cgi-bin/ikiwiki.cgi',
 110                 HTTP_HOST       => 'example.com',
 111         );
 112
 113         my $cgi = CGI->new($args{params});
 114         my $query_string = $cgi->query_string();
 115         diag $query_string;
 116
 117         if ($method eq 'POST') {
 118                 $defaults{REQUEST_METHOD} = 'POST';
 119                 $in = $query_string;
 120                 $defaults{CONTENT_LENGTH} = length $in;
 121         } else {
 122                 $defaults{REQUEST_METHOD} = 'GET';
 123                 $defaults{QUERY_STRING} = $query_string;
 124         }
 125
 126         my %envvars = (
 127                 %defaults,
 128                 %$environ,
 129         );
 130         run(["./t/tmp/ikiwiki.cgi"], \$in, \$out, init => sub {
 131                 map {
 132                         $ENV{$_} = $envvars{$_}
 133                 } keys(%envvars);
 134         });
 135
 136         return $out;
 137 }
 138
 139 sub run_git {
 140         my (undef, $filename, $line) = caller;
 141         my $args = shift;
 142         my $desc = shift || join(' ', 'git', @$args);
 143         my ($in, $out);
 144         ok(run(['git', @$args], \$in, \$out, init => sub {
 145                 chdir 't/tmp/in' or die $!;
 146                 my $name = 'The IkiWiki Tests';
 147                 my $email = 'nobody@ikiwiki-tests.invalid';
 148                 if ($args->[0] eq 'commit') {
 149                         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
 150                         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
 151                 }
 152         }), "$desc at $filename:$line");
 153         return $out;
 154 }
 155
 156 sub test {
 157         my $content;
 158         my $status;
 159
 160         ok(! system(qw(rm -rf t/tmp)));
 161         ok(! system(qw(mkdir t/tmp)));
 162
 163         write_old_file('.gitignore', 't/tmp/in', "/doc/.ikiwiki/\n");
 164         write_old_file('doc/writable/one.mdwn', 't/tmp/in', 'This is the first test page');
 165         write_old_file('doc/writable/two.mdwn', 't/tmp/in', 'This is the second test page');
 166         write_old_file('doc/writable/three.mdwn', 't/tmp/in', 'This is the third test page');
 167         write_old_file('doc/writable/three.bin', 't/tmp/in', 'An attachment');
 168
 169         unless ($installed) {
 170                 ok(! system(qw(cp -pRL doc/wikiicons t/tmp/in/doc/)));
 171                 ok(! system(qw(cp -pRL doc/recentchanges.mdwn t/tmp/in/doc/)));
 172         }
 173
 174         run_git(['init']);
 175         run_git(['add', '.']);
 176         run_git(['commit', '-m', 'Initial commit']);
 177
 178         write_setup_file();
 179         thoroughly_rebuild();
 180         check_cgi_mode_bits();
 181
 182         ok(-e 't/tmp/out/writable/one/index.html');
 183         $content = readfile('t/tmp/out/writable/one/index.html');
 184         like($content, qr{This is the first test page});
 185         my $orig_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 186
 187         # We have to wait 1 second here so that new writes are guaranteed
 188         # to have a strictly larger mtime.
 189         sleep 1;
 190
 191         # Test the git hook, which accepts git commits
 192         writefile('doc/writable/one.mdwn', 't/tmp/in',
 193                 'This is new content for the first test page');
 194         run_git(['add', '.']);
 195         run_git(['commit', '-m', 'Git commit']);
 196         my $first_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 197         isnt($orig_sha1, $first_revertable_sha1);
 198
 199         ok(-e 't/tmp/out/writable/one/index.html');
 200         $content = readfile('t/tmp/out/writable/one/index.html');
 201         like($content, qr{This is new content for the first test page});
 202
 203         # Test a web commit
 204         $content = run_cgi(method => 'POST',
 205                 params => {
 206                         do => 'edit',
 207                         page => 'writable/two',
 208                         type => 'mdwn',
 209                         editmessage => 'Web commit',
 210                         editcontent => 'Here is new content for the second page',
 211                         _submit => 'Save Page',
 212                         _submitted => '1',
 213                 },
 214         );
 215         like($content, qr{^Status:\s*302\s}m);
 216         like($content, qr{^Location:\s*http://example\.com/writable/two/\?updated}m);
 217         my $second_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 218         isnt($orig_sha1, $second_revertable_sha1);
 219         isnt($first_revertable_sha1, $second_revertable_sha1);
 220
 221         ok(-e 't/tmp/out/writable/two/index.html');
 222         $content = readfile('t/tmp/out/writable/two/index.html');
 223         like($content, qr{Here is new content for the second page});
 224
 225         # Another edit
 226         writefile('doc/writable/three.mdwn', 't/tmp/in',
 227                 'Also new content for the third page');
 228         unlink('t/tmp/in/doc/writable/three.bin');
 229         writefile('doc/writable/three.bin', 't/tmp/in',
 230                 'Changed attachment');
 231         run_git(['add', '.']);
 232         run_git(['commit', '-m', 'Git commit']);
 233         ok(-e 't/tmp/out/writable/three/index.html');
 234         $content = readfile('t/tmp/out/writable/three/index.html');
 235         like($content, qr{Also new content for the third page});
 236         $content = readfile('t/tmp/out/writable/three.bin');
 237         like($content, qr{Changed attachment});
 238         my $third_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 239         isnt($orig_sha1, $third_revertable_sha1);
 240         isnt($second_revertable_sha1, $third_revertable_sha1);
 241
 242         run_git(['mv', 'doc/writable/one.mdwn', 'doc/one.mdwn']);
 243         run_git(['mv', 'doc/writable/two.mdwn', 'two.mdwn']);
 244         run_git(['commit', '-m', 'Rename files to test CVE-2016-10026']);
 245         ok(! -e 't/tmp/out/writable/two/index.html');
 246         ok(! -e 't/tmp/out/writable/one/index.html');
 247         ok(-e 't/tmp/out/one/index.html');
 248         my $sha1_before_revert = run_git(['rev-list', '--max-count=1', 'HEAD']);
 249         isnt($sha1_before_revert, $third_revertable_sha1);
 250
 251         $content = run_cgi(method => 'post',
 252                 params => {
 253                         do => 'revert',
 254                         revertmessage => 'CVE-2016-10026',
 255                         rev => $first_revertable_sha1,
 256                         _submit => 'Revert',
 257                         _submitted_revert => '1',
 258                 },
 259         );
 260         like($content, qr{is locked and cannot be edited});
 261         # The tree is left clean
 262         run_git(['diff', '--exit-code']);
 263         run_git(['diff', '--cached', '--exit-code']);
 264         my $sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 265         is($sha1, $sha1_before_revert);
 266
 267         ok(-e 't/tmp/out/one/index.html');
 268         ok(! -e 't/tmp/in/doc/writable/one.mdwn');
 269         ok(-e 't/tmp/in/doc/one.mdwn');
 270         $content = readfile('t/tmp/out/one/index.html');
 271         like($content, qr{This is new content for the first test page});
 272
 273         $content = run_cgi(method => 'post',
 274                 params => {
 275                         do => 'revert',
 276                         revertmessage => 'CVE-2016-10026',
 277                         rev => $second_revertable_sha1,
 278                         _submit => 'Revert',
 279                         _submitted_revert => '1',
 280                 },
 281         );
 282         like($content, qr{you are not allowed to change two\.mdwn});
 283         run_git(['diff', '--exit-code']);
 284         run_git(['diff', '--cached', '--exit-code']);
 285         $sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 286         is($sha1, $sha1_before_revert);
 287
 288         ok(! -e 't/tmp/out/writable/two/index.html');
 289         ok(! -e 't/tmp/out/two/index.html');
 290         ok(! -e 't/tmp/in/doc/writable/two.mdwn');
 291         ok(-e 't/tmp/in/two.mdwn');
 292         $content = readfile('t/tmp/in/two.mdwn');
 293         like($content, qr{Here is new content for the second page});
 294
 295         # We have to wait 1 second here so that new writes are guaranteed
 296         # to have a strictly larger mtime.
 297         sleep 1;
 298
 299         # This one can legitimately be reverted
 300         $content = run_cgi(method => 'post',
 301                 params => {
 302                         do => 'revert',
 303                         revertmessage => 'not CVE-2016-10026',
 304                         rev => $third_revertable_sha1,
 305                         _submit => 'Revert',
 306                         _submitted_revert => '1',
 307                 },
 308         );
 309         like($content, qr{^Status:\s*302\s}m);
 310         like($content, qr{^Location:\s*http://example\.com/recentchanges/}m);
 311         run_git(['diff', '--exit-code']);
 312         run_git(['diff', '--cached', '--exit-code']);
 313         ok(-e 't/tmp/out/writable/three/index.html');
 314         $content = readfile('t/tmp/out/writable/three/index.html');
 315         like($content, qr{This is the third test page});
 316         $content = readfile('t/tmp/out/writable/three.bin');
 317         like($content, qr{An attachment});
 318 }
 319
 320 test();
 321
 322 done_testing();