IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use open qw{:utf8 :std};
  10
  11 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  12 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  29         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  30         hook(type => "rcs", id => "rcs_preprevert", call => \&rcs_preprevert);
  31         hook(type => "rcs", id => "rcs_revert", call => \&rcs_revert);
  32         hook(type => "rcs", id => "rcs_find_changes", call => \&rcs_find_changes);
  33         hook(type => "rcs", id => "rcs_get_current_rev", call => \&rcs_get_current_rev);
  34 }
  35
  36 sub checkconfig () {
  37         if (! defined $config{gitorigin_branch}) {
  38                 $config{gitorigin_branch}="origin";
  39         }
  40         if (! defined $config{gitmaster_branch}) {
  41                 $config{gitmaster_branch}="master";
  42         }
  43         if (defined $config{git_wrapper} &&
  44             length $config{git_wrapper}) {
  45                 push @{$config{wrappers}}, {
  46                         wrapper => $config{git_wrapper},
  47                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  48                         wrapper_background_command => $config{git_wrapper_background_command},
  49                 };
  50         }
  51
  52         if (defined $config{git_test_receive_wrapper} &&
  53             length $config{git_test_receive_wrapper} &&
  54             defined $config{untrusted_committers} &&
  55             @{$config{untrusted_committers}}) {
  56                 push @{$config{wrappers}}, {
  57                         test_receive => 1,
  58                         wrapper => $config{git_test_receive_wrapper},
  59                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  60                 };
  61         }
  62
  63         # Avoid notes, parser does not handle and they only slow things down.
  64         $ENV{GIT_NOTES_REF}="";
  65
  66         # Run receive test only if being called by the wrapper, and not
  67         # when generating same.
  68         if ($config{test_receive} && ! exists $config{wrapper}) {
  69                 require IkiWiki::Receive;
  70                 IkiWiki::Receive::test();
  71         }
  72 }
  73
  74 sub getsetup () {
  75         return
  76                 plugin => {
  77                         safe => 0, # rcs plugin
  78                         rebuild => undef,
  79                         section => "rcs",
  80                 },
  81                 git_wrapper => {
  82                         type => "string",
  83                         example => "/git/wiki.git/hooks/post-update",
  84                         description => "git hook to generate",
  85                         safe => 0, # file
  86                         rebuild => 0,
  87                 },
  88                 git_wrapper_background_command => {
  89                         type => "string",
  90                         example => "git push github",
  91                         description => "shell command for git_wrapper to run, in the background",
  92                         safe => 0, # command
  93                         rebuild => 0,
  94                 },
  95                 git_wrappermode => {
  96                         type => "string",
  97                         example => '06755',
  98                         description => "mode for git_wrapper (can safely be made suid)",
  99                         safe => 0,
 100                         rebuild => 0,
 101                 },
 102                 git_test_receive_wrapper => {
 103                         type => "string",
 104                         example => "/git/wiki.git/hooks/pre-receive",
 105                         description => "git pre-receive hook to generate",
 106                         safe => 0, # file
 107                         rebuild => 0,
 108                 },
 109                 untrusted_committers => {
 110                         type => "string",
 111                         example => [],
 112                         description => "unix users whose commits should be checked by the pre-receive hook",
 113                         safe => 0,
 114                         rebuild => 0,
 115                 },
 116                 historyurl => {
 117                         type => "string",
 118                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]];hb=HEAD",
 119                         description => "gitweb url to show file history ([[file]] substituted)",
 120                         safe => 1,
 121                         rebuild => 1,
 122                 },
 123                 diffurl => {
 124                         type => "string",
 125                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 126                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 127                         safe => 1,
 128                         rebuild => 1,
 129                 },
 130                 gitorigin_branch => {
 131                         type => "string",
 132                         example => "origin",
 133                         description => "where to pull and push changes (set to empty string to disable)",
 134                         safe => 0, # paranoia
 135                         rebuild => 0,
 136                 },
 137                 gitmaster_branch => {
 138                         type => "string",
 139                         example => "master",
 140                         description => "branch that the wiki is stored in",
 141                         safe => 0, # paranoia
 142                         rebuild => 0,
 143                 },
 144 }
 145
 146 sub genwrapper {
 147         if ($config{test_receive}) {
 148                 require IkiWiki::Receive;
 149                 return IkiWiki::Receive::genwrapper();
 150         }
 151         else {
 152                 return "";
 153         }
 154 }
 155
 156 my $git_dir=undef;
 157 my $prefix=undef;
 158
 159 sub in_git_dir ($$) {
 160         $git_dir=shift;
 161         my @ret=shift->();
 162         $git_dir=undef;
 163         $prefix=undef;
 164         return @ret;
 165 }
 166
 167 sub safe_git (&@) {
 168         # Start a child process safely without resorting to /bin/sh.
 169         # Returns command output (in list content) or success state
 170         # (in scalar context), or runs the specified data handler.
 171
 172         my ($error_handler, $data_handler, @cmdline) = @_;
 173
 174         my $pid = open my $OUT, "-|";
 175
 176         error("Cannot fork: $!") if !defined $pid;
 177
 178         if (!$pid) {
 179                 # In child.
 180                 # Git commands want to be in wc.
 181                 if (! defined $git_dir) {
 182                         chdir $config{srcdir}
 183                             or error("cannot chdir to $config{srcdir}: $!");
 184                 }
 185                 else {
 186                         chdir $git_dir
 187                             or error("cannot chdir to $git_dir: $!");
 188                 }
 189                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 190         }
 191         # In parent.
 192
 193         # git output is probably utf-8 encoded, but may contain
 194         # other encodings or invalidly encoded stuff. So do not rely
 195         # on the normal utf-8 IO layer, decode it by hand.
 196         binmode($OUT);
 197
 198         my @lines;
 199         while (<$OUT>) {
 200                 $_=decode_utf8($_, 0);
 201
 202                 chomp;
 203
 204                 if (! defined $data_handler) {
 205                         push @lines, $_;
 206                 }
 207                 else {
 208                         last unless $data_handler->($_);
 209                 }
 210         }
 211
 212         close $OUT;
 213
 214         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 215
 216         return wantarray ? @lines : ($? == 0);
 217 }
 218 # Convenient wrappers.
 219 sub run_or_die ($@) { safe_git(\&error, undef, @_) }
 220 sub run_or_cry ($@) { safe_git(sub { warn @_ }, undef, @_) }
 221 sub run_or_non ($@) { safe_git(undef, undef, @_) }
 222
 223 my $ensured_committer;
 224 sub ensure_committer {
 225         return if $ensured_committer;
 226
 227         my $name = join('', run_or_non("git", "config", "user.name"));
 228         my $email = join('', run_or_non("git", "config", "user.email"));
 229
 230         if (! length $name) {
 231                 run_or_die("git", "config", "user.name", "IkiWiki");
 232         }
 233
 234         if (! length $email) {
 235                 run_or_die("git", "config", "user.email", "ikiwiki.info");
 236         }
 237
 238         $ensured_committer = 1;
 239 }
 240
 241 sub merge_past ($$$) {
 242         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 243         # Git merge commands work with the committed changes, except in the
 244         # implicit case of '-m' of git checkout(1).  So we should invent a
 245         # kludge here.  In principle, we need to create a throw-away branch
 246         # in preparing for the merge itself.  Since branches are cheap (and
 247         # branching is fast), this shouldn't cost high.
 248         #
 249         # The main problem is the presence of _uncommitted_ local changes.  One
 250         # possible approach to get rid of this situation could be that we first
 251         # make a temporary commit in the master branch and later restore the
 252         # initial state (this is possible since Git has the ability to undo a
 253         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 254         # as follows:
 255         #
 256         #       - create a diff of HEAD:current-sha1
 257         #       - dummy commit
 258         #       - create a dummy branch and switch to it
 259         #       - rewind to past (reset --hard to the current-sha1)
 260         #       - apply the diff and commit
 261         #       - switch to master and do the merge with the dummy branch
 262         #       - make a soft reset (undo the last commit of master)
 263         #
 264         # The above method has some drawbacks: (1) it needs a redundant commit
 265         # just to get rid of local changes, (2) somewhat slow because of the
 266         # required system forks.  Until someone points a more straight method
 267         # (which I would be grateful) I have implemented an alternative method.
 268         # In this approach, we hide all the modified files from Git by renaming
 269         # them (using the 'rename' builtin) and later restore those files in
 270         # the throw-away branch (that is, we put the files themselves instead
 271         # of applying a patch).
 272
 273         my ($sha1, $file, $message) = @_;
 274
 275         my @undo;      # undo stack for cleanup in case of an error
 276         my $conflict;  # file content with conflict markers
 277
 278         ensure_committer();
 279
 280         eval {
 281                 # Hide local changes from Git by renaming the modified file.
 282                 # Relative paths must be converted to absolute for renaming.
 283                 my ($target, $hidden) = (
 284                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 285                 );
 286                 rename($target, $hidden)
 287                     or error("rename '$target' to '$hidden' failed: $!");
 288                 # Ensure to restore the renamed file on error.
 289                 push @undo, sub {
 290                         return if ! -e "$hidden"; # already renamed
 291                         rename($hidden, $target)
 292                             or warn "rename '$hidden' to '$target' failed: $!";
 293                 };
 294
 295                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 296
 297                 # Create a throw-away branch and rewind backward.
 298                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 299                 run_or_die('git', 'branch', $branch, $sha1);
 300
 301                 # Switch to throw-away branch for the merge operation.
 302                 push @undo, sub {
 303                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 304                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 305                         }
 306                 };
 307                 run_or_die('git', 'checkout', $branch);
 308
 309                 # Put the modified file in _this_ branch.
 310                 rename($hidden, $target)
 311                     or error("rename '$hidden' to '$target' failed: $!");
 312
 313                 # _Silently_ commit all modifications in the current branch.
 314                 run_or_non('git', 'commit', '-m', $message, '-a');
 315                 # ... and re-switch to master.
 316                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 317
 318                 # Attempt to merge without complaining.
 319                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 320                         $conflict = readfile($target);
 321                         run_or_die('git', 'reset', '--hard');
 322                 }
 323         };
 324         my $failure = $@;
 325
 326         # Process undo stack (in reverse order).  By policy cleanup
 327         # actions should normally print a warning on failure.
 328         while (my $handle = pop @undo) {
 329                 $handle->();
 330         }
 331
 332         error("Git merge failed!\n$failure\n") if $failure;
 333
 334         return $conflict;
 335 }
 336
 337 sub decode_git_file ($) {
 338         my $file=shift;
 339
 340         # git does not output utf-8 filenames, but instead
 341         # double-quotes them with the utf-8 characters
 342         # escaped as \nnn\nnn.
 343         if ($file =~ m/^"(.*)"$/) {
 344                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 345         }
 346
 347         # strip prefix if in a subdir
 348         if (! defined $prefix) {
 349                 ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 350                 if (! defined $prefix) {
 351                         $prefix="";
 352                 }
 353         }
 354         $file =~ s/^\Q$prefix\E//;
 355
 356         return decode("utf8", $file);
 357 }
 358
 359 sub parse_diff_tree ($) {
 360         # Parse the raw diff tree chunk and return the info hash.
 361         # See git-diff-tree(1) for the syntax.
 362         my $dt_ref = shift;
 363
 364         # End of stream?
 365         return if ! @{ $dt_ref } ||
 366                   !defined $dt_ref->[0] || !length $dt_ref->[0];
 367
 368         my %ci;
 369         # Header line.
 370         while (my $line = shift @{ $dt_ref }) {
 371                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 372
 373                 my $sha1 = $2;
 374                 $ci{'sha1'} = $sha1;
 375                 last;
 376         }
 377
 378         # Identification lines for the commit.
 379         while (my $line = shift @{ $dt_ref }) {
 380                 # Regexps are semi-stolen from gitweb.cgi.
 381                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 382                         $ci{'tree'} = $1;
 383                 }
 384                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 385                         # XXX: collecting in reverse order
 386                         push @{ $ci{'parents'} }, $1;
 387                 }
 388                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 389                         my ($who, $name, $epoch, $tz) =
 390                            ($1,   $2,    $3,     $4 );
 391
 392                         $ci{  $who          } = $name;
 393                         $ci{ "${who}_epoch" } = $epoch;
 394                         $ci{ "${who}_tz"    } = $tz;
 395
 396                         if ($name =~ m/^([^<]+)\s+<([^@>]+)/) {
 397                                 $ci{"${who}_name"} = $1;
 398                                 $ci{"${who}_username"} = $2;
 399                         }
 400                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 401                                 $ci{"${who}_username"} = $1;
 402                         }
 403                         else {
 404                                 $ci{"${who}_username"} = $name;
 405                         }
 406                 }
 407                 elsif ($line =~ m/^$/) {
 408                         # Trailing empty line signals next section.
 409                         last;
 410                 }
 411         }
 412
 413         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 414
 415         if (defined $ci{'parents'}) {
 416                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 417         }
 418         else {
 419                 $ci{'parent'} = 0 x 40;
 420         }
 421
 422         # Commit message (optional).
 423         while ($dt_ref->[0] =~ /^    /) {
 424                 my $line = shift @{ $dt_ref };
 425                 $line =~ s/^    //;
 426                 push @{ $ci{'comment'} }, $line;
 427         }
 428         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 429
 430         # Modified files.
 431         while (my $line = shift @{ $dt_ref }) {
 432                 if ($line =~ m{^
 433                         (:+)       # number of parents
 434                         ([^\t]+)\t # modes, sha1, status
 435                         (.*)       # file names
 436                 $}xo) {
 437                         my $num_parents = length $1;
 438                         my @tmp = split(" ", $2);
 439                         my ($file, $file_to) = split("\t", $3);
 440                         my @mode_from = splice(@tmp, 0, $num_parents);
 441                         my $mode_to = shift(@tmp);
 442                         my @sha1_from = splice(@tmp, 0, $num_parents);
 443                         my $sha1_to = shift(@tmp);
 444                         my $status = shift(@tmp);
 445
 446                         if (length $file) {
 447                                 push @{ $ci{'details'} }, {
 448                                         'file'      => decode_git_file($file),
 449                                         'sha1_from' => $sha1_from[0],
 450                                         'sha1_to'   => $sha1_to,
 451                                         'mode_from' => $mode_from[0],
 452                                         'mode_to'   => $mode_to,
 453                                         'status'    => $status,
 454                                 };
 455                         }
 456                         next;
 457                 };
 458                 last;
 459         }
 460
 461         return \%ci;
 462 }
 463
 464 sub git_commit_info ($;$) {
 465         # Return an array of commit info hashes of num commits
 466         # starting from the given sha1sum.
 467         my ($sha1, $num) = @_;
 468
 469         my @opts;
 470         push @opts, "--max-count=$num" if defined $num;
 471
 472         my @raw_lines = run_or_die('git', 'log', @opts,
 473                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 474                 '-r', $sha1, '--', '.');
 475
 476         my @ci;
 477         while (my $parsed = parse_diff_tree(\@raw_lines)) {
 478                 push @ci, $parsed;
 479         }
 480
 481         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 482
 483         return wantarray ? @ci : $ci[0];
 484 }
 485
 486 sub rcs_find_changes ($) {
 487         my $oldrev=shift;
 488
 489         # Note that git log will sometimes show files being added that
 490         # don't exist. Particularly, git merge -s ours can result in a
 491         # merge commit where some files were not really added.
 492         # This is why the code below verifies that the files really
 493         # exist.
 494         my @raw_lines = run_or_die('git', 'log',
 495                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 496                 '--no-renames', , '--reverse',
 497                 '-r', "$oldrev..HEAD", '--', '.');
 498
 499         # Due to --reverse, we see changes in chronological order.
 500         my %changed;
 501         my %deleted;
 502         my $nullsha = 0 x 40;
 503         my $newrev=$oldrev;
 504         while (my $ci = parse_diff_tree(\@raw_lines)) {
 505                 $newrev=$ci->{sha1};
 506                 foreach my $i (@{$ci->{details}}) {
 507                         my $file=$i->{file};
 508                         if ($i->{sha1_to} eq $nullsha) {
 509                                 if (! -e "$config{srcdir}/$file") {
 510                                         delete $changed{$file};
 511                                         $deleted{$file}=1;
 512                                 }
 513                         }
 514                         else {
 515                                 if (-e "$config{srcdir}/$file") {
 516                                         delete $deleted{$file};
 517                                         $changed{$file}=1;
 518                                 }
 519                         }
 520                 }
 521         }
 522
 523         return (\%changed, \%deleted, $newrev);
 524 }
 525
 526 sub git_sha1_file ($) {
 527         my $file=shift;
 528         git_sha1("--", $file);
 529 }
 530
 531 sub git_sha1 (@) {
 532         # Ignore error since a non-existing file might be given.
 533         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 534                 '--', @_);
 535         if (defined $sha1) {
 536                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 537         }
 538         return defined $sha1 ? $sha1 : '';
 539 }
 540
 541 sub rcs_get_current_rev () {
 542         git_sha1();
 543 }
 544
 545 sub rcs_update () {
 546         # Update working directory.
 547
 548         ensure_committer();
 549
 550         if (length $config{gitorigin_branch}) {
 551                 run_or_cry('git', 'pull', '--prune', $config{gitorigin_branch});
 552         }
 553 }
 554
 555 sub rcs_prepedit ($) {
 556         # Return the commit sha1sum of the file when editing begins.
 557         # This will be later used in rcs_commit if a merge is required.
 558         my ($file) = @_;
 559
 560         return git_sha1_file($file);
 561 }
 562
 563 sub rcs_commit (@) {
 564         # Try to commit the page; returns undef on _success_ and
 565         # a version of the page with the rcs's conflict markers on
 566         # failure.
 567         my %params=@_;
 568
 569         # Check to see if the page has been changed by someone else since
 570         # rcs_prepedit was called.
 571         my $cur    = git_sha1_file($params{file});
 572         my ($prev) = $params{token} =~ /^($sha1_pattern)$/; # untaint
 573
 574         if (defined $cur && defined $prev && $cur ne $prev) {
 575                 my $conflict = merge_past($prev, $params{file}, $dummy_commit_msg);
 576                 return $conflict if defined $conflict;
 577         }
 578
 579         return rcs_commit_helper(@_);
 580 }
 581
 582 sub rcs_commit_staged (@) {
 583         # Commits all staged changes. Changes can be staged using rcs_add,
 584         # rcs_remove, and rcs_rename.
 585         return rcs_commit_helper(@_);
 586 }
 587
 588 sub rcs_commit_helper (@) {
 589         my %params=@_;
 590
 591         my %env=%ENV;
 592
 593         ensure_committer();
 594
 595         if (defined $params{session}) {
 596                 # Set the commit author and email based on web session info.
 597                 my $u;
 598                 if (defined $params{session}->param("name")) {
 599                         $u=$params{session}->param("name");
 600                 }
 601                 elsif (defined $params{session}->remote_addr()) {
 602                         $u=$params{session}->remote_addr();
 603                 }
 604                 if (defined $u) {
 605                         $u=encode_utf8($u);
 606                         $ENV{GIT_AUTHOR_NAME}=$u;
 607                 }
 608                 if (defined $params{session}->param("nickname")) {
 609                         $u=encode_utf8($params{session}->param("nickname"));
 610                         $u=~s/\s+/_/g;
 611                         $u=~s/[^-_0-9[:alnum:]]+//g;
 612                 }
 613                 if (defined $u) {
 614                         $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 615                 }
 616         }
 617
 618         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 619         my @opts;
 620         if ($params{message} !~ /\S/) {
 621                 # Force git to allow empty commit messages.
 622                 # (If this version of git supports it.)
 623                 my ($version)=`git --version` =~ /git version (.*)/;
 624                 if ($version ge "1.7.8") {
 625                         push @opts, "--allow-empty-message", "--no-edit";
 626                 }
 627                 if ($version ge "1.7.2") {
 628                         push @opts, "--allow-empty-message";
 629                 }
 630                 elsif ($version ge "1.5.4") {
 631                         push @opts, '--cleanup=verbatim';
 632                 }
 633                 else {
 634                         $params{message}.=".";
 635                 }
 636         }
 637         if (exists $params{file}) {
 638                 push @opts, '--', $params{file};
 639         }
 640         # git commit returns non-zero if nothing really changed.
 641         # So we should ignore its exit status (hence run_or_non).
 642         if (run_or_non('git', 'commit', '-m', $params{message}, '-q', @opts)) {
 643                 if (length $config{gitorigin_branch}) {
 644                         run_or_cry('git', 'push', $config{gitorigin_branch}, $config{gitmaster_branch});
 645                 }
 646         }
 647
 648         %ENV=%env;
 649         return undef; # success
 650 }
 651
 652 sub rcs_add ($) {
 653         # Add file to archive.
 654
 655         my ($file) = @_;
 656
 657         ensure_committer();
 658
 659         run_or_cry('git', 'add', $file);
 660 }
 661
 662 sub rcs_remove ($) {
 663         # Remove file from archive.
 664
 665         my ($file) = @_;
 666
 667         ensure_committer();
 668
 669         run_or_cry('git', 'rm', '-f', $file);
 670 }
 671
 672 sub rcs_rename ($$) {
 673         my ($src, $dest) = @_;
 674
 675         ensure_committer();
 676
 677         run_or_cry('git', 'mv', '-f', $src, $dest);
 678 }
 679
 680 sub rcs_recentchanges ($) {
 681         # List of recent changes.
 682
 683         my ($num) = @_;
 684
 685         eval q{use Date::Parse};
 686         error($@) if $@;
 687
 688         my @rets;
 689         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 690                 # Skip redundant commits.
 691                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 692
 693                 my ($sha1, $when) = (
 694                         $ci->{'sha1'},
 695                         $ci->{'author_epoch'}
 696                 );
 697
 698                 my @pages;
 699                 foreach my $detail (@{ $ci->{'details'} }) {
 700                         my $file = $detail->{'file'};
 701                         my $efile = join('/',
 702                                 map { uri_escape_utf8($_) } split('/', $file)
 703                         );
 704
 705                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 706                         $diffurl =~ s/\[\[file\]\]/$efile/go;
 707                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 708                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 709                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 710                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 711
 712                         push @pages, {
 713                                 page => pagename($file),
 714                                 diffurl => $diffurl,
 715                         };
 716                 }
 717
 718                 my @messages;
 719                 my $pastblank=0;
 720                 foreach my $line (@{$ci->{'comment'}}) {
 721                         $pastblank=1 if $line eq '';
 722                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 723                         push @messages, { line => $line };
 724                 }
 725
 726                 my $user=$ci->{'author_username'};
 727                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 728                 my $nickname;
 729
 730                 # Set nickname only if a non-url author_username is available,
 731                 # and author_name is an url.
 732                 if ($user !~ /:\/\// && defined $ci->{'author_name'} &&
 733                     $ci->{'author_name'} =~ /:\/\//) {
 734                         $nickname=$user;
 735                         $user=$ci->{'author_name'};
 736                 }
 737
 738                 # compatability code for old web commit messages
 739                 if (! $web_commit &&
 740                       defined $messages[0] &&
 741                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 742                         $user = defined $2 ? "$2" : "$3";
 743                         $messages[0]->{line} = $4;
 744                         $web_commit=1;
 745                 }
 746
 747                 push @rets, {
 748                         rev        => $sha1,
 749                         user       => $user,
 750                         nickname   => $nickname,
 751                         committype => $web_commit ? "web" : "git",
 752                         when       => $when,
 753                         message    => [@messages],
 754                         pages      => [@pages],
 755                 } if @pages;
 756
 757                 last if @rets >= $num;
 758         }
 759
 760         return @rets;
 761 }
 762
 763 sub rcs_diff ($;$) {
 764         my $rev=shift;
 765         my $maxlines=shift;
 766         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 767         my @lines;
 768         my $addlines=sub {
 769                 my $line=shift;
 770                 return if defined $maxlines && @lines == $maxlines;
 771                 push @lines, $line."\n"
 772                         if (@lines || $line=~/^diff --git/);
 773                 return 1;
 774         };
 775         safe_git(undef, $addlines, "git", "show", $sha1);
 776         if (wantarray) {
 777                 return @lines;
 778         }
 779         else {
 780                 return join("", @lines);
 781         }
 782 }
 783
 784 {
 785 my %time_cache;
 786
 787 sub findtimes ($$) {
 788         my $file=shift;
 789         my $id=shift; # 0 = mtime ; 1 = ctime
 790
 791         if (! keys %time_cache) {
 792                 my $date;
 793                 foreach my $line (run_or_die('git', 'log',
 794                                 '--pretty=format:%at',
 795                                 '--name-only', '--relative')) {
 796                         if (! defined $date && $line =~ /^(\d+)$/) {
 797                                 $date=$line;
 798                         }
 799                         elsif (! length $line) {
 800                                 $date=undef;
 801                         }
 802                         else {
 803                                 my $f=decode_git_file($line);
 804
 805                                 if (! $time_cache{$f}) {
 806                                         $time_cache{$f}[0]=$date; # mtime
 807                                 }
 808                                 $time_cache{$f}[1]=$date; # ctime
 809                         }
 810                 }
 811         }
 812
 813         return exists $time_cache{$file} ? $time_cache{$file}[$id] : 0;
 814 }
 815
 816 }
 817
 818 sub rcs_getctime ($) {
 819         my $file=shift;
 820
 821         return findtimes($file, 1);
 822 }
 823
 824 sub rcs_getmtime ($) {
 825         my $file=shift;
 826
 827         return findtimes($file, 0);
 828 }
 829
 830 {
 831 my $ret;
 832 sub git_find_root {
 833         # The wiki may not be the only thing in the git repo.
 834         # Determine if it is in a subdirectory by examining the srcdir,
 835         # and its parents, looking for the .git directory.
 836
 837         return @$ret if defined $ret;
 838
 839         my $subdir="";
 840         my $dir=$config{srcdir};
 841         while (! -d "$dir/.git") {
 842                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 843                 $dir=IkiWiki::dirname($dir);
 844                 if (! length $dir) {
 845                         error("cannot determine root of git repo");
 846                 }
 847         }
 848
 849         $ret=[$subdir, $dir];
 850         return @$ret;
 851 }
 852
 853 }
 854
 855 sub git_parse_changes {
 856         my $reverted = shift;
 857         my @changes = @_;
 858
 859         my ($subdir, $rootdir) = git_find_root();
 860         my @rets;
 861         foreach my $ci (@changes) {
 862                 foreach my $detail (@{ $ci->{'details'} }) {
 863                         my $file = $detail->{'file'};
 864
 865                         # check that all changed files are in the subdir
 866                         if (length $subdir &&
 867                             ! ($file =~ s/^\Q$subdir\E//)) {
 868                                 error sprintf(gettext("you are not allowed to change %s"), $file);
 869                         }
 870
 871                         my ($action, $mode, $path);
 872                         if ($detail->{'status'} =~ /^[M]+\d*$/) {
 873                                 $action="change";
 874                                 $mode=$detail->{'mode_to'};
 875                         }
 876                         elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 877                                 $action= $reverted ? "remove" : "add";
 878                                 $mode=$detail->{'mode_to'};
 879                         }
 880                         elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 881                                 $action= $reverted ? "add" : "remove";
 882                                 $mode=$detail->{'mode_from'};
 883                         }
 884                         else {
 885                                 error "unknown status ".$detail->{'status'};
 886                         }
 887
 888                         # test that the file mode is ok
 889                         if ($mode !~ /^100[64][64][64]$/) {
 890                                 error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 891                         }
 892                         if ($action eq "change") {
 893                                 if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 894                                         error gettext("you are not allowed to change file modes");
 895                                 }
 896                         }
 897
 898                         # extract attachment to temp file
 899                         if (($action eq 'add' || $action eq 'change') &&
 900                             ! pagetype($file)) {
 901                                 eval q{use File::Temp};
 902                                 die $@ if $@;
 903                                 my $fh;
 904                                 ($fh, $path)=File::Temp::tempfile(undef, UNLINK => 1);
 905                                 my $cmd = "cd $git_dir && ".
 906                                           "git show $detail->{sha1_to} > '$path'";
 907                                 if (system($cmd) != 0) {
 908                                         error("failed writing temp file '$path'.");
 909                                 }
 910                         }
 911
 912                         push @rets, {
 913                                 file => $file,
 914                                 action => $action,
 915                                 path => $path,
 916                         };
 917                 }
 918         }
 919
 920         return @rets;
 921 }
 922
 923 sub rcs_receive () {
 924         my @rets;
 925         while (<>) {
 926                 chomp;
 927                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 928
 929                 # only allow changes to gitmaster_branch
 930                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 931                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 932                 }
 933
 934                 # Avoid chdir when running git here, because the changes
 935                 # are in the master git repo, not the srcdir repo.
 936                 # (Also, if a subdir is involved, we don't want to chdir to
 937                 # it and only see changes in it.)
 938                 # The pre-receive hook already puts us in the right place.
 939                 in_git_dir(".", sub {
 940                         push @rets, git_parse_changes(0, git_commit_info($oldrev."..".$newrev));
 941                 });
 942         }
 943
 944         return reverse @rets;
 945 }
 946
 947 sub rcs_preprevert ($) {
 948         my $rev=shift;
 949         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 950
 951         # Examine changes from root of git repo, not from any subdir,
 952         # in order to see all changes.
 953         my ($subdir, $rootdir) = git_find_root();
 954         in_git_dir($rootdir, sub {
 955                 my @commits=git_commit_info($sha1, 1);
 956
 957                 if (! @commits) {
 958                         error "unknown commit"; # just in case
 959                 }
 960
 961                 # git revert will fail on merge commits. Add a nice message.
 962                 if (exists $commits[0]->{parents} &&
 963                     @{$commits[0]->{parents}} > 1) {
 964                         error gettext("you are not allowed to revert a merge");
 965                 }
 966
 967                 git_parse_changes(1, @commits);
 968         });
 969 }
 970
 971 sub rcs_revert ($) {
 972         # Try to revert the given rev; returns undef on _success_.
 973         my $rev = shift;
 974         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 975
 976         ensure_committer();
 977
 978         if (run_or_non('git', 'revert', '--no-commit', $sha1)) {
 979                 return undef;
 980         }
 981         else {
 982                 run_or_die('git', 'reset', '--hard');
 983                 return sprintf(gettext("Failed to revert commit %s"), $sha1);
 984         }
 985 }
 986
 987 1