IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("istranslatable");
  27 memoize("_istranslation");
  28 memoize("percenttranslated");
  29
  30 sub import {
  31         hook(type => "getsetup", id => "po", call => \&getsetup);
  32         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  33         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  34         hook(type => "scan", id => "po", call => \&scan, last =>1);
  35         hook(type => "filter", id => "po", call => \&filter);
  36         hook(type => "htmlize", id => "po", call => \&htmlize);
  37         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  38         hook(type => "postscan", id => "po", call => \&postscan);
  39         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  40         hook(type => "delete", id => "po", call => \&mydelete);
  41         hook(type => "change", id => "po", call => \&change);
  42         hook(type => "canremove", id => "po", call => \&canremove);
  43         hook(type => "canrename", id => "po", call => \&canrename);
  44         hook(type => "editcontent", id => "po", call => \&editcontent);
  45
  46         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  47         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  48         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  49         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  50         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  51         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  52         $origsubs{'urlto'}=\&IkiWiki::urlto;
  53         inject(name => "IkiWiki::urlto", call => \&myurlto);
  54         $origsubs{'nicepagetitle'}=\&IkiWiki::nicepagetitle;
  55         inject(name => "IkiWiki::nicepagetitle", call => \&mynicepagetitle);
  56 }
  57
  58
  59 # ,----
  60 # | Table of contents
  61 # `----
  62
  63 # 1. Hooks
  64 # 2. Injected functions
  65 # 3. Blackboxes for private data
  66 # 4. Helper functions
  67 # 5. PageSpec's
  68
  69
  70 # ,----
  71 # | Hooks
  72 # `----
  73
  74 sub getsetup () {
  75         return
  76                 plugin => {
  77                         safe => 0,
  78                         rebuild => 1,
  79                 },
  80                 po_master_language => {
  81                         type => "string",
  82                         example => {
  83                                 'code' => 'en',
  84                                 'name' => 'English'
  85                         },
  86                         description => "master language (non-PO files)",
  87                         safe => 1,
  88                         rebuild => 1,
  89                 },
  90                 po_slave_languages => {
  91                         type => "string",
  92                         example => {
  93                                 'fr' => 'Français',
  94                                 'es' => 'Castellano',
  95                                 'de' => 'Deutsch'
  96                         },
  97                         description => "slave languages (PO files)",
  98                         safe => 1,
  99                         rebuild => 1,
 100                 },
 101                 po_translatable_pages => {
 102                         type => "pagespec",
 103                         example => "!*/Discussion",
 104                         description => "PageSpec controlling which pages are translatable",
 105                         link => "ikiwiki/PageSpec",
 106                         safe => 1,
 107                         rebuild => 1,
 108                 },
 109                 po_link_to => {
 110                         type => "string",
 111                         example => "current",
 112                         description => "internal linking behavior (default/current/negotiated)",
 113                         safe => 1,
 114                         rebuild => 1,
 115                 },
 116                 po_translation_status_in_links => {
 117                         type => "boolean",
 118                         example => 1,
 119                         description => "display translation status in links to translations",
 120                         safe => 1,
 121                         rebuild => 1,
 122                 },
 123 }
 124
 125 sub checkconfig () {
 126         foreach my $field (qw{po_master_language po_slave_languages}) {
 127                 if (! exists $config{$field} || ! defined $config{$field}) {
 128                         error(sprintf(gettext("Must specify %s"), $field));
 129                 }
 130         }
 131         if (! (keys %{$config{po_slave_languages}})) {
 132                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 133         }
 134         map {
 135                 islanguagecode($_)
 136                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 137         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 138         if (! exists $config{po_translatable_pages} ||
 139             ! defined $config{po_translatable_pages}) {
 140                 $config{po_translatable_pages}="";
 141         }
 142         if (! exists $config{po_link_to} ||
 143             ! defined $config{po_link_to}) {
 144                 $config{po_link_to}='default';
 145         }
 146         elsif (! grep {
 147                         $config{po_link_to} eq $_
 148                 } ('default', 'current', 'negotiated')) {
 149                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 150                                 $config{po_link_to}));
 151                 $config{po_link_to}='default';
 152         }
 153         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 154                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 155                 $config{po_link_to}='default';
 156         }
 157         if (! exists $config{po_translation_status_in_links} ||
 158             ! defined $config{po_translation_status_in_links}) {
 159                 $config{po_translation_status_in_links}=1;
 160         }
 161         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 162 }
 163
 164 sub needsbuild () {
 165         my $needsbuild=shift;
 166
 167         # backup @needsbuild content so that change() can know whether
 168         # a given master page was rendered because its source file was changed
 169         @origneedsbuild=(@$needsbuild);
 170
 171         flushmemoizecache();
 172         buildtranslationscache();
 173
 174         # make existing translations depend on the corresponding master page
 175         foreach my $master (keys %translations) {
 176                 map add_depends($_, $master), values %{otherlanguages($master)};
 177         }
 178 }
 179
 180 # Massage the recorded state of internal links so that:
 181 # - it matches the actually generated links, rather than the links as written
 182 #   in the pages' source
 183 # - backlinks are consistent in all cases
 184 sub scan (@) {
 185         my %params=@_;
 186         my $page=$params{page};
 187         my $content=$params{content};
 188
 189         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 190
 191         if (istranslation($page)) {
 192                 foreach my $destpage (@{$links{$page}}) {
 193                         if (istranslatable($destpage)) {
 194                                 # replace one occurence of $destpage in $links{$page}
 195                                 # (we only want to replace the one that was added by
 196                                 # IkiWiki::Plugin::link::scan, other occurences may be
 197                                 # there for other reasons)
 198                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 199                                         if (@{$links{$page}}[$i] eq $destpage) {
 200                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 201                                                 last;
 202                                         }
 203                                 }
 204                         }
 205                 }
 206         }
 207         elsif (! istranslatable($page) && ! istranslation($page)) {
 208                 foreach my $destpage (@{$links{$page}}) {
 209                         if (istranslatable($destpage)) {
 210                                 # make sure any destpage's translations has
 211                                 # $page in its backlinks
 212                                 push @{$links{$page}},
 213                                         values %{otherlanguages($destpage)};
 214                         }
 215                 }
 216         }
 217 }
 218
 219 # We use filter to convert PO to the master page's format,
 220 # since the rest of ikiwiki should not work on PO files.
 221 sub filter (@) {
 222         my %params = @_;
 223
 224         my $page = $params{page};
 225         my $destpage = $params{destpage};
 226         my $content = decode_utf8(encode_utf8($params{content}));
 227
 228         return $content if ( ! istranslation($page)
 229                              || alreadyfiltered($page, $destpage) );
 230
 231         # CRLF line terminators make poor Locale::Po4a feel bad
 232         $content=~s/\r\n/\n/g;
 233
 234         # There are incompatibilities between some File::Temp versions
 235         # (including 0.18, bundled with Lenny's perl-modules package)
 236         # and others (e.g. 0.20, previously present in the archive as
 237         # a standalone package): under certain circumstances, some
 238         # return a relative filename, whereas others return an absolute one;
 239         # we here use this module in a way that is at least compatible
 240         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
 241         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 242                                     DIR => File::Spec->tmpdir,
 243                                     UNLINK => 1)->filename;
 244         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 245                                      DIR => File::Spec->tmpdir,
 246                                      UNLINK => 1)->filename;
 247
 248         writefile(basename($infile), File::Spec->tmpdir, $content);
 249
 250         my $masterfile = srcfile($pagesources{masterpage($page)});
 251         my %options = (
 252                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 253         );
 254         my $doc=Locale::Po4a::Chooser::new('text',%options);
 255         $doc->process(
 256                 'po_in_name'    => [ $infile ],
 257                 'file_in_name'  => [ $masterfile ],
 258                 'file_in_charset'  => 'utf-8',
 259                 'file_out_charset' => 'utf-8',
 260         ) or error("[po/filter:$page]: failed to translate");
 261         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 262         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 263
 264         # Unlinking should happen automatically, thanks to File::Temp,
 265         # but it does not work here, probably because of the way writefile()
 266         # and Locale::Po4a::write() work.
 267         unlink $infile, $outfile;
 268
 269         setalreadyfiltered($page, $destpage);
 270         return $content;
 271 }
 272
 273 sub htmlize (@) {
 274         my %params=@_;
 275
 276         my $page = $params{page};
 277         my $content = $params{content};
 278
 279         # ignore PO files this plugin did not create
 280         return $content unless istranslation($page);
 281
 282         # force content to be htmlize'd as if it was the same type as the master page
 283         return IkiWiki::htmlize($page, $page,
 284                                 pagetype(srcfile($pagesources{masterpage($page)})),
 285                                 $content);
 286 }
 287
 288 sub pagetemplate (@) {
 289         my %params=@_;
 290         my $page=$params{page};
 291         my $destpage=$params{destpage};
 292         my $template=$params{template};
 293
 294         my ($masterpage, $lang) = istranslation($page);
 295
 296         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 297                 $template->param(percenttranslated => percenttranslated($page));
 298         }
 299         if ($template->query(name => "istranslation")) {
 300                 $template->param(istranslation => scalar istranslation($page));
 301         }
 302         if ($template->query(name => "istranslatable")) {
 303                 $template->param(istranslatable => istranslatable($page));
 304         }
 305         if ($template->query(name => "HOMEPAGEURL")) {
 306                 $template->param(homepageurl => homepageurl($page));
 307         }
 308         if ($template->query(name => "otherlanguages")) {
 309                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 310                 map add_depends($page, $_), (values %{otherlanguages($page)});
 311         }
 312         # Rely on IkiWiki::Render's genpage() to decide wether
 313         # a discussion link should appear on $page; this is not
 314         # totally accurate, though: some broken links may be generated
 315         # when cgiurl is disabled.
 316         # This compromise avoids some code duplication, and will probably
 317         # prevent future breakage when ikiwiki internals change.
 318         # Known limitations are preferred to future random bugs.
 319         if ($template->param('discussionlink') && istranslation($page)) {
 320                 $template->param('discussionlink' => htmllink(
 321                                                         $page,
 322                                                         $destpage,
 323                                                         $masterpage . '/' . gettext("Discussion"),
 324                                                         noimageinline => 1,
 325                                                         forcesubpage => 0,
 326                                                         linktext => gettext("Discussion"),
 327                                                         ));
 328         }
 329         # Remove broken parentlink to ./index.html on home page's translations.
 330         # It works because this hook has the "last" parameter set, to ensure it
 331         # runs after parentlinks' own pagetemplate hook.
 332         if ($template->param('parentlinks')
 333             && istranslation($page)
 334             && $masterpage eq "index") {
 335                 $template->param('parentlinks' => []);
 336         }
 337 } # }}}
 338
 339 sub postscan (@) {
 340         my %params = @_;
 341         my $page = $params{page};
 342
 343         # backlinks involve back-dependencies, so that nicepagetitle effects,
 344         # such as translation status displayed in links, are updated
 345         use IkiWiki::Render;
 346         map add_depends($page, $_), keys %{$IkiWiki::backlinks{$page}};
 347 }
 348
 349 # Add the renamed page translations to the list of to-be-renamed pages.
 350 sub renamepages($$$) {
 351         my ($torename, $cgi, $session) = (shift, shift, shift);
 352
 353         # copy the initial array, so that we can iterate on it AND
 354         # modify it at the same time, without iterating on the items we
 355         # pushed on it ourselves
 356         my @torename=@{$torename};
 357
 358         # Save the page(s) the user asked to rename, so that our
 359         # canrename hook can tell the difference between:
 360         #  - a translation being renamed as a consequence of its master page
 361         #    being renamed
 362         #  - a user trying to directly rename a translation
 363         # This is why this hook has to be run first, before @torename is modified
 364         # by other plugins.
 365         $session->param(po_orig_torename => [ @torename ]);
 366         IkiWiki::cgi_savesession($session);
 367
 368         foreach my $rename (@torename) {
 369                 next unless istranslatable($rename->{src});
 370                 my %otherpages=%{otherlanguages($rename->{src})};
 371                 while (my ($lang, $otherpage) = each %otherpages) {
 372                         push @{$torename}, {
 373                                 src => $otherpage,
 374                                 srcfile => $pagesources{$otherpage},
 375                                 dest => otherlanguage($rename->{dest}, $lang),
 376                                 destfile => $rename->{dest}.".".$lang.".po",
 377                                 required => 0,
 378                         };
 379                 }
 380         }
 381 }
 382
 383 sub mydelete(@) {
 384         my @deleted=@_;
 385
 386         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 387 }
 388
 389 sub change(@) {
 390         my @rendered=@_;
 391
 392         my $updated_po_files=0;
 393
 394         # Refresh/create POT and PO files as needed.
 395         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 396                 my $page=pagename($file);
 397                 my $masterfile=srcfile($file);
 398                 my $updated_pot_file=0;
 399                 # Only refresh Pot file if it does not exist, or if
 400                 # $pagesources{$page} was changed: don't if only the HTML was
 401                 # refreshed, e.g. because of a dependency.
 402                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 403                     || ! -e potfile($masterfile)) {
 404                         refreshpot($masterfile);
 405                         $updated_pot_file=1;
 406                 }
 407                 my @pofiles;
 408                 map {
 409                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 410                 } (pofiles($masterfile));
 411                 if (@pofiles) {
 412                         refreshpofiles($masterfile, @pofiles);
 413                         map { IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 414                         $updated_po_files=1;
 415                 }
 416         }
 417
 418         if ($updated_po_files) {
 419                 commit_and_refresh(
 420                         gettext("updated PO files"),
 421                         "IkiWiki::Plugin::po::change");
 422         }
 423 }
 424
 425 sub canremove ($$$) {
 426         my ($page, $cgi, $session) = (shift, shift, shift);
 427
 428         if (istranslation($page)) {
 429                 return gettext("Can not remove a translation. Removing the master page, ".
 430                                "though, removes its translations as well.");
 431         }
 432         return undef;
 433 }
 434
 435 sub canrename ($$@) {
 436         my ($cgi, $session) = (shift, shift);
 437         my %params = @_;
 438
 439         if (istranslation($params{src})) {
 440                 my $masterpage = masterpage($params{src});
 441                 # Tell the difference between:
 442                 #  - a translation being renamed as a consequence of its master page
 443                 #    being renamed, which is allowed
 444                 #  - a user trying to directly rename a translation, which is forbidden
 445                 # by looking for the master page in the list of to-be-renamed pages we
 446                 # saved early in the renaming process.
 447                 my $orig_torename = $session->param("po_orig_torename");
 448                 unless (scalar grep { $_->{src} eq $masterpage } @{$orig_torename}) {
 449                         return gettext("Can not rename a translation. Renaming the master page, ".
 450                                        "though, renames its translations as well.");
 451                 }
 452         }
 453         return undef;
 454 }
 455
 456 # As we're previewing or saving a page, the content may have
 457 # changed, so tell the next filter() invocation it must not be lazy.
 458 sub editcontent () {
 459         my %params=@_;
 460
 461         unsetalreadyfiltered($params{page}, $params{page});
 462         return $params{content};
 463 }
 464
 465
 466 # ,----
 467 # | Injected functions
 468 # `----
 469
 470 # Implement po_link_to 'current' and 'negotiated' settings.
 471 sub mybestlink ($$) {
 472         my $page=shift;
 473         my $link=shift;
 474
 475         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 476         if (length $res
 477             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 478             && istranslatable($res)
 479             && istranslation($page)) {
 480                 return $res . "." . lang($page);
 481         }
 482         return $res;
 483 }
 484
 485 sub mybeautify_urlpath ($) {
 486         my $url=shift;
 487
 488         my $res=$origsubs{'beautify_urlpath'}->($url);
 489         if ($config{po_link_to} eq "negotiated") {
 490                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 491                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 492                 map {
 493                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 494                 } (keys %{$config{po_slave_languages}});
 495         }
 496         return $res;
 497 }
 498
 499 sub mytargetpage ($$) {
 500         my $page=shift;
 501         my $ext=shift;
 502
 503         if (istranslation($page) || istranslatable($page)) {
 504                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 505                 if (! $config{usedirs} || $masterpage eq 'index') {
 506                         return $masterpage . "." . $lang . "." . $ext;
 507                 }
 508                 else {
 509                         return $masterpage . "/index." . $lang . "." . $ext;
 510                 }
 511         }
 512         return $origsubs{'targetpage'}->($page, $ext);
 513 }
 514
 515 sub myurlto ($$;$) {
 516         my $to=shift;
 517         my $from=shift;
 518         my $absolute=shift;
 519
 520         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 521         if (! length $to
 522             && $config{po_link_to} eq "current"
 523             && istranslatable('index')) {
 524                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 525         }
 526         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 527         # so that one is redirected to the just-edited page rather than to the
 528         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 529         # we only do so when our beautify_urlpath would actually do what we want to
 530         # avoid, i.e. when po_link_to = negotiated
 531         if ($config{po_link_to} eq "negotiated") {
 532                 my @caller = caller(1);
 533                 my $run_by_editpage = 0;
 534                 $run_by_editpage = 1 if (exists $caller[3] && defined $caller[3]
 535                                          && $caller[3] eq "IkiWiki::cgi_editpage");
 536                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 537                         if $run_by_editpage;
 538                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 539                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 540                         if $run_by_editpage;
 541                 return $res;
 542         }
 543         else {
 544                 return $origsubs{'urlto'}->($to,$from,$absolute)
 545         }
 546 }
 547
 548 sub mynicepagetitle ($;$) {
 549         my ($page, $unescaped) = (shift, shift);
 550
 551         my $res = $origsubs{'nicepagetitle'}->($page, $unescaped);
 552         return $res unless istranslation($page);
 553         return $res unless $config{po_translation_status_in_links};
 554         return $res.' ('.percenttranslated($page).' %)';
 555 }
 556
 557 # ,----
 558 # | Blackboxes for private data
 559 # `----
 560
 561 {
 562         my %filtered;
 563
 564         sub alreadyfiltered($$) {
 565                 my $page=shift;
 566                 my $destpage=shift;
 567
 568                 return ( exists $filtered{$page}{$destpage}
 569                          && $filtered{$page}{$destpage} eq 1 );
 570         }
 571
 572         sub setalreadyfiltered($$) {
 573                 my $page=shift;
 574                 my $destpage=shift;
 575
 576                 $filtered{$page}{$destpage}=1;
 577         }
 578
 579         sub unsetalreadyfiltered($$) {
 580                 my $page=shift;
 581                 my $destpage=shift;
 582
 583                 if (exists $filtered{$page}{$destpage}) {
 584                         delete $filtered{$page}{$destpage};
 585                 }
 586         }
 587
 588         sub resetalreadyfiltered() {
 589                 undef %filtered;
 590         }
 591 }
 592
 593 # ,----
 594 # | Helper functions
 595 # `----
 596
 597 sub maybe_add_leading_slash ($;$) {
 598         my $str=shift;
 599         my $add=shift;
 600         $add=1 unless defined $add;
 601         return '/' . $str if $add;
 602         return $str;
 603 }
 604
 605 sub istranslatablefile ($) {
 606         my $file=shift;
 607
 608         return 0 unless defined $file;
 609         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 610         return 0 if $file =~ /\.pot$/;
 611         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 612         return;
 613 }
 614
 615 sub istranslatable ($) {
 616         my $page=shift;
 617
 618         $page=~s#^/##;
 619         return 1 if istranslatablefile($pagesources{$page});
 620         return;
 621 }
 622
 623 sub _istranslation ($) {
 624         my $page=shift;
 625
 626         my $hasleadingslash = ($page=~s#^/##);
 627         my $file=$pagesources{$page};
 628         return 0 unless (defined $file
 629                          && defined pagetype($file)
 630                          && pagetype($file) eq 'po');
 631         return 0 if $file =~ /\.pot$/;
 632
 633         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 634         return 0 unless (defined $masterpage && defined $lang
 635                          && length $masterpage && length $lang
 636                          && defined $pagesources{$masterpage}
 637                          && defined $config{po_slave_languages}{$lang});
 638
 639         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 640                 if istranslatable($masterpage);
 641 }
 642
 643 sub istranslation ($) {
 644         my $page=shift;
 645
 646         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 647                 my $hasleadingslash = ($masterpage=~s#^/##);
 648                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 649                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 650         }
 651         return;
 652 }
 653
 654 sub masterpage ($) {
 655         my $page=shift;
 656
 657         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 658                 return $masterpage;
 659         }
 660         return $page;
 661 }
 662
 663 sub lang ($) {
 664         my $page=shift;
 665
 666         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 667                 return $lang;
 668         }
 669         return $config{po_master_language}{code};
 670 }
 671
 672 sub islanguagecode ($) {
 673         my $code=shift;
 674
 675         return ($code =~ /^[a-z]{2}$/);
 676 }
 677
 678 sub otherlanguage ($$) {
 679         my $page=shift;
 680         my $code=shift;
 681
 682         return masterpage($page) if $code eq $config{po_master_language}{code};
 683         return masterpage($page) . '.' . $code;
 684 }
 685
 686 sub otherlanguages ($) {
 687         my $page=shift;
 688
 689         my %ret;
 690         return \%ret unless (istranslation($page) || istranslatable($page));
 691         my $curlang=lang($page);
 692         foreach my $lang
 693                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 694                 next if $lang eq $curlang;
 695                 $ret{$lang}=otherlanguage($page, $lang);
 696         }
 697         return \%ret;
 698 }
 699
 700 sub potfile ($) {
 701         my $masterfile=shift;
 702
 703         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 704         $dir='' if $dir eq './';
 705         return File::Spec->catpath('', $dir, $name . ".pot");
 706 }
 707
 708 sub pofile ($$) {
 709         my $masterfile=shift;
 710         my $lang=shift;
 711
 712         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 713         $dir='' if $dir eq './';
 714         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 715 }
 716
 717 sub pofiles ($) {
 718         my $masterfile=shift;
 719
 720         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 721 }
 722
 723 sub refreshpot ($) {
 724         my $masterfile=shift;
 725
 726         my $potfile=potfile($masterfile);
 727         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 728         my $doc=Locale::Po4a::Chooser::new('text',%options);
 729         $doc->{TT}{utf_mode} = 1;
 730         $doc->{TT}{file_in_charset} = 'utf-8';
 731         $doc->{TT}{file_out_charset} = 'utf-8';
 732         $doc->read($masterfile);
 733         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 734         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 735         # compulsory since this module prevents us from using the porefs option.
 736         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 737         $doc->{TT}{po_out}->set_charset('utf-8');
 738         # do the actual work
 739         $doc->parse;
 740         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 741         $doc->writepo($potfile);
 742 }
 743
 744 sub refreshpofiles ($@) {
 745         my $masterfile=shift;
 746         my @pofiles=@_;
 747
 748         my $potfile=potfile($masterfile);
 749         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 750
 751         foreach my $pofile (@pofiles) {
 752                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 753                 if (-e $pofile) {
 754                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 755                                 or error("[po/refreshpofiles:$pofile] failed to update");
 756                 }
 757                 else {
 758                         File::Copy::syscopy($potfile,$pofile)
 759                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 760                 }
 761         }
 762 }
 763
 764 sub buildtranslationscache() {
 765         # use istranslation's side-effect
 766         map istranslation($_), (keys %pagesources);
 767 }
 768
 769 sub resettranslationscache() {
 770         undef %translations;
 771 }
 772
 773 sub flushmemoizecache() {
 774         Memoize::flush_cache("istranslatable");
 775         Memoize::flush_cache("_istranslation");
 776         Memoize::flush_cache("percenttranslated");
 777 }
 778
 779 sub urlto_with_orig_beautiful_urlpath($$) {
 780         my $to=shift;
 781         my $from=shift;
 782
 783         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 784         my $res=urlto($to, $from);
 785         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 786
 787         return $res;
 788 }
 789
 790 sub percenttranslated ($) {
 791         my $page=shift;
 792
 793         $page=~s/^\///;
 794         return gettext("N/A") unless istranslation($page);
 795         my $file=srcfile($pagesources{$page});
 796         my $masterfile = srcfile($pagesources{masterpage($page)});
 797         my %options = (
 798                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 799         );
 800         my $doc=Locale::Po4a::Chooser::new('text',%options);
 801         $doc->process(
 802                 'po_in_name'    => [ $file ],
 803                 'file_in_name'  => [ $masterfile ],
 804                 'file_in_charset'  => 'utf-8',
 805                 'file_out_charset' => 'utf-8',
 806         ) or error("[po/percenttranslated:$page]: failed to translate");
 807         my ($percent,$hit,$queries) = $doc->stats();
 808         return $percent;
 809 }
 810
 811 sub languagename ($) {
 812         my $code=shift;
 813
 814         return $config{po_master_language}{name}
 815                 if $code eq $config{po_master_language}{code};
 816         return $config{po_slave_languages}{$code}
 817                 if defined $config{po_slave_languages}{$code};
 818         return;
 819 }
 820
 821 sub otherlanguagesloop ($) {
 822         my $page=shift;
 823
 824         my @ret;
 825         my %otherpages=%{otherlanguages($page)};
 826         while (my ($lang, $otherpage) = each %otherpages) {
 827                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 828                         push @ret, {
 829                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 830                                 code => $lang,
 831                                 language => languagename($lang),
 832                                 master => 1,
 833                         };
 834                 }
 835                 else {
 836                         push @ret, {
 837                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 838                                 code => $lang,
 839                                 language => languagename($lang),
 840                                 percent => percenttranslated($otherpage),
 841                         }
 842                 }
 843         }
 844         return sort {
 845                         return -1 if $a->{code} eq $config{po_master_language}{code};
 846                         return 1 if $b->{code} eq $config{po_master_language}{code};
 847                         return $a->{language} cmp $b->{language};
 848                 } @ret;
 849 }
 850
 851 sub homepageurl (;$) {
 852         my $page=shift;
 853
 854         return urlto('', $page);
 855 }
 856
 857 sub deletetranslations ($) {
 858         my $deletedmasterfile=shift;
 859
 860         my $deletedmasterpage=pagename($deletedmasterfile);
 861         my @todelete;
 862         map {
 863                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 864                 my $absfile = "$config{srcdir}/$file";
 865                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 866                         push @todelete, $file;
 867                 }
 868         } keys %{$config{po_slave_languages}};
 869
 870         map {
 871                 if ($config{rcs}) {
 872                         IkiWiki::rcs_remove($_);
 873                 }
 874                 else {
 875                         IkiWiki::prune("$config{srcdir}/$_");
 876                 }
 877         } @todelete;
 878
 879         if (scalar @todelete) {
 880                 commit_and_refresh(
 881                         gettext("removed obsolete PO files"),
 882                         "IkiWiki::Plugin::po::deletetranslations");
 883         }
 884 }
 885
 886 sub commit_and_refresh ($$) {
 887         my ($msg, $author) = (shift, shift);
 888
 889         if ($config{rcs}) {
 890                 IkiWiki::disable_commit_hook();
 891                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
 892                 IkiWiki::enable_commit_hook();
 893                 IkiWiki::rcs_update();
 894         }
 895         # Reinitialize module's private variables.
 896         resetalreadyfiltered();
 897         resettranslationscache();
 898         flushmemoizecache();
 899         # Trigger a wiki refresh.
 900         require IkiWiki::Render;
 901         # without preliminary saveindex/loadindex, refresh()
 902         # complains about a lot of uninitialized variables
 903         IkiWiki::saveindex();
 904         IkiWiki::loadindex();
 905         IkiWiki::refresh();
 906         IkiWiki::saveindex();
 907 }
 908
 909 # ,----
 910 # | PageSpec's
 911 # `----
 912
 913 package IkiWiki::PageSpec;
 914 use warnings;
 915 use strict;
 916 use IkiWiki 2.00;
 917
 918 sub match_istranslation ($;@) {
 919         my $page=shift;
 920
 921         if (IkiWiki::Plugin::po::istranslation($page)) {
 922                 return IkiWiki::SuccessReason->new("is a translation page");
 923         }
 924         else {
 925                 return IkiWiki::FailReason->new("is not a translation page");
 926         }
 927 }
 928
 929 sub match_istranslatable ($;@) {
 930         my $page=shift;
 931
 932         if (IkiWiki::Plugin::po::istranslatable($page)) {
 933                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 934         }
 935         else {
 936                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 937         }
 938 }
 939
 940 sub match_lang ($$;@) {
 941         my $page=shift;
 942         my $wanted=shift;
 943
 944         my $regexp=IkiWiki::glob2re($wanted);
 945         my $lang=IkiWiki::Plugin::po::lang($page);
 946         if ($lang!~/^$regexp$/i) {
 947                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 948         }
 949         else {
 950                 return IkiWiki::SuccessReason->new("file language is $wanted");
 951         }
 952 }
 953
 954 sub match_currentlang ($$;@) {
 955         my $page=shift;
 956         shift;
 957         my %params=@_;
 958
 959         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 960
 961         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 962         my $lang=IkiWiki::Plugin::po::lang($page);
 963
 964         if ($lang eq $currentlang) {
 965                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 966         }
 967         else {
 968                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 969         }
 970 }
 971
 972 1