IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                         section => "widget",
  23                 },
  24 }
  25
  26 sub preprocess (@) {
  27         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  28         my %params=@_;
  29
  30         if (! defined $image) {
  31                 error("bad image filename");
  32         }
  33
  34         if (exists $imgdefaults{$params{page}}) {
  35                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  36                         if (! exists $params{$key}) {
  37                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  38                         }
  39                 }
  40         }
  41
  42         if (! exists $params{size} || ! length $params{size}) {
  43                 $params{size}='full';
  44         }
  45
  46         if ($image eq 'defaults') {
  47                 $imgdefaults{$params{page}} = \%params;
  48                 return '';
  49         }
  50
  51         add_link($params{page}, $image);
  52         add_depends($params{page}, $image);
  53
  54         # optimisation: detect scan mode, and avoid generating the image
  55         if (! defined wantarray) {
  56                 return;
  57         }
  58
  59         my $file = bestlink($params{page}, $image);
  60         my $srcfile = srcfile($file, 1);
  61         if (! length $file || ! defined $srcfile) {
  62                 return htmllink($params{page}, $params{destpage}, $image);
  63         }
  64
  65         my $dir = $params{page};
  66         my $base = IkiWiki::basename($file);
  67         my $extension;
  68         my $format;
  69
  70         if ($base =~ m/\.([a-z0-9]+)$/) {
  71                 $extension = $1;
  72         }
  73         else {
  74                 error gettext("Unable to detect image type from extension");
  75         }
  76
  77         # Never interpret well-known file extensions as any other format,
  78         # in case the wiki configuration unwisely allows attaching
  79         # arbitrary files named *.jpg, etc.
  80         if ($extension =~ m/^(jpeg|jpg)$/is) {
  81                 $format = 'jpeg';
  82         }
  83         elsif ($extension =~ m/^(png)$/is) {
  84                 $format = 'png';
  85         }
  86         elsif ($extension =~ m/^(gif)$/is) {
  87                 $format = 'gif';
  88         }
  89         elsif ($extension =~ m/^(svg)$/is) {
  90                 $format = 'svg';
  91         }
  92         elsif ($extension =~ m/^(pdf)$/is) {
  93                 $format = 'pdf';
  94         }
  95         else {
  96                 # allow ImageMagick to auto-detect (potentially dangerous)
  97                 $format = '';
  98         }
  99
 100         my $issvg = $base=~s/\.svg$/.png/i;
 101         my $ispdf = $base=~s/\.pdf$/.png/i;
 102         my $pagenumber = exists($params{pagenumber}) ? int($params{pagenumber}) : 0;
 103         if ($pagenumber != 0) {
 104                 $base = "p$pagenumber-$base";
 105         }
 106
 107         eval q{use Image::Magick};
 108         error gettext("Image::Magick is not installed") if $@;
 109         my $im = Image::Magick->new();
 110         my $imglink;
 111         my $imgdatalink;
 112         my $r = $im->Read("$format:$srcfile\[$pagenumber]");
 113         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
 114
 115         if (! defined $im->Get("width") || ! defined $im->Get("height")) {
 116                 error sprintf(gettext("failed to get dimensions of %s"), $file);
 117         }
 118
 119         my ($dwidth, $dheight);
 120
 121         if ($params{size} eq 'full') {
 122                 $dwidth = $im->Get("width");
 123                 $dheight = $im->Get("height");
 124         } else {
 125                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
 126                 error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
 127                         unless (defined $w && defined $h &&
 128                                 (length $w || length $h));
 129
 130                 if ($im->Get("width") == 0 || $im->Get("height") == 0) {
 131                         ($dwidth, $dheight)=(0, 0);
 132                 } elsif (! length $w || (length $h && $im->Get("height")*$w > $h * $im->Get("width"))) {
 133                         # using height because only height is given or ...
 134                         # because original image is more portrait than $w/$h
 135                         # ... slimness of $im > $h/w
 136                         # ... $im->Get("height")/$im->Get("width") > $h/$w
 137                         # ... $im->Get("height")*$w > $h * $im->Get("width")
 138
 139                         $dheight=$h;
 140                         $dwidth=$h / $im->Get("height") * $im->Get("width");
 141                 } else { # (! length $h) or $w is what determines the resized size
 142                         $dwidth=$w;
 143                         $dheight=$w / $im->Get("width") * $im->Get("height");
 144                 }
 145         }
 146
 147         if ($dwidth < $im->Get("width") || $ispdf) {
 148                 # resize down, or resize to pixels at all
 149
 150                 my $outfile = "$config{destdir}/$dir/$params{size}-$base";
 151                 $imglink = "$dir/$params{size}-$base";
 152
 153                 will_render($params{page}, $imglink);
 154
 155                 if (-e $outfile && (-M $srcfile >= -M $outfile)) {
 156                         $im = Image::Magick->new;
 157                         $r = $im->Read($outfile);
 158                         error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
 159                 }
 160                 else {
 161                         $r = $im->Resize(geometry => "${dwidth}x${dheight}");
 162                         error sprintf(gettext("failed to resize: %s"), $r) if $r;
 163
 164                         $im->set(($issvg || $ispdf) ? (magick => 'png') : ());
 165                         my @blob = $im->ImageToBlob();
 166                         # don't actually write resized file in preview mode;
 167                         # rely on width and height settings
 168                         if (! $params{preview}) {
 169                                 writefile($imglink, $config{destdir}, $blob[0], 1);
 170                         }
 171                         else {
 172                                 eval q{use MIME::Base64};
 173                                 error($@) if $@;
 174                                 $imgdatalink = "data:image/".$im->Get("magick").";base64,".encode_base64($blob[0]);
 175                         }
 176                 }
 177
 178                 # always get the true size of the resized image (it could be
 179                 # that imagemagick did its calculations differently)
 180                 $dwidth  = $im->Get("width");
 181                 $dheight = $im->Get("height");
 182         } else {
 183                 $imglink = $file;
 184         }
 185
 186         if (! defined($dwidth) || ! defined($dheight)) {
 187                 error sprintf(gettext("failed to determine size of image %s"), $file)
 188         }
 189
 190         my ($fileurl, $imgurl);
 191         my $urltobase = $params{preview} ? undef : $params{destpage};
 192         $fileurl=urlto($file, $urltobase);
 193         $imgurl=$imgdatalink ? $imgdatalink : urlto($imglink, $urltobase);
 194
 195         if (! exists $params{class}) {
 196                 $params{class}="img";
 197         }
 198
 199         my $attrs='';
 200         foreach my $attr (qw{alt title class id hspace vspace}) {
 201                 if (exists $params{$attr}) {
 202                         $attrs.=" $attr=\"$params{$attr}\"";
 203                 }
 204         }
 205
 206         my $imgtag='<img src="'.$imgurl.
 207                 '" width="'.$dwidth.
 208                 '" height="'.$dheight.'"'.
 209                 $attrs.
 210                 (exists $params{align} && ! exists $params{caption} ? ' align="'.$params{align}.'"' : '').
 211                 ' />';
 212
 213         my $link;
 214         if (! defined $params{link}) {
 215                 $link=$fileurl;
 216         }
 217         elsif ($params{link} =~ /^\w+:\/\//) {
 218                 $link=$params{link};
 219         }
 220
 221         if (defined $link) {
 222                 $imgtag='<a href="'.$link.'">'.$imgtag.'</a>';
 223         }
 224         else {
 225                 my $b = bestlink($params{page}, $params{link});
 226
 227                 if (length $b) {
 228                         add_depends($params{page}, $b, deptype("presence"));
 229                         $imgtag=htmllink($params{page}, $params{destpage},
 230                                 $params{link}, linktext => $imgtag,
 231                                 noimageinline => 1,
 232                         );
 233                 }
 234         }
 235
 236         if (exists $params{caption}) {
 237                 return '<table class="img'.
 238                         (exists $params{align} ? " align-$params{align}" : "").
 239                         '">'.
 240                         '<caption>'.$params{caption}.'</caption>'.
 241                         '<tr><td>'.$imgtag.'</td></tr>'.
 242                         '</table>';
 243         }
 244         else {
 245                 return $imgtag;
 246         }
 247 }
 248
 249 1