IkiWiki/Plugin/recentchanges.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::recentchanges;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8 use HTML::Entities;
   9
  10 sub import {
  11         hook(type => "getsetup", id => "recentchanges", call => \&getsetup);
  12         hook(type => "checkconfig", id => "recentchanges", call => \&checkconfig);
  13         hook(type => "refresh", id => "recentchanges", call => \&refresh);
  14         hook(type => "pagetemplate", id => "recentchanges", call => \&pagetemplate);
  15         hook(type => "htmlize", id => "_change", call => \&htmlize);
  16         hook(type => "sessioncgi", id => "recentchanges", call => \&sessioncgi);
  17         # Load goto to fix up links from recentchanges
  18         IkiWiki::loadplugin("goto");
  19 }
  20
  21 sub getsetup () {
  22         return
  23                 plugin => {
  24                         safe => 1,
  25                         rebuild => 1,
  26                 },
  27                 recentchangespage => {
  28                         type => "string",
  29                         example => "recentchanges",
  30                         description => "name of the recentchanges page",
  31                         safe => 1,
  32                         rebuild => 1,
  33                 },
  34                 recentchangesnum => {
  35                         type => "integer",
  36                         example => 100,
  37                         description => "number of changes to track",
  38                         safe => 1,
  39                         rebuild => 0,
  40                 },
  41 }
  42
  43 sub checkconfig () {
  44         $config{recentchangespage}='recentchanges' unless defined $config{recentchangespage};
  45         $config{recentchangesnum}=100 unless defined $config{recentchangesnum};
  46 }
  47
  48 sub refresh ($) {
  49         my %seen;
  50
  51         # add new changes
  52         foreach my $change (IkiWiki::rcs_recentchanges($config{recentchangesnum})) {
  53                 $seen{store($change, $config{recentchangespage})}=1;
  54         }
  55
  56         # delete old and excess changes
  57         foreach my $page (keys %pagesources) {
  58                 if ($pagesources{$page} =~ /\._change$/ && ! $seen{$page}) {
  59                         unlink($config{srcdir}.'/'.$pagesources{$page});
  60                 }
  61         }
  62 }
  63
  64 sub confirmation_form {
  65         my ($q, $session, $rev) = @_;
  66
  67         eval q{use CGI::FormBuilder};
  68         error($@) if $@;
  69         my $f = CGI::FormBuilder->new(
  70                 name => "revert",
  71                 header => 0,
  72                 charset => "utf-8",
  73                 method => 'POST',
  74                 javascript => 0,
  75                 params => $q,
  76                 action => $config{cgiurl},
  77                 stylesheet => 1,
  78                 template => { template('revert.tmpl') },
  79         );
  80
  81         $f->field(name => "sid", type => "hidden", value => $session->id,
  82                 force => 1);
  83         $f->field(name => "do", type => "hidden", value => "revert",
  84                 force => 1);
  85
  86         return $f, ["Revert", "Cancel"];
  87 }
  88
  89 sub sessioncgi ($$) {
  90         my ($q, $session) = @_;
  91         my $do = $q->param('do');
  92         my $rev = $q->param('rev');
  93
  94         return unless $do eq 'revert' && $rev;
  95
  96         $IkiWiki::hooks{rcs}{rcs_preprevert}{call}->(
  97                 cgi => $q, session => $session, rev => $rev);
  98
  99         my ($form, $buttons) = confirmation_form($q, $session);
 100         IkiWiki::decode_form_utf8($form);
 101
 102         if ($form->submitted eq 'Revert' && $form->validate) {
 103                 IkiWiki::checksessionexpiry($q, $session, $q->param('sid'));
 104                 IkiWiki::disable_commit_hook();
 105                 my $r = $IkiWiki::hooks{rcs}{rcs_revert}{call}->($rev);
 106                 if (! defined $r) { # success
 107                         rcs_commit_staged(
 108                                 message => sprintf(gettext("This reverts commit %s"), $rev),
 109                                 session => $session,
 110                                 rev => $rev,
 111                         );
 112                 }
 113                 IkiWiki::enable_commit_hook();
 114
 115                 if (defined $r) {
 116                         die "Revert '$rev' failed.";
 117                 }
 118                 else {
 119                         require IkiWiki::Render;
 120                         IkiWiki::refresh();
 121                         IkiWiki::saveindex();
 122                 }
 123         }
 124         elsif ($form->submitted ne 'Cancel') {
 125                 $form->title(sprintf(gettext("confirm reversion of %s"), $rev));
 126                 $form->tmpl_param(diff => encode_entities(scalar IkiWiki::rcs_diff($rev)));
 127                 $form->field(name => "rev", type => "hidden", value => $rev, force => 1);
 128                 IkiWiki::showform($form, $buttons, $session, $q);
 129                 exit 0;
 130         }
 131
 132         IkiWiki::redirect($q, urlto($config{recentchangespage}, ''));
 133         exit 0;
 134 }
 135
 136 # Enable the recentchanges link.
 137 sub pagetemplate (@) {
 138         my %params=@_;
 139         my $template=$params{template};
 140         my $page=$params{page};
 141
 142         if (defined $config{recentchangespage} && $config{rcs} &&
 143             $template->query(name => "recentchangesurl") &&
 144             $page ne $config{recentchangespage}) {
 145                 $template->param(recentchangesurl => urlto($config{recentchangespage}, $page));
 146                 $template->param(have_actions => 1);
 147         }
 148 }
 149
 150 # Pages with extension _change have plain html markup, pass through.
 151 sub htmlize (@) {
 152         my %params=@_;
 153         return $params{content};
 154 }
 155
 156 sub store ($$$) {
 157         my $change=shift;
 158
 159         my $page="$config{recentchangespage}/change_".titlepage($change->{rev});
 160
 161         # Optimisation to avoid re-writing pages. Assumes commits never
 162         # change (or that any changes are not important).
 163         return $page if exists $pagesources{$page} && ! $config{rebuild};
 164
 165         # Limit pages to first 10, and add links to the changed pages.
 166         my $is_excess = exists $change->{pages}[10];
 167         delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
 168         $change->{pages} = [
 169                 map {
 170                         if (length $config{cgiurl}) {
 171                                 $_->{link} = "<a href=\"".
 172                                         IkiWiki::cgiurl(
 173                                                 do => "goto",
 174                                                 page => $_->{page}
 175                                         ).
 176                                         "\" rel=\"nofollow\">".
 177                                         pagetitle($_->{page}).
 178                                         "</a>"
 179                         }
 180                         else {
 181                                 $_->{link} = pagetitle($_->{page});
 182                         }
 183                         $_->{baseurl}="$config{url}/" if length $config{url};
 184
 185                         $_;
 186                 } @{$change->{pages}}
 187         ];
 188         push @{$change->{pages}}, { link => '...' } if $is_excess;
 189
 190         if (length $config{cgiurl} &&
 191             exists $IkiWiki::hooks{rcs}{rcs_preprevert} &&
 192             exists $IkiWiki::hooks{rcs}{rcs_revert}) {
 193                 $change->{reverturl} = IkiWiki::cgiurl(
 194                         do => "revert",
 195                         rev => $change->{rev}
 196                 );
 197         }
 198
 199         $change->{author}=$change->{user};
 200         my $oiduser=eval { IkiWiki::openiduser($change->{user}) };
 201         if (defined $oiduser) {
 202                 $change->{authorurl}=$change->{user};
 203                 $change->{user}=defined $change->{nickname} ? $change->{nickname} : $oiduser;
 204         }
 205         elsif (length $config{cgiurl}) {
 206                 $change->{authorurl} = IkiWiki::cgiurl(
 207                         do => "goto",
 208                         page => IkiWiki::userpage($change->{author}),
 209                 );
 210         }
 211
 212         if (ref $change->{message}) {
 213                 foreach my $field (@{$change->{message}}) {
 214                         if (exists $field->{line}) {
 215                                 # escape html
 216                                 $field->{line} = encode_entities($field->{line});
 217                                 # escape links and preprocessor stuff
 218                                 $field->{line} = encode_entities($field->{line}, '\[\]');
 219                         }
 220                 }
 221         }
 222
 223         # Fill out a template with the change info.
 224         my $template=template("change.tmpl", blind_cache => 1);
 225         $template->param(
 226                 %$change,
 227                 commitdate => displaytime($change->{when}, "%X %x"),
 228                 wikiname => $config{wikiname},
 229         );
 230
 231         $template->param(permalink => "$config{url}/$config{recentchangespage}/#change-".titlepage($change->{rev}))
 232                 if exists $config{url};
 233
 234         IkiWiki::run_hooks(pagetemplate => sub {
 235                 shift->(page => $page, destpage => $page,
 236                         template => $template, rev => $change->{rev});
 237         });
 238
 239         my $file=$page."._change";
 240         writefile($file, $config{srcdir}, $template->output);
 241         utime $change->{when}, $change->{when}, "$config{srcdir}/$file";
 242
 243         return $page;
 244 }
 245
 246 1