IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub showform ($$$$) { #{{{
  25         my $form=shift;
  26         my $buttons=shift;
  27         my $session=shift;
  28         my $cgi=shift;
  29
  30         if (exists $hooks{formbuilder}) {
  31                 run_hooks(formbuilder => sub {
  32                         shift->(form => $form, cgi => $cgi, session => $session,
  33                                 buttons => $buttons);
  34                 });
  35         }
  36
  37         printheader($session);
  38         print misctemplate($form->title, $form->render(submit => $buttons));
  39 }
  40
  41 sub redirect ($$) { #{{{
  42         my $q=shift;
  43         my $url=shift;
  44         if (! $config{w3mmode}) {
  45                 print $q->redirect($url);
  46         }
  47         else {
  48                 print "Content-type: text/plain\n";
  49                 print "W3m-control: GOTO $url\n\n";
  50         }
  51 } #}}}
  52
  53 sub check_canedit ($$$;$) { #{{{
  54         my $page=shift;
  55         my $q=shift;
  56         my $session=shift;
  57         my $nonfatal=shift;
  58
  59         my $canedit;
  60         my $callback;
  61         run_hooks(canedit => sub {
  62                 return if defined $canedit;
  63                 my $ret=shift->($page, $q, $session);
  64                 if (defined $ret) {
  65                         if ($ret eq "") {
  66                                 $canedit=1;
  67                         }
  68                         elsif (ref $ret eq 'CODE') {
  69                                 $canedit=0;
  70                                 $callback->() unless $nonfatal;
  71                         }
  72                         elsif (defined $ret) {
  73                                 $canedit=0;
  74                                 error($ret) unless $nonfatal;
  75                         }
  76                 }
  77         });
  78         return $canedit;
  79 } #}}}
  80
  81 sub decode_cgi_utf8 ($) { #{{{
  82         my $cgi = shift;
  83         foreach my $f ($cgi->param) {
  84                 $cgi->param($f, map { decode_utf8 $_ } $cgi->param($f));
  85         }
  86 } #}}}
  87
  88 sub cgi_recentchanges ($) { #{{{
  89         my $q=shift;
  90
  91         # Optimisation: building recentchanges means calculating lots of
  92         # links. Memoizing htmllink speeds it up a lot (can't be memoized
  93         # during page builds as the return values may change, but they
  94         # won't here.)
  95         eval q{use Memoize};
  96         error($@) if $@;
  97         memoize("htmllink");
  98
  99         eval q{use Time::Duration};
 100         error($@) if $@;
 101
 102         my $changelog=[rcs_recentchanges(100)];
 103         foreach my $change (@$changelog) {
 104                 $change->{when} = concise(ago($change->{when}));
 105
 106                 $change->{user} = userlink($change->{user});
 107
 108                 my $is_excess = exists $change->{pages}[10]; # limit pages to first 10
 109                 delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
 110                 $change->{pages} = [
 111                         map {
 112                                 $_->{link} = htmllink("", "", $_->{page},
 113                                         noimageinline => 1,
 114                                         linktext => pagetitle($_->{page}));
 115                                 $_;
 116                         } @{$change->{pages}}
 117                 ];
 118                 push @{$change->{pages}}, { link => '...' } if $is_excess;
 119         }
 120
 121         my $template=template("recentchanges.tmpl");
 122         $template->param(
 123                 title => "RecentChanges",
 124                 indexlink => indexlink(),
 125                 wikiname => $config{wikiname},
 126                 changelog => $changelog,
 127                 baseurl => baseurl(),
 128         );
 129         run_hooks(pagetemplate => sub {
 130                 shift->(page => "", destpage => "", template => $template);
 131         });
 132         print $q->header(-charset => 'utf-8'), $template->output;
 133 } #}}}
 134
 135 # Check if the user is signed in. If not, redirect to the signin form and
 136 # save their place to return to later.
 137 sub needsignin ($$) { #{{{
 138         my $q=shift;
 139         my $session=shift;
 140
 141         if (! defined $session->param("name") ||
 142             ! userinfo_get($session->param("name"), "regdate")) {
 143                 $session->param(postsignin => $ENV{QUERY_STRING});
 144                 cgi_signin($q, $session);
 145                 cgi_savesession($session);
 146                 exit;
 147         }
 148 } #}}}
 149
 150 sub cgi_signin ($$) { #{{{
 151         my $q=shift;
 152         my $session=shift;
 153
 154         decode_cgi_utf8($q);
 155         eval q{use CGI::FormBuilder};
 156         error($@) if $@;
 157         my $form = CGI::FormBuilder->new(
 158                 title => "signin",
 159                 name => "signin",
 160                 charset => "utf-8",
 161                 method => 'POST',
 162                 required => 'NONE',
 163                 javascript => 0,
 164                 params => $q,
 165                 action => $config{cgiurl},
 166                 header => 0,
 167                 template => {type => 'div'},
 168                 stylesheet => baseurl()."style.css",
 169         );
 170         my $buttons=["Login"];
 171
 172         if ($q->param("do") ne "signin" && !$form->submitted) {
 173                 $form->text(gettext("You need to log in first."));
 174         }
 175         $form->field(name => "do", type => "hidden", value => "signin",
 176                 force => 1);
 177
 178         run_hooks(formbuilder_setup => sub {
 179                 shift->(form => $form, cgi => $q, session => $session,
 180                         buttons => $buttons);
 181         });
 182
 183         if ($form->submitted) {
 184                 $form->validate;
 185         }
 186
 187         showform($form, $buttons, $session, $q);
 188 } #}}}
 189
 190 sub cgi_postsignin ($$) { #{{{
 191         my $q=shift;
 192         my $session=shift;
 193
 194         # Continue with whatever was being done before the signin process.
 195         if (defined $session->param("postsignin")) {
 196                 my $postsignin=CGI->new($session->param("postsignin"));
 197                 $session->clear("postsignin");
 198                 cgi($postsignin, $session);
 199                 cgi_savesession($session);
 200                 exit;
 201         }
 202         else {
 203                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 204         }
 205 } #}}}
 206
 207 sub cgi_prefs ($$) { #{{{
 208         my $q=shift;
 209         my $session=shift;
 210
 211         needsignin($q, $session);
 212
 213         decode_cgi_utf8($q);
 214         eval q{use CGI::FormBuilder};
 215         error($@) if $@;
 216         my $form = CGI::FormBuilder->new(
 217                 title => "preferences",
 218                 name => "preferences",
 219                 header => 0,
 220                 charset => "utf-8",
 221                 method => 'POST',
 222                 validate => {
 223                         email => 'EMAIL',
 224                 },
 225                 required => 'NONE',
 226                 javascript => 0,
 227                 params => $q,
 228                 action => $config{cgiurl},
 229                 template => {type => 'div'},
 230                 stylesheet => baseurl()."style.css",
 231                 fieldsets => [
 232                         [login => gettext("Login")],
 233                         [preferences => gettext("Preferences")],
 234                         [admin => gettext("Admin")]
 235                 ],
 236         );
 237         my $buttons=["Save Preferences", "Logout", "Cancel"];
 238
 239         run_hooks(formbuilder_setup => sub {
 240                 shift->(form => $form, cgi => $q, session => $session,
 241                         buttons => $buttons);
 242         });
 243
 244         $form->field(name => "do", type => "hidden");
 245         $form->field(name => "email", size => 50, fieldset => "preferences");
 246         $form->field(name => "subscriptions", size => 50,
 247                 fieldset => "preferences",
 248                 comment => "(".htmllink("", "", "ikiwiki/PageSpec", noimageinline => 1).")");
 249         $form->field(name => "banned_users", size => 50,
 250                 fieldset => "admin");
 251
 252         my $user_name=$session->param("name");
 253         if (! is_admin($user_name)) {
 254                 $form->field(name => "banned_users", type => "hidden");
 255         }
 256
 257         if (! $form->submitted) {
 258                 $form->field(name => "email", force => 1,
 259                         value => userinfo_get($user_name, "email"));
 260                 $form->field(name => "subscriptions", force => 1,
 261                         value => userinfo_get($user_name, "subscriptions"));
 262                 if (is_admin($user_name)) {
 263                         $form->field(name => "banned_users", force => 1,
 264                                 value => join(" ", get_banned_users()));
 265                 }
 266         }
 267
 268         if ($form->submitted eq 'Logout') {
 269                 $session->delete();
 270                 redirect($q, $config{url});
 271                 return;
 272         }
 273         elsif ($form->submitted eq 'Cancel') {
 274                 redirect($q, $config{url});
 275                 return;
 276         }
 277         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 278                 foreach my $field (qw(email subscriptions)) {
 279                         if (defined $form->field($field) && length $form->field($field)) {
 280                                 userinfo_set($user_name, $field, $form->field($field)) ||
 281                                         error("failed to set $field");
 282                         }
 283                 }
 284                 if (is_admin($user_name)) {
 285                         set_banned_users(grep { ! is_admin($_) }
 286                                         split(' ',
 287                                                 $form->field("banned_users"))) ||
 288                                 error("failed saving changes");
 289                 }
 290                 $form->text(gettext("Preferences saved."));
 291         }
 292
 293         showform($form, $buttons, $session, $q);
 294 } #}}}
 295
 296 sub cgi_editpage ($$) { #{{{
 297         my $q=shift;
 298         my $session=shift;
 299
 300         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 301         my @buttons=("Save Page", "Preview", "Cancel");
 302
 303         decode_cgi_utf8($q);
 304         eval q{use CGI::FormBuilder};
 305         error($@) if $@;
 306         my $form = CGI::FormBuilder->new(
 307                 title => "editpage",
 308                 fields => \@fields,
 309                 charset => "utf-8",
 310                 method => 'POST',
 311                 required => [qw{editcontent}],
 312                 javascript => 0,
 313                 params => $q,
 314                 action => $config{cgiurl},
 315                 header => 0,
 316                 table => 0,
 317                 template => scalar template_params("editpage.tmpl"),
 318                 wikiname => $config{wikiname},
 319         );
 320
 321         run_hooks(formbuilder_setup => sub {
 322                 shift->(form => $form, cgi => $q, session => $session,
 323                         buttons => \@buttons);
 324         });
 325
 326         # This untaint is safe because titlepage removes any problematic
 327         # characters.
 328         my ($page)=$form->field('page');
 329         $page=titlepage(possibly_foolish_untaint($page));
 330         if (! defined $page || ! length $page ||
 331             file_pruned($page, $config{srcdir}) || $page=~/^\//) {
 332                 error("bad page name");
 333         }
 334
 335         my $from;
 336         if (defined $form->field('from')) {
 337                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 338         }
 339
 340         my $file;
 341         my $type;
 342         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 343                 $file=$pagesources{$page};
 344                 $type=pagetype($file);
 345                 if (! defined $type) {
 346                         error(sprintf(gettext("%s is not an editable page"), $page));
 347                 }
 348                 if (! $form->submitted) {
 349                         $form->field(name => "rcsinfo",
 350                                 value => rcs_prepedit($file), force => 1);
 351                 }
 352                 $form->field(name => "editcontent", validate => '/.*/');
 353         }
 354         else {
 355                 $type=$form->param('type');
 356                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 357                         $type=possibly_foolish_untaint($type);
 358                 }
 359                 elsif (defined $from && exists $pagesources{$from}) {
 360                         # favor the type of linking page
 361                         $type=pagetype($pagesources{$from});
 362                 }
 363                 $type=$config{default_pageext} unless defined $type;
 364                 $file=$page.".".$type;
 365                 if (! $form->submitted) {
 366                         $form->field(name => "rcsinfo", value => "", force => 1);
 367                 }
 368                 $form->field(name => "editcontent", validate => '/.+/');
 369         }
 370
 371         $form->field(name => "do", type => 'hidden');
 372         $form->field(name => "from", type => 'hidden');
 373         $form->field(name => "rcsinfo", type => 'hidden');
 374         $form->field(name => "subpage", type => 'hidden');
 375         $form->field(name => "page", value => pagetitle($page, 1), force => 1);
 376         $form->field(name => "type", value => $type, force => 1);
 377         $form->field(name => "comments", type => "text", size => 80);
 378         $form->field(name => "editcontent", type => "textarea", rows => 20,
 379                 cols => 80);
 380         $form->tmpl_param("can_commit", $config{rcs});
 381         $form->tmpl_param("indexlink", indexlink());
 382         $form->tmpl_param("helponformattinglink",
 383                 htmllink("", "", "ikiwiki/formatting",
 384                         noimageinline => 1,
 385                         linktext => "FormattingHelp"));
 386         $form->tmpl_param("baseurl", baseurl());
 387
 388         if ($form->submitted eq "Cancel") {
 389                 if ($form->field("do") eq "create" && defined $from) {
 390                         redirect($q, "$config{url}/".htmlpage($from));
 391                 }
 392                 elsif ($form->field("do") eq "create") {
 393                         redirect($q, $config{url});
 394                 }
 395                 else {
 396                         redirect($q, "$config{url}/".htmlpage($page));
 397                 }
 398                 return;
 399         }
 400         elsif ($form->submitted eq "Preview") {
 401                 my $content=$form->field('editcontent');
 402                 run_hooks(editcontent => sub {
 403                         $content=shift->(
 404                                 content => $content,
 405                                 page => $page,
 406                                 cgi => $q,
 407                                 session => $session,
 408                         );
 409                 });
 410                 $form->tmpl_param("page_preview",
 411                         htmlize($page, $type,
 412                         linkify($page, "",
 413                         preprocess($page, $page,
 414                         filter($page, $page, $content), 0, 1))));
 415         }
 416         elsif ($form->submitted eq "Save Page") {
 417                 $form->tmpl_param("page_preview", "");
 418         }
 419         $form->tmpl_param("page_conflict", "");
 420
 421         if ($form->submitted ne "Save Page" || ! $form->validate) {
 422                 if ($form->field("do") eq "create") {
 423                         my @page_locs;
 424                         my $best_loc;
 425                         if (! defined $from || ! length $from ||
 426                             $from ne $form->field('from') ||
 427                             file_pruned($from, $config{srcdir}) ||
 428                             $from=~/^\// ||
 429                             $form->submitted eq "Preview") {
 430                                 @page_locs=$best_loc=$page;
 431                         }
 432                         else {
 433                                 my $dir=$from."/";
 434                                 $dir=~s![^/]+/+$!!;
 435
 436                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 437                                     $page eq gettext('discussion')) {
 438                                         $best_loc="$from/$page";
 439                                 }
 440                                 else {
 441                                         $best_loc=$dir.$page;
 442                                 }
 443
 444                                 push @page_locs, $dir.$page;
 445                                 push @page_locs, "$from/$page";
 446                                 while (length $dir) {
 447                                         $dir=~s![^/]+/+$!!;
 448                                         push @page_locs, $dir.$page;
 449                                 }
 450                         }
 451                         push @page_locs, "$config{userdir}/$page"
 452                                 if length $config{userdir};
 453
 454                         @page_locs = grep {
 455                                 ! exists $pagecase{lc $_}
 456                         } @page_locs;
 457                         if (! @page_locs) {
 458                                 # hmm, someone else made the page in the
 459                                 # meantime?
 460                                 redirect($q, "$config{url}/".htmlpage($page));
 461                                 return;
 462                         }
 463
 464                         my @editable_locs = grep {
 465                                 check_canedit($_, $q, $session, 1)
 466                         } @page_locs;
 467                         if (! @editable_locs) {
 468                                 # let it throw an error this time
 469                                 map { check_canedit($_, $q, $session) } @page_locs;
 470                         }
 471
 472                         my @page_types;
 473                         if (exists $hooks{htmlize}) {
 474                                 @page_types=keys %{$hooks{htmlize}};
 475                         }
 476
 477                         $form->tmpl_param("page_select", 1);
 478                         $form->field(name => "page", type => 'select',
 479                                 options => [ map { pagetitle($_, 1) } @editable_locs ],
 480                                 value => pagetitle($best_loc, 1));
 481                         $form->field(name => "type", type => 'select',
 482                                 options => \@page_types);
 483                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 484
 485                 }
 486                 elsif ($form->field("do") eq "edit") {
 487                         check_canedit($page, $q, $session);
 488                         if (! defined $form->field('editcontent') ||
 489                             ! length $form->field('editcontent')) {
 490                                 my $content="";
 491                                 if (exists $pagesources{$page}) {
 492                                         $content=readfile(srcfile($pagesources{$page}));
 493                                         $content=~s/\n/\r\n/g;
 494                                 }
 495                                 $form->field(name => "editcontent", value => $content,
 496                                         force => 1);
 497                         }
 498                         $form->tmpl_param("page_select", 0);
 499                         $form->field(name => "page", type => 'hidden');
 500                         $form->field(name => "type", type => 'hidden');
 501                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 502                 }
 503
 504                 showform($form, \@buttons, $session, $q);
 505                 saveindex();
 506         }
 507         else {
 508                 # save page
 509                 check_canedit($page, $q, $session);
 510
 511                 my $exists=-e "$config{srcdir}/$file";
 512
 513                 if ($form->field("do") ne "create" && ! $exists &&
 514                     ! eval { srcfile($file) }) {
 515                         $form->tmpl_param("page_gone", 1);
 516                         $form->field(name => "do", value => "create", force => 1);
 517                         $form->tmpl_param("page_select", 0);
 518                         $form->field(name => "page", type => 'hidden');
 519                         $form->field(name => "type", type => 'hidden');
 520                         $form->title(sprintf(gettext("editing %s"), $page));
 521                         showform($form, \@buttons, $session, $q);
 522                         return;
 523                 }
 524                 elsif ($form->field("do") eq "create" && $exists) {
 525                         $form->tmpl_param("creation_conflict", 1);
 526                         $form->field(name => "do", value => "edit", force => 1);
 527                         $form->tmpl_param("page_select", 0);
 528                         $form->field(name => "page", type => 'hidden');
 529                         $form->field(name => "type", type => 'hidden');
 530                         $form->title(sprintf(gettext("editing %s"), $page));
 531                         $form->field("editcontent",
 532                                 value => readfile("$config{srcdir}/$file").
 533                                          "\n\n\n".$form->field("editcontent"),
 534                                 force => 1);
 535                         showform($form, \@buttons, $session, $q);
 536                         return;
 537                 }
 538
 539                 my $content=$form->field('editcontent');
 540                 run_hooks(editcontent => sub {
 541                         $content=shift->(
 542                                 content => $content,
 543                                 page => $page,
 544                                 cgi => $q,
 545                                 session => $session,
 546                         );
 547                 });
 548                 $content=~s/\r\n/\n/g;
 549                 $content=~s/\r/\n/g;
 550                 $content.="\n" if $content !~ /\n$/;
 551
 552                 $config{cgi}=0; # avoid cgi error message
 553                 eval { writefile($file, $config{srcdir}, $content) };
 554                 $config{cgi}=1;
 555                 if ($@) {
 556                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 557                                 force => 1);
 558                         $form->tmpl_param("failed_save", 1);
 559                         $form->tmpl_param("error_message", $@);
 560                         $form->field("editcontent", value => $content, force => 1);
 561                         $form->tmpl_param("page_select", 0);
 562                         $form->field(name => "page", type => 'hidden');
 563                         $form->field(name => "type", type => 'hidden');
 564                         $form->title(sprintf(gettext("editing %s"), $page));
 565                         showform($form, \@buttons, $session, $q);
 566                         return;
 567                 }
 568
 569                 my $conflict;
 570                 if ($config{rcs}) {
 571                         my $message="";
 572                         if (defined $form->field('comments') &&
 573                             length $form->field('comments')) {
 574                                 $message=$form->field('comments');
 575                         }
 576
 577                         if (! $exists) {
 578                                 rcs_add($file);
 579                         }
 580
 581                         # Prevent deadlock with post-commit hook by
 582                         # signaling to it that it should not try to
 583                         # do anything (except send commit mails).
 584                         disable_commit_hook();
 585                         $conflict=rcs_commit($file, $message,
 586                                 $form->field("rcsinfo"),
 587                                 $session->param("name"), $ENV{REMOTE_ADDR});
 588                         enable_commit_hook();
 589                         rcs_update();
 590                 }
 591
 592                 # Refresh even if there was a conflict, since other changes
 593                 # may have been committed while the post-commit hook was
 594                 # disabled.
 595                 require IkiWiki::Render;
 596                 # Reload index, since the first time it's loaded is before
 597                 # the wiki is locked, and things may have changed in the
 598                 # meantime.
 599                 loadindex();
 600                 refresh();
 601                 saveindex();
 602
 603                 if (defined $conflict) {
 604                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 605                                 force => 1);
 606                         $form->tmpl_param("page_conflict", 1);
 607                         $form->field("editcontent", value => $conflict, force => 1);
 608                         $form->field("do", "edit", force => 1);
 609                         $form->tmpl_param("page_select", 0);
 610                         $form->field(name => "page", type => 'hidden');
 611                         $form->field(name => "type", type => 'hidden');
 612                         $form->title(sprintf(gettext("editing %s"), $page));
 613                         showform($form, \@buttons, $session, $q);
 614                         return;
 615                 }
 616                 else {
 617                         # The trailing question mark tries to avoid broken
 618                         # caches and get the most recent version of the page.
 619                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 620                 }
 621         }
 622 } #}}}
 623
 624 sub cgi_getsession ($) { #{{{
 625         my $q=shift;
 626
 627         eval q{use CGI::Session};
 628         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 629
 630         my $oldmask=umask(077);
 631         my $session = CGI::Session->new("driver:DB_File", $q,
 632                 { FileName => "$config{wikistatedir}/sessions.db" });
 633         umask($oldmask);
 634
 635         return $session;
 636 } #}}}
 637
 638 sub cgi_savesession ($) { #{{{
 639         my $session=shift;
 640
 641         # Force session flush with safe umask.
 642         my $oldmask=umask(077);
 643         $session->flush;
 644         umask($oldmask);
 645 } #}}}
 646
 647 sub cgi (;$$) { #{{{
 648         my $q=shift;
 649         my $session=shift;
 650
 651         if (! $q) {
 652                 eval q{use CGI};
 653                 error($@) if $@;
 654
 655                 $q=CGI->new;
 656
 657                 run_hooks(cgi => sub { shift->($q) });
 658         }
 659
 660         my $do=$q->param('do');
 661         if (! defined $do || ! length $do) {
 662                 my $error = $q->cgi_error;
 663                 if ($error) {
 664                         error("Request not processed: $error");
 665                 }
 666                 else {
 667                         error("\"do\" parameter missing");
 668                 }
 669         }
 670
 671         # Things that do not need a session.
 672         if ($do eq 'recentchanges') {
 673                 cgi_recentchanges($q);
 674                 return;
 675         }
 676
 677         # Need to lock the wiki before getting a session.
 678         lockwiki();
 679
 680         if (! $session) {
 681                 $session=cgi_getsession($q);
 682         }
 683
 684         # Auth hooks can sign a user in.
 685         if ($do ne 'signin' && ! defined $session->param("name")) {
 686                 run_hooks(auth => sub {
 687                         shift->($q, $session)
 688                 });
 689                 if (defined $session->param("name")) {
 690                         # Make sure whatever user was authed is in the
 691                         # userinfo db.
 692                         if (! userinfo_get($session->param("name"), "regdate")) {
 693                                 userinfo_setall($session->param("name"), {
 694                                         email => "",
 695                                         password => "",
 696                                         regdate => time,
 697                                 }) || error("failed adding user");
 698                         }
 699                 }
 700         }
 701
 702         if (defined $session->param("name") &&
 703             userinfo_get($session->param("name"), "banned")) {
 704                 print $q->header(-status => "403 Forbidden");
 705                 $session->delete();
 706                 print gettext("You are banned.");
 707                 cgi_savesession($session);
 708         }
 709
 710         run_hooks(sessioncgi => sub { shift->($q, $session) });
 711
 712         if ($do eq 'signin') {
 713                 cgi_signin($q, $session);
 714                 cgi_savesession($session);
 715         }
 716         elsif ($do eq 'prefs') {
 717                 cgi_prefs($q, $session);
 718         }
 719         elsif ($do eq 'create' || $do eq 'edit') {
 720                 cgi_editpage($q, $session);
 721         }
 722         elsif (defined $session->param("postsignin")) {
 723                 cgi_postsignin($q, $session);
 724         }
 725         else {
 726                 error("unknown do parameter");
 727         }
 728 } #}}}
 729
 730 sub userlink ($) { #{{{
 731         my $user=shift;
 732
 733         eval q{use CGI 'escapeHTML'};
 734         error($@) if $@;
 735         if ($user =~ m!^https?://! &&
 736             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
 737                 # Munge user-urls, as used by eg, OpenID.
 738                 my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
 739                 my $display=$oid->display;
 740                 # Convert "user.somehost.com" to "user [somehost.com]".
 741                 if ($display !~ /\[/) {
 742                         $display=~s/^(.*?)\.([^.]+\.[a-z]+)$/$1 [$2]/;
 743                 }
 744                 # Convert "http://somehost.com/user" to "user [somehost.com]".
 745                 if ($display !~ /\[/) {
 746                         $display=~s/^https?:\/\/(.+)\/([^\/]+)$/$2 [$1]/;
 747                 }
 748                 $display=~s!^https?://!!; # make sure this is removed
 749                 return "<a href=\"$user\">".escapeHTML($display)."</a>";
 750         }
 751         else {
 752                 return htmllink("", "", escapeHTML(
 753                         length $config{userdir} ? $config{userdir}."/".$user : $user
 754                 ), noimageinline => 1);
 755         }
 756 } #}}}
 757
 758 1