IkiWiki/Plugin/getsource.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::getsource;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use open qw{:utf8 :std};
   8
   9 sub import {
  10         hook(type => "getsetup", id => "getsource", call => \&getsetup);
  11         hook(type => "pagetemplate", id => "getsource", call => \&pagetemplate);
  12         hook(type => "cgi", id => "getsource", call => \&cgi_getsource);
  13 }
  14
  15 sub getsetup () {
  16         return
  17                 plugin => {
  18                         safe => 1,
  19                         rebuild => 1,
  20                 },
  21                 getsource_mimetype => {
  22                         type => "string",
  23                         example => "text/plain; charset=utf-8",
  24                         description => "Mime type for returned source.",
  25                         safe => 1,
  26                         rebuild => 0,
  27                 },
  28 }
  29
  30 sub pagetemplate (@) {
  31         my %params=@_;
  32
  33         my $page=$params{page};
  34         my $template=$params{template};
  35
  36         if (length $config{cgiurl}) {
  37                 $template->param(getsourceurl => IkiWiki::cgiurl(do => "getsource", page => $page));
  38                 $template->param(have_actions => 1);
  39         }
  40 }
  41
  42 sub cgi_getsource ($) {
  43         my $cgi=shift;
  44
  45         return unless (defined $cgi->param('do') &&
  46                                         $cgi->param("do") eq "getsource");
  47
  48         IkiWiki::decode_cgi_utf8($cgi);
  49
  50         my $page=$cgi->param('page');
  51
  52         # For %pagesources.
  53         IkiWiki::loadindex();
  54
  55         if (! exists $pagesources{$page}) {
  56                 IkiWiki::cgi_custom_failure(
  57                         $cgi->header(-status => "404 Not Found"),
  58                         IkiWiki::misctemplate(gettext("missing page"),
  59                                 "<p>".
  60                                 sprintf(gettext("The page %s does not exist."),
  61                                         htmllink("", "", $page)).
  62                                 "</p>"));
  63                 exit;
  64         }
  65
  66         if (! defined pagetype($pagesources{$page})) {
  67                 IkiWiki::cgi_custom_failure(
  68                         $cgi->header(-status => "403 Forbidden"),
  69                         IkiWiki::misctemplate(gettext("not a page"),
  70                                 "<p>".
  71                                 sprintf(gettext("%s is an attachment, not a page."),
  72                                         htmllink("", "", $page)).
  73                                 "</p>"));
  74                 exit;
  75         }
  76
  77         if (! $config{getsource_mimetype}) {
  78                 $config{getsource_mimetype} = "text/plain; charset=utf-8";
  79         }
  80
  81         print "Content-Type: $config{getsource_mimetype}\r\n";
  82         print ("\r\n");
  83         print readfile(srcfile($pagesources{$page}));
  84
  85         exit 0;
  86 }
  87
  88 1