IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my (%backlinks, %rendered);
  11 our %brokenlinks;
  12 my $links_calculated=0;
  13
  14 sub calculate_links () {
  15         return if $links_calculated;
  16         %backlinks=%brokenlinks=();
  17         foreach my $page (keys %links) {
  18                 foreach my $link (@{$links{$page}}) {
  19                         my $bestlink=bestlink($page, $link);
  20                         if (length $bestlink) {
  21                                 $backlinks{$bestlink}{$page}=1
  22                                         if $bestlink ne $page;
  23                         }
  24                         else {
  25                                 push @{$brokenlinks{$link}}, $page;
  26                         }
  27                 }
  28         }
  29         $links_calculated=1;
  30 }
  31
  32 sub backlink_pages ($) {
  33         my $page=shift;
  34
  35         calculate_links();
  36
  37         return keys %{$backlinks{$page}};
  38 }
  39
  40 sub backlinks ($) {
  41         my $page=shift;
  42
  43         my @links;
  44         foreach my $p (backlink_pages($page)) {
  45                 my $href=urlto($p, $page);
  46
  47                 # Trim common dir prefixes from both pages.
  48                 my $p_trimmed=$p;
  49                 my $page_trimmed=$page;
  50                 my $dir;
  51                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  52                         defined $dir &&
  53                         $p_trimmed=~s/^\Q$dir\E// &&
  54                         $page_trimmed=~s/^\Q$dir\E//;
  55
  56                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  57         }
  58         return @links;
  59 }
  60
  61 sub genpage ($$) {
  62         my $page=shift;
  63         my $content=shift;
  64
  65         run_hooks(postscan => sub {
  66                 shift->(page => $page, content => $content);
  67         });
  68
  69         my $templatefile;
  70         run_hooks(templatefile => sub {
  71                 return if defined $templatefile;
  72                 my $file=shift->(page => $page);
  73                 if (defined $file && defined template_file($file)) {
  74                         $templatefile=$file;
  75                 }
  76         });
  77         my $template;
  78         if (defined $templatefile) {
  79                 $template=template_depends($templatefile, $page,
  80                         blind_cache => 1);
  81         }
  82         else {
  83                 # no explicit depends as special case
  84                 $template=template('page.tmpl',
  85                         blind_cache => 1);
  86         }
  87         my $actions=0;
  88
  89         if (length $config{cgiurl}) {
  90                 if (IkiWiki->can("cgi_editpage")) {
  91                         $template->param(editurl => cgiurl(do => "edit", page => $page));
  92                         $actions++;
  93                 }
  94                 if (exists $hooks{auth}) {
  95                         $template->param(prefsurl => cgiurl(do => "prefs"));
  96                         $actions++;
  97                 }
  98         }
  99
 100         if (defined $config{historyurl} && length $config{historyurl}) {
 101                 my $u=$config{historyurl};
 102                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
 103                 $template->param(historyurl => $u);
 104                 $actions++;
 105         }
 106         if ($config{discussion}) {
 107                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 108                    (length $config{cgiurl} ||
 109                     exists $links{$page."/".$config{discussionpage}})) {
 110                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
 111                         $actions++;
 112                 }
 113         }
 114
 115         my @actions;
 116         run_hooks(pageactions => sub {
 117                 push @actions, map { { action => $_ } }
 118                         grep { defined } shift->(page => $page);
 119         });
 120         $template->param(actions => \@actions);
 121
 122         if ($actions || @actions) {
 123                 $template->param(have_actions => 1);
 124         }
 125
 126         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 127         my ($backlinks, $more_backlinks);
 128         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 129                 $backlinks=\@backlinks;
 130                 $more_backlinks=[];
 131         }
 132         else {
 133                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 134                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 135         }
 136
 137         $template->param(
 138                 title => $page eq 'index'
 139                         ? $config{wikiname}
 140                         : pagetitle(basename($page)),
 141                 ispage => 1,
 142                 wikiname => $config{wikiname},
 143                 content => $content,
 144                 backlinks => $backlinks,
 145                 more_backlinks => $more_backlinks,
 146                 mtime => displaytime($pagemtime{$page}),
 147                 ctime => displaytime($pagectime{$page}, undef, 1),
 148                 baseurl => baseurl($page),
 149                 html5 => $config{html5},
 150         );
 151
 152         run_hooks(pagetemplate => sub {
 153                 shift->(page => $page, destpage => $page, template => $template);
 154         });
 155
 156         $content=$template->output;
 157
 158         run_hooks(format => sub {
 159                 $content=shift->(
 160                         page => $page,
 161                         content => $content,
 162                 );
 163         });
 164
 165         return $content;
 166 }
 167
 168 sub scan ($) {
 169         my $file=shift;
 170
 171         debug(sprintf(gettext("scanning %s"), $file));
 172
 173         my $type=pagetype($file);
 174         if (defined $type) {
 175                 my $srcfile=srcfile($file);
 176                 my $content=readfile($srcfile);
 177                 my $page=pagename($file);
 178                 will_render($page, htmlpage($page), 1);
 179
 180                 if ($config{discussion}) {
 181                         # Discussion links are a special case since they're
 182                         # not in the text of the page, but on its template.
 183                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 184                 }
 185                 else {
 186                         $links{$page}=[];
 187                 }
 188                 delete $typedlinks{$page};
 189
 190                 run_hooks(scan => sub {
 191                         shift->(
 192                                 page => $page,
 193                                 content => $content,
 194                         );
 195                 });
 196
 197                 # Preprocess in scan-only mode.
 198                 preprocess($page, $page, $content, 1);
 199         }
 200         else {
 201                 will_render($file, $file, 1);
 202         }
 203 }
 204
 205 sub fast_file_copy (@) {
 206         my $srcfile=shift;
 207         my $destfile=shift;
 208         my $srcfd=shift;
 209         my $destfd=shift;
 210         my $cleanup=shift;
 211
 212         my $blksize = 16384;
 213         my ($len, $buf, $written);
 214         while ($len = sysread $srcfd, $buf, $blksize) {
 215                 if (! defined $len) {
 216                         next if $! =~ /^Interrupted/;
 217                         error("failed to read $srcfile: $!", $cleanup);
 218                 }
 219                 my $offset = 0;
 220                 while ($len) {
 221                         defined($written = syswrite $destfd, $buf, $len, $offset)
 222                                 or error("failed to write $destfile: $!", $cleanup);
 223                         $len -= $written;
 224                         $offset += $written;
 225                 }
 226         }
 227 }
 228
 229 sub render ($$) {
 230         my $file=shift;
 231         return if $rendered{$file};
 232         debug(shift);
 233         $rendered{$file}=1;
 234
 235         my $type=pagetype($file);
 236         my $srcfile=srcfile($file);
 237         if (defined $type) {
 238                 my $page=pagename($file);
 239                 delete $depends{$page};
 240                 delete $depends_simple{$page};
 241                 will_render($page, htmlpage($page), 1);
 242                 return if $type=~/^_/;
 243
 244                 my $content=htmlize($page, $page, $type,
 245                         linkify($page, $page,
 246                         preprocess($page, $page,
 247                         filter($page, $page,
 248                         readfile($srcfile)))));
 249
 250                 my $output=htmlpage($page);
 251                 writefile($output, $config{destdir}, genpage($page, $content));
 252         }
 253         else {
 254                 delete $depends{$file};
 255                 delete $depends_simple{$file};
 256                 will_render($file, $file, 1);
 257
 258                 if ($config{hardlink}) {
 259                         # only hardlink if owned by same user
 260                         my @stat=stat($srcfile);
 261                         if ($stat[4] == $>) {
 262                                 prep_writefile($file, $config{destdir});
 263                                 unlink($config{destdir}."/".$file);
 264                                 if (link($srcfile, $config{destdir}."/".$file)) {
 265                                         return;
 266                                 }
 267                         }
 268                         # if hardlink fails, fall back to copying
 269                 }
 270
 271                 my $srcfd=readfile($srcfile, 1, 1);
 272                 writefile($file, $config{destdir}, undef, 1, sub {
 273                         fast_file_copy($srcfile, $file, $srcfd, @_);
 274                 });
 275         }
 276 }
 277
 278 sub prune ($) {
 279         my $file=shift;
 280
 281         unlink($file);
 282         my $dir=dirname($file);
 283         while (rmdir($dir)) {
 284                 $dir=dirname($dir);
 285         }
 286 }
 287
 288 sub srcdir_check () {
 289         # security check, avoid following symlinks in the srcdir path by default
 290         my $test=$config{srcdir};
 291         while (length $test) {
 292                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 293                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 294                 }
 295                 unless ($test=~s/\/+$//) {
 296                         $test=dirname($test);
 297                 }
 298         }
 299
 300 }
 301
 302 sub find_src_files () {
 303         my @files;
 304         my %pages;
 305         eval q{use File::Find};
 306         error($@) if $@;
 307
 308         my ($page, $dir, $underlay);
 309         my $helper=sub {
 310                 my $file=decode_utf8($_);
 311
 312                 return if -l $file || -d _;
 313                 $file=~s/^\Q$dir\E\/?//;
 314                 return if ! length $file;
 315                 $page = pagename($file);
 316                 if (! exists $pagesources{$page} &&
 317                     file_pruned($file)) {
 318                         $File::Find::prune=1;
 319                         return;
 320                 }
 321
 322                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 323                 if (! defined $f) {
 324                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 325                         return;
 326                 }
 327
 328                 if ($underlay) {
 329                         # avoid underlaydir override attacks; see security.mdwn
 330                         if (! -l "$config{srcdir}/$f" && ! -e _) {
 331                                 if (! $pages{$page}) {
 332                                         push @files, $f;
 333                                         $pages{$page}=1;
 334                                 }
 335                         }
 336                 }
 337                 else {
 338                         push @files, $f;
 339                         if ($pages{$page}) {
 340                                 debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 341                         }
 342                         $pages{$page}=1;
 343                 }
 344         };
 345
 346         find({
 347                 no_chdir => 1,
 348                 wanted => $helper,
 349         }, $dir=$config{srcdir});
 350         $underlay=1;
 351         foreach (@{$config{underlaydirs}}, $config{underlaydir}) {
 352                 find({
 353                         no_chdir => 1,
 354                         wanted => $helper,
 355                 }, $dir=$_);
 356         };
 357         return \@files, \%pages;
 358 }
 359
 360 sub find_new_files ($) {
 361         my $files=shift;
 362         my @new;
 363         my @internal_new;
 364
 365         my $times_noted;
 366
 367         foreach my $file (@$files) {
 368                 my $page=pagename($file);
 369                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 370                         # the page has changed its type
 371                         $forcerebuild{$page}=1;
 372                 }
 373                 $pagesources{$page}=$file;
 374                 if (! $pagemtime{$page}) {
 375                         if (isinternal($page)) {
 376                                 push @internal_new, $file;
 377                         }
 378                         elsif ($config{rcs}) {
 379                                 push @new, $file;
 380                                 if ($config{gettime} && -e "$config{srcdir}/$file") {
 381                                         if (! $times_noted) {
 382                                                 debug(sprintf(gettext("querying %s for file creation and modification times.."), $config{rcs}));
 383                                                 $times_noted=1;
 384                                         }
 385
 386                                         eval {
 387                                                 my $ctime=rcs_getctime("$config{srcdir}/$file");
 388                                                 if ($ctime > 0) {
 389                                                         $pagectime{$page}=$ctime;
 390                                                 }
 391                                         };
 392                                         if ($@) {
 393                                                 print STDERR $@;
 394                                         }
 395                                         my $mtime;
 396                                         eval {
 397                                                 $mtime=rcs_getmtime("$config{srcdir}/$file");
 398                                         };
 399                                         if ($@) {
 400                                                 print STDERR $@;
 401                                         }
 402                                         elsif ($mtime > 0) {
 403                                                 utime($mtime, $mtime, "$config{srcdir}/$file");
 404                                         }
 405                                 }
 406                         }
 407                         $pagecase{lc $page}=$page;
 408                         if (! exists $pagectime{$page}) {
 409                                 $pagectime{$page}=(srcfile_stat($file))[10];
 410                         }
 411                 }
 412         }
 413
 414         return \@new, \@internal_new;
 415 }
 416
 417 sub find_del_files ($) {
 418         my $pages=shift;
 419         my @del;
 420         my @internal_del;
 421
 422         foreach my $page (keys %pagesources) {
 423                 if (! $pages->{$page}) {
 424                         if (isinternal($page)) {
 425                                 push @internal_del, $pagesources{$page};
 426                         }
 427                         else {
 428                                 push @del, $pagesources{$page};
 429                         }
 430                         $links{$page}=[];
 431                         delete $typedlinks{$page};
 432                         $renderedfiles{$page}=[];
 433                         $pagemtime{$page}=0;
 434                 }
 435         }
 436
 437         return \@del, \@internal_del;
 438 }
 439
 440 sub remove_del (@) {
 441         foreach my $file (@_) {
 442                 my $page=pagename($file);
 443                 if (! isinternal($page)) {
 444                         debug(sprintf(gettext("removing obsolete %s"), $page));
 445                 }
 446
 447                 foreach my $old (@{$oldrenderedfiles{$page}}) {
 448                         prune($config{destdir}."/".$old);
 449                 }
 450
 451                 foreach my $source (keys %destsources) {
 452                         if ($destsources{$source} eq $page) {
 453                                 delete $destsources{$source};
 454                         }
 455                 }
 456
 457                 delete $pagecase{lc $page};
 458                 delete $pagesources{$page};
 459         }
 460 }
 461
 462 sub find_changed ($) {
 463         my $files=shift;
 464         my @changed;
 465         my @internal_changed;
 466         foreach my $file (@$files) {
 467                 my $page=pagename($file);
 468                 my ($srcfile, @stat)=srcfile_stat($file);
 469                 if (! exists $pagemtime{$page} ||
 470                     $stat[9] > $pagemtime{$page} ||
 471                     $forcerebuild{$page}) {
 472                         $pagemtime{$page}=$stat[9];
 473
 474                         if (isinternal($page)) {
 475                                 # Preprocess internal page in scan-only mode.
 476                                 preprocess($page, $page, readfile($srcfile), 1);
 477                                 push @internal_changed, $file;
 478                         }
 479                         else {
 480                                 push @changed, $file;
 481                         }
 482                 }
 483         }
 484         return \@changed, \@internal_changed;
 485 }
 486
 487 sub calculate_old_links ($$) {
 488         my ($changed, $del)=@_;
 489         my %oldlink_targets;
 490         foreach my $file (@$changed, @$del) {
 491                 my $page=pagename($file);
 492                 if (exists $oldlinks{$page}) {
 493                         foreach my $l (@{$oldlinks{$page}}) {
 494                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 495                         }
 496                 }
 497         }
 498         return \%oldlink_targets;
 499 }
 500
 501 sub derender_internal ($) {
 502         my $file=shift;
 503         my $page=pagename($file);
 504         delete $depends{$page};
 505         delete $depends_simple{$page};
 506         foreach my $old (@{$renderedfiles{$page}}) {
 507                 delete $destsources{$old};
 508         }
 509         $renderedfiles{$page}=[];
 510 }
 511
 512 sub render_linkers ($) {
 513         my $f=shift;
 514         my $p=pagename($f);
 515         foreach my $page (keys %{$backlinks{$p}}) {
 516                 my $file=$pagesources{$page};
 517                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 518         }
 519 }
 520
 521 sub remove_unrendered () {
 522         foreach my $src (keys %rendered) {
 523                 my $page=pagename($src);
 524                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 525                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 526                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 527                                 prune($config{destdir}."/".$file);
 528                         }
 529                 }
 530         }
 531 }
 532
 533 sub link_types_changed ($$) {
 534         # each is of the form { type => { link => 1 } }
 535         my $new = shift;
 536         my $old = shift;
 537
 538         return 0 if !defined $new && !defined $old;
 539         return 1 if (!defined $new && %$old) || (!defined $old && %$new);
 540
 541         while (my ($type, $links) = each %$new) {
 542                 foreach my $link (keys %$links) {
 543                         return 1 unless exists $old->{$type}{$link};
 544                 }
 545         }
 546
 547         while (my ($type, $links) = each %$old) {
 548                 foreach my $link (keys %$links) {
 549                         return 1 unless exists $new->{$type}{$link};
 550                 }
 551         }
 552
 553         return 0;
 554 }
 555
 556 sub calculate_changed_links ($$$) {
 557         my ($changed, $del, $oldlink_targets)=@_;
 558
 559         my (%backlinkchanged, %linkchangers);
 560
 561         foreach my $file (@$changed, @$del) {
 562                 my $page=pagename($file);
 563
 564                 if (exists $links{$page}) {
 565                         foreach my $l (@{$links{$page}}) {
 566                                 my $target=bestlink($page, $l);
 567                                 if (! exists $oldlink_targets->{$page}{$l} ||
 568                                     $target ne $oldlink_targets->{$page}{$l}) {
 569                                         $backlinkchanged{$target}=1;
 570                                         $linkchangers{lc($page)}=1;
 571                                 }
 572                                 delete $oldlink_targets->{$page}{$l};
 573                         }
 574                 }
 575                 if (exists $oldlink_targets->{$page} &&
 576                     %{$oldlink_targets->{$page}}) {
 577                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 578                                 $backlinkchanged{$target}=1;
 579                         }
 580                         $linkchangers{lc($page)}=1;
 581                 }
 582
 583                 # we currently assume that changing the type of a link doesn't
 584                 # change backlinks
 585                 if (!exists $linkchangers{lc($page)}) {
 586                         if (link_types_changed($typedlinks{$page}, $oldtypedlinks{$page})) {
 587                                 $linkchangers{lc($page)}=1;
 588                         }
 589                 }
 590         }
 591
 592         return \%backlinkchanged, \%linkchangers;
 593 }
 594
 595 sub render_dependent ($$$$$$$) {
 596         my ($files, $new, $internal_new, $del, $internal_del,
 597                 $internal_changed, $linkchangers)=@_;
 598
 599         my @changed=(keys %rendered, @$del);
 600         my @exists_changed=(@$new, @$del);
 601
 602         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 603         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 604
 605         foreach my $p ("templates/page.tmpl", keys %{$depends_simple{""}}) {
 606                 if ($rendered{$p} || grep { $_ eq $p } @$del) {
 607                         foreach my $f (@$files) {
 608                                 next if $rendered{$f};
 609                                 render($f, sprintf(gettext("building %s, which depends on %s"), $f, $p));
 610                         }
 611                         return 0;
 612                 }
 613         }
 614
 615         foreach my $f (@$files) {
 616                 next if $rendered{$f};
 617                 my $p=pagename($f);
 618                 my $reason = undef;
 619
 620                 if (exists $depends_simple{$p} && ! defined $reason) {
 621                         foreach my $d (keys %{$depends_simple{$p}}) {
 622                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 623                                      $lc_changed{$d})
 624                                     ||
 625                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 626                                      $lc_exists_changed{$d})
 627                                     ||
 628                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 629                                      $linkchangers->{$d})
 630                                 ) {
 631                                         $reason = $d;
 632                                         last;
 633                                 }
 634                         }
 635                 }
 636
 637                 if (exists $depends{$p} && ! defined $reason) {
 638                         foreach my $dep (keys %{$depends{$p}}) {
 639                                 my $sub=pagespec_translate($dep);
 640                                 next unless defined $sub;
 641
 642                                 # only consider internal files
 643                                 # if the page explicitly depends
 644                                 # on such files
 645                                 my $internal_dep=$dep =~ /internal\(/;
 646
 647                                 my $in=sub {
 648                                         my $list=shift;
 649                                         my $type=shift;
 650                                         foreach my $file (@$list) {
 651                                                 next if $file eq $f;
 652                                                 my $page=pagename($file);
 653                                                 if ($sub->($page, location => $p)) {
 654                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 655                                                                 next unless $linkchangers->{lc($page)};
 656                                                         }
 657                                                         $reason=$page;
 658                                                         return 1;
 659                                                 }
 660                                         }
 661                                         return undef;
 662                                 };
 663
 664                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 665                                         last if $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 666                                         last if $internal_dep && (
 667                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 668                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 669                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT)
 670                                         );
 671                                 }
 672                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 673                                         last if $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 674                                         last if $internal_dep && (
 675                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 676                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE)
 677                                         );
 678                                 }
 679                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 680                                         last if $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 681                                         last if $internal_dep && (
 682                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 683                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 684                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS)
 685                                         );
 686                                 }
 687                         }
 688                 }
 689
 690                 if (defined $reason) {
 691                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 692                         return 1;
 693                 }
 694         }
 695
 696         return 0;
 697 }
 698
 699 sub render_backlinks ($) {
 700         my $backlinkchanged=shift;
 701         foreach my $link (keys %$backlinkchanged) {
 702                 my $linkfile=$pagesources{$link};
 703                 if (defined $linkfile) {
 704                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 705                 }
 706         }
 707 }
 708
 709 sub gen_autofile ($$$) {
 710         my $autofile=shift;
 711         my $pages=shift;
 712         my $del=shift;
 713
 714         if (file_pruned($autofile)) {
 715                 return;
 716         }
 717
 718         my ($file)="$config{srcdir}/$autofile" =~ /$config{wiki_file_regexp}/; # untaint
 719         if (! defined $file) {
 720                 return;
 721         }
 722
 723         # Remember autofiles that were tried, and never try them again later.
 724         if (exists $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}) {
 725                 return;
 726         }
 727         $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}=1;
 728
 729         if (srcfile($autofile, 1) || file_pruned($autofile)) {
 730                 return;
 731         }
 732
 733         if (-l $file || -d _ || -e _) {
 734                 return;
 735         }
 736
 737         my $page = pagename($file);
 738         if ($pages->{$page}) {
 739                 return;
 740         }
 741
 742         if (grep { $_ eq $autofile } @$del) {
 743                 return;
 744         }
 745
 746         $autofiles{$autofile}{generator}->();
 747         $pages->{$page}=1;
 748         return 1;
 749 }
 750
 751
 752 sub refresh () {
 753         srcdir_check();
 754         run_hooks(refresh => sub { shift->() });
 755         my ($files, $pages)=find_src_files();
 756         my ($new, $internal_new)=find_new_files($files);
 757         my ($del, $internal_del)=find_del_files($pages);
 758         my ($changed, $internal_changed)=find_changed($files);
 759         run_hooks(needsbuild => sub { shift->($changed) });
 760         my $oldlink_targets=calculate_old_links($changed, $del);
 761
 762         foreach my $file (@$changed) {
 763                 scan($file);
 764         }
 765
 766         foreach my $autofile (keys %autofiles) {
 767                 if (gen_autofile($autofile, $pages, $del)) {
 768                         push @{$files}, $autofile;
 769                         push @{$new}, $autofile if find_new_files([$autofile]);
 770                         push @{$changed}, $autofile if find_changed([$autofile]);
 771
 772                         scan($autofile);
 773                 }
 774         }
 775
 776         calculate_links();
 777
 778         remove_del(@$del, @$internal_del);
 779
 780         foreach my $file (@$changed) {
 781                 render($file, sprintf(gettext("building %s"), $file));
 782         }
 783         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 784                 derender_internal($file);
 785         }
 786
 787         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 788                 $del, $oldlink_targets);
 789
 790         foreach my $file (@$new, @$del) {
 791                 render_linkers($file);
 792         }
 793
 794         if (@$changed || @$internal_changed ||
 795             @$del || @$internal_del || @$internal_new) {
 796                 1 while render_dependent($files, $new, $internal_new,
 797                         $del, $internal_del, $internal_changed,
 798                         $linkchangers);
 799         }
 800
 801         render_backlinks($backlinkchanged);
 802         remove_unrendered();
 803
 804         if (@$del) {
 805                 run_hooks(delete => sub { shift->(@$del) });
 806         }
 807         if (%rendered) {
 808                 run_hooks(change => sub { shift->(keys %rendered) });
 809         }
 810 }
 811
 812 sub clean_rendered {
 813         lockwiki();
 814         loadindex();
 815         remove_unrendered();
 816         foreach my $page (keys %oldrenderedfiles) {
 817                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 818                         prune($config{destdir}."/".$file);
 819                 }
 820         }
 821 }
 822
 823 sub commandline_render () {
 824         lockwiki();
 825         loadindex();
 826         unlockwiki();
 827
 828         my $srcfile=possibly_foolish_untaint($config{render});
 829         my $file=$srcfile;
 830         $file=~s/\Q$config{srcdir}\E\/?//;
 831
 832         my $type=pagetype($file);
 833         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 834         my $content=readfile($srcfile);
 835         my $page=pagename($file);
 836         $pagesources{$page}=$file;
 837         $content=filter($page, $page, $content);
 838         $content=preprocess($page, $page, $content);
 839         $content=linkify($page, $page, $content);
 840         $content=htmlize($page, $page, $type, $content);
 841         $pagemtime{$page}=(stat($srcfile))[9];
 842         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 843
 844         print genpage($page, $content);
 845         exit 0;
 846 }
 847
 848 1