IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8
   9 my %meta;
  10 my %title;
  11 my %permalink;
  12 my %author;
  13 my %authorurl;
  14 my %license;
  15 my %copyright;
  16
  17 sub import { #{{{
  18         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  19         hook(type => "filter", id => "meta", call => \&filter);
  20         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  21 } # }}}
  22
  23 sub filter (@) { #{{{
  24         my %params=@_;
  25
  26         $meta{$params{page}}='';
  27
  28         return $params{content};
  29 } # }}}
  30
  31 sub scrub ($) { #{{{
  32         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  33                 return IkiWiki::Plugin::htmlscrubber::sanitize(content => shift);
  34         }
  35         else {
  36                 return shift;
  37         }
  38 } #}}}
  39
  40 sub preprocess (@) { #{{{
  41         if (! @_) {
  42                 return "";
  43         }
  44         my %params=@_;
  45         my $key=shift;
  46         my $value=$params{$key};
  47         delete $params{$key};
  48         my $page=$params{page};
  49         delete $params{page};
  50         my $destpage=$params{destpage};
  51         delete $params{destpage};
  52         delete $params{preview};
  53
  54         eval q{use HTML::Entities};
  55         # Always dencode, even if encoding later, since it might not be
  56         # fully encoded.
  57         $value=decode_entities($value);
  58
  59         if ($key eq 'link') {
  60                 if (%params) {
  61                         $meta{$page}.=scrub("<link href=\"".encode_entities($value)."\" ".
  62                                 join(" ", map {
  63                                         encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\""
  64                                 } keys %params).
  65                                 " />\n");
  66                 }
  67                 else {
  68                         # hidden WikiLink
  69                         push @{$links{$page}}, $value;
  70                 }
  71         }
  72         elsif ($key eq 'redir') {
  73                 my $safe=0;
  74                 if ($value =~ /^$config{wiki_link_regexp}$/) {
  75                         my $link=bestlink($page, $value);
  76                         if (! length $link) {
  77                                 return "[[meta ".gettext("redir page not found")."]]";
  78                         }
  79                         $value=urlto($link, $destpage);
  80                         $safe=1;
  81                 }
  82                 else {
  83                         $value=encode_entities($value);
  84                 }
  85                 my $delay=int(exists $params{delay} ? $params{delay} : 0);
  86                 my $redir="<meta http-equiv=\"refresh\" content=\"$delay; URL=$value\">";
  87                 if (! $safe) {
  88                         $redir=scrub($redir);
  89                 }
  90                 $meta{$page}.=$redir;
  91         }
  92         elsif ($key eq 'title') {
  93                 $title{$page}=HTML::Entities::encode_numeric($value);
  94         }
  95         elsif ($key eq 'permalink') {
  96                 $permalink{$page}=$value;
  97                 $meta{$page}.=scrub("<link rel=\"bookmark\" href=\"".encode_entities($value)."\" />\n");
  98         }
  99         elsif ($key eq 'date') {
 100                 eval q{use Date::Parse};
 101                 if (! $@) {
 102                         my $time = str2time($value);
 103                         $IkiWiki::pagectime{$page}=$time if defined $time;
 104                 }
 105         }
 106         elsif ($key eq 'stylesheet') {
 107                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
 108                 my $title=exists $params{title} ? $params{title} : $value;
 109                 # adding .css to the value prevents using any old web
 110                 # editable page as a stylesheet
 111                 my $stylesheet=bestlink($page, $value.".css");
 112                 if (! length $stylesheet) {
 113                         return "[[meta ".gettext("stylesheet not found")."]]";
 114                 }
 115                 $meta{$page}.='<link href="'.urlto($stylesheet, $page).
 116                         '" rel="'.encode_entities($rel).
 117                         '" title="'.encode_entities($title).
 118                         "\" type=\"text/css\" />\n";
 119         }
 120         elsif ($key eq 'openid') {
 121                 if (exists $params{server}) {
 122                         $meta{$page}.='<link href="'.encode_entities($params{server}).
 123                                 "\" rel=\"openid.server\" />\n";
 124                 }
 125                 $meta{$page}.='<link href="'.encode_entities($value).
 126                         "\" rel=\"openid.delegate\" />\n";
 127         }
 128         elsif ($key eq 'license') {
 129                 $meta{$page}.="<link rel=\"license\" href=\"#page_license\" />\n";
 130                 $license{$page}=$value;
 131         }
 132         elsif ($key eq 'copyright') {
 133                 $meta{$page}.="<link rel=\"copyright\" href=\"#page_copyright\" />\n";
 134                 $copyright{$page}=$value;
 135         }
 136         else {
 137                 $meta{$page}.=scrub("<meta name=\"".encode_entities($key).
 138                         "\" content=\"".encode_entities($value)."\" />\n");
 139                 if ($key eq 'author') {
 140                         $author{$page}=$value;
 141                 }
 142                 elsif ($key eq 'authorurl') {
 143                         $authorurl{$page}=$value;
 144                 }
 145         }
 146
 147         return "";
 148 } # }}}
 149
 150 sub pagetemplate (@) { #{{{
 151         my %params=@_;
 152         my $page=$params{page};
 153         my $destpage=$params{destpage};
 154         my $template=$params{template};
 155
 156         $template->param(meta => $meta{$page})
 157                 if exists $meta{$page} && $template->query(name => "meta");
 158         if (exists $title{$page} && $template->query(name => "title")) {
 159                 $template->param(title => $title{$page});
 160                 $template->param(title_overridden => 1);
 161         }
 162         $template->param(permalink => $permalink{$page})
 163                 if exists $permalink{$page} && $template->query(name => "permalink");
 164         $template->param(author => $author{$page})
 165                 if exists $author{$page} && $template->query(name => "author");
 166         $template->param(authorurl => $authorurl{$page})
 167                 if exists $authorurl{$page} && $template->query(name => "authorurl");
 168
 169         if ($page ne $destpage &&
 170             ((exists $license{$page}   && ! exists $license{$destpage}) ||
 171              (exists $copyright{$page} && ! exists $copyright{$destpage}))) {
 172                 # Force a scan of the destpage to get its copyright/license
 173                 # info. If the info is declared after an inline, it will
 174                 # otherwise not be available at this point.
 175                 IkiWiki::scan($pagesources{$destpage});
 176         }
 177
 178         if (exists $license{$page} && $template->query(name => "license") &&
 179             ($page eq $destpage || ! exists $license{$destpage} ||
 180              $license{$page} ne $license{$destpage})) {
 181                 $template->param(license => IkiWiki::linkify($page, $destpage, $license{$page}));
 182         }
 183         if (exists $copyright{$page} && $template->query(name => "copyright") &&
 184             ($page eq $destpage || ! exists $copyright{$destpage} ||
 185              $copyright{$page} ne $copyright{$destpage})) {
 186                 $template->param(copyright => IkiWiki::linkify($page, $destpage, $copyright{$page}));
 187         }
 188 } # }}}
 189
 190 1