IkiWiki/Plugin/openid.pm

   1 #!/usr/bin/perl
   2 # OpenID support.
   3 package IkiWiki::Plugin::openid;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         add_underlay("openid-selector");
  11         add_underlay("jquery");
  12         hook(type => "checkconfig", id => "openid", call => \&checkconfig);
  13         hook(type => "getsetup", id => "openid", call => \&getsetup);
  14         hook(type => "auth", id => "openid", call => \&auth);
  15         hook(type => "formbuilder_setup", id => "openid",
  16                 call => \&formbuilder_setup, last => 1);
  17 }
  18
  19 sub checkconfig () {
  20         if ($config{cgi}) {
  21                 # Intercept normal signin form, so the openid selector
  22                 # can be displayed.
  23                 #
  24                 # When other auth hooks are registered, give the selector
  25                 # a reference to the normal signin form.
  26                 require IkiWiki::CGI;
  27                 my $real_cgi_signin;
  28                 my $otherform_label=gettext("Other");
  29                 if (keys %{$IkiWiki::hooks{auth}} > 1) {
  30                         $real_cgi_signin=\&IkiWiki::cgi_signin;
  31                         my %h=%{$IkiWiki::hooks{auth}};
  32                         delete $h{openid};
  33                         delete $h{emailauth};
  34                         if (keys %h == 1 && exists $h{passwordauth}) {
  35                                 $otherform_label=gettext("Password");
  36                         }
  37                 }
  38                 inject(name => "IkiWiki::cgi_signin", call => sub ($$) {
  39                         openid_selector($real_cgi_signin, $otherform_label, @_);
  40                 });
  41         }
  42 }
  43
  44 sub getsetup () {
  45         return
  46                 plugin => {
  47                         safe => 1,
  48                         rebuild => 0,
  49                         section => "auth",
  50                 },
  51                 openid_realm => {
  52                         type => "string",
  53                         description => "url pattern of openid realm (default is cgiurl)",
  54                         safe => 0,
  55                         rebuild => 0,
  56                 },
  57                 openid_cgiurl => {
  58                         type => "string",
  59                         description => "url to ikiwiki cgi to use for openid authentication (default is cgiurl)",
  60                         safe => 0,
  61                         rebuild => 0,
  62                 },
  63 }
  64
  65 sub openid_selector {
  66         my $real_cgi_signin=shift;
  67         my $otherform_label=shift;
  68         my $q=shift;
  69         my $session=shift;
  70
  71         my $template=IkiWiki::template("openid-selector.tmpl");
  72         my $openid_url=$q->param('openid_identifier');
  73
  74         if (! load_openid_module()) {
  75                 if ($real_cgi_signin) {
  76                         $real_cgi_signin->($q, $session);
  77                         exit;
  78                 }
  79                 error(sprintf(gettext("failed to load openid module: "), @_));
  80         }
  81         elsif (defined $q->param("action") && $q->param("action") eq "verify" && defined $openid_url && length $openid_url) {
  82                 validate($q, $session, $openid_url, sub {
  83                         $template->param(login_error => shift())
  84                 });
  85         }
  86
  87         $template->param(
  88                 cgiurl => IkiWiki::cgiurl(),
  89                 (defined $openid_url ? (openid_url => $openid_url) : ()),
  90                 ($real_cgi_signin ? (otherform => $real_cgi_signin->($q, $session, 1)) : ()),
  91                 otherform_label => $otherform_label,
  92                 login_selector_openid => 1,
  93                 login_selector_email => 1,
  94         );
  95
  96         IkiWiki::printheader($session);
  97         print IkiWiki::cgitemplate($q, "signin", $template->output);
  98         exit;
  99 }
 100
 101 sub formbuilder_setup (@) {
 102         my %params=@_;
 103
 104         my $form=$params{form};
 105         my $session=$params{session};
 106         my $cgi=$params{cgi};
 107
 108         if ($form->title eq "preferences" &&
 109                IkiWiki::openiduser($session->param("name"))) {
 110                 $form->field(name => "openid_identifier", disabled => 1,
 111                         label => htmllink("", "", "ikiwiki/OpenID", noimageinline => 1),
 112                         value => "",
 113                         size => 1, force => 1,
 114                         fieldset => "login",
 115                         comment => $session->param("name"));
 116         }
 117 }
 118
 119 sub validate ($$$;$) {
 120         my $q=shift;
 121         my $session=shift;
 122         my $openid_url=shift;
 123         my $errhandler=shift;
 124
 125         my $csr=getobj($q, $session);
 126
 127         my $claimed_identity = $csr->claimed_identity($openid_url);
 128         if (! $claimed_identity) {
 129                 if ($errhandler) {
 130                         if (ref($errhandler) eq 'CODE') {
 131                                 $errhandler->($csr->err);
 132                         }
 133                         return 0;
 134                 }
 135                 else {
 136                         error($csr->err);
 137                 }
 138         }
 139
 140         # Ask for client to provide a name and email, if possible.
 141         # Try sreg and ax
 142         if ($claimed_identity->can("set_extension_args")) {
 143                 $claimed_identity->set_extension_args(
 144                         'http://openid.net/extensions/sreg/1.1',
 145                         {
 146                                 optional => 'email,fullname,nickname',
 147                         },
 148                 );
 149                 $claimed_identity->set_extension_args(
 150                         'http://openid.net/srv/ax/1.0',
 151                         {
 152                                 mode => 'fetch_request',
 153                                 'required' => 'email,fullname,nickname,firstname',
 154                                 'type.email' => "http://schema.openid.net/contact/email",
 155                                 'type.fullname' => "http://axschema.org/namePerson",
 156                                 'type.nickname' => "http://axschema.org/namePerson/friendly",
 157                                 'type.firstname' => "http://axschema.org/namePerson/first",
 158                         },
 159                 );
 160         }
 161
 162         my $cgiurl=$config{openid_cgiurl};
 163         $cgiurl=$q->url if ! defined $cgiurl;
 164
 165         my $trust_root=$config{openid_realm};
 166         $trust_root=$cgiurl if ! defined $trust_root;
 167
 168         my $check_url = $claimed_identity->check_url(
 169                 return_to => auto_upgrade_https($q, "$cgiurl?do=postsignin"),
 170                 trust_root => auto_upgrade_https($q, $trust_root),
 171                 delayed_return => 1,
 172         );
 173         # Redirect the user to the OpenID server, which will
 174         # eventually bounce them back to auth()
 175         IkiWiki::redirect($q, $check_url);
 176         exit 0;
 177 }
 178
 179 sub auth ($$) {
 180         my $q=shift;
 181         my $session=shift;
 182
 183         if (defined $q->param('openid.mode')) {
 184                 my $csr=getobj($q, $session);
 185
 186                 if (my $setup_url = $csr->user_setup_url) {
 187                         IkiWiki::redirect($q, $setup_url);
 188                 }
 189                 elsif ($csr->user_cancel) {
 190                         IkiWiki::redirect($q, IkiWiki::baseurl(undef));
 191                 }
 192                 elsif (my $vident = $csr->verified_identity) {
 193                         $session->param(name => $vident->url);
 194
 195                         my @extensions;
 196                         if ($vident->can("signed_extension_fields")) {
 197                                 @extensions=grep { defined } (
 198                                         $vident->signed_extension_fields('http://openid.net/extensions/sreg/1.1'),
 199                                         $vident->signed_extension_fields('http://openid.net/srv/ax/1.0'),
 200                                 );
 201                         }
 202                         my $nickname;
 203                         foreach my $ext (@extensions) {
 204                                 foreach my $field (qw{value.email email}) {
 205                                         if (exists $ext->{$field} &&
 206                                             defined $ext->{$field} &&
 207                                             length $ext->{$field}) {
 208                                                 $session->param(email => $ext->{$field});
 209                                                 if (! defined $nickname &&
 210                                                     $ext->{$field}=~/(.+)@.+/) {
 211                                                         $nickname = $1;
 212                                                 }
 213                                                 last;
 214                                         }
 215                                 }
 216                                 foreach my $field (qw{value.nickname nickname value.fullname fullname value.firstname}) {
 217                                         if (exists $ext->{$field} &&
 218                                             defined $ext->{$field} &&
 219                                             length $ext->{$field}) {
 220                                                 $nickname=$ext->{$field};
 221                                                 last;
 222                                         }
 223                                 }
 224                         }
 225                         if (defined $nickname) {
 226                                 $session->param(nickname =>
 227                                         Encode::decode_utf8($nickname));
 228                         }
 229                 }
 230                 else {
 231                         error("OpenID failure: ".$csr->err);
 232                 }
 233         }
 234         elsif (defined $q->param('openid_identifier')) {
 235                 # myopenid.com affiliate support
 236                 validate($q, $session, scalar $q->param('openid_identifier'));
 237         }
 238 }
 239
 240 sub getobj ($$) {
 241         my $q=shift;
 242         my $session=shift;
 243
 244         eval q{use Net::INET6Glue::INET_is_INET6}; # may not be available
 245         eval q{use Net::OpenID::Consumer};
 246         error($@) if $@;
 247
 248         my $ua;
 249         eval q{use LWPx::ParanoidAgent};
 250         if (! $@) {
 251                 $ua=LWPx::ParanoidAgent->new(agent => $config{useragent});
 252         }
 253         else {
 254                 $ua=useragent();
 255         }
 256
 257         # Store the secret in the session.
 258         my $secret=$session->param("openid_secret");
 259         if (! defined $secret) {
 260                 $secret=rand;
 261                 $session->param(openid_secret => $secret);
 262         }
 263
 264         my $cgiurl=$config{openid_cgiurl};
 265         $cgiurl=$q->url if ! defined $cgiurl;
 266
 267         return Net::OpenID::Consumer->new(
 268                 ua => $ua,
 269                 args => $q,
 270                 consumer_secret => sub { return shift()+$secret },
 271                 required_root => auto_upgrade_https($q, $cgiurl),
 272         );
 273 }
 274
 275 sub auto_upgrade_https {
 276         my $q=shift;
 277         my $url=shift;
 278         if ($q->https()) {
 279                 $url=~s/^http:/https:/i;
 280         }
 281         return $url;
 282 }
 283
 284 sub load_openid_module {
 285         # Give up if module is unavailable to avoid needing to depend on it.
 286         eval q{use Net::OpenID::Consumer};
 287         if ($@) {
 288                 debug("unable to load Net::OpenID::Consumer, not enabling OpenID login ($@)");
 289                 return;
 290         }
 291         return 1;
 292 }
 293
 294 1