t/git-cgi.t

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4
   5 use Test::More;
   6
   7 BEGIN {
   8         my $git = `which git`;
   9         chomp $git;
  10         plan(skip_all => 'git not available') unless -x $git;
  11
  12         plan(skip_all => "CGI not available")
  13                 unless eval q{
  14                         use CGI qw();
  15                         1;
  16                 };
  17
  18         plan(skip_all => "IPC::Run not available")
  19                 unless eval q{
  20                         use IPC::Run qw(run);
  21                         1;
  22                 };
  23
  24         use_ok('IkiWiki');
  25         use_ok('YAML::XS');
  26 }
  27
  28 # We check for English error messages
  29 $ENV{LC_ALL} = 'C';
  30
  31 use Cwd qw(getcwd);
  32 use Errno qw(ENOENT);
  33
  34 my $installed = $ENV{INSTALLED_TESTS};
  35
  36 my @command;
  37 if ($installed) {
  38         @command = qw(ikiwiki);
  39 }
  40 else {
  41         ok(! system("make -s ikiwiki.out"));
  42         @command = ("perl", "-I".getcwd."/blib/lib", './ikiwiki.out',
  43                 '--underlaydir='.getcwd.'/underlays/basewiki',
  44                 '--set', 'underlaydirbase='.getcwd.'/underlays',
  45                 '--templatedir='.getcwd.'/templates');
  46 }
  47
  48 sub write_old_file {
  49         my $name = shift;
  50         my $dir = shift;
  51         my $content = shift;
  52         writefile($name, $dir, $content);
  53         ok(utime(333333333, 333333333, "$dir/$name"));
  54 }
  55
  56 sub write_setup_file {
  57         my %setup = (
  58                 wikiname => 'this is the name of my wiki',
  59                 srcdir => getcwd.'/t/tmp/in/doc',
  60                 destdir => getcwd.'/t/tmp/out',
  61                 url => 'http://example.com',
  62                 cgiurl => 'http://example.com/cgi-bin/ikiwiki.cgi',
  63                 cgi_wrapper => getcwd.'/t/tmp/ikiwiki.cgi',
  64                 cgi_wrappermode => '0751',
  65                 add_plugins => [qw(anonok attachment lockedit recentchanges)],
  66                 disable_plugins => [qw(emailauth openid passwordauth)],
  67                 anonok_pagespec => 'writable/*',
  68                 locked_pages => '!writable/*',
  69                 rcs => 'git',
  70                 git_wrapper => getcwd.'/t/tmp/in/.git/hooks/post-commit',
  71                 git_wrappermode => '0754',
  72                 gitorigin_branch => '',
  73         );
  74         unless ($installed) {
  75                 $setup{ENV} = { 'PERL5LIB' => getcwd.'/blib/lib' };
  76         }
  77         writefile("test.setup", "t/tmp",
  78                 "# IkiWiki::Setup::Yaml - YAML formatted setup file\n" .
  79                 Dump(\%setup));
  80 }
  81
  82 sub thoroughly_rebuild {
  83         ok(unlink("t/tmp/ikiwiki.cgi") || $!{ENOENT});
  84         ok(unlink("t/tmp/in/.git/hooks/post-commit") || $!{ENOENT});
  85         ok(! system(@command, qw(--setup t/tmp/test.setup --rebuild --wrappers)));
  86 }
  87
  88 sub check_cgi_mode_bits {
  89         my $mode;
  90
  91         (undef, undef, $mode, undef, undef,
  92                 undef, undef, undef, undef, undef,
  93                 undef, undef, undef) = stat('t/tmp/ikiwiki.cgi');
  94         is ($mode & 07777, 0751);
  95         (undef, undef, $mode, undef, undef,
  96                 undef, undef, undef, undef, undef,
  97                 undef, undef, undef) = stat('t/tmp/in/.git/hooks/post-commit');
  98         is ($mode & 07777, 0754);
  99 }
 100
 101 sub run_cgi {
 102         my (%args) = @_;
 103         my ($in, $out);
 104         my $method = $args{method} || 'GET';
 105         my $environ = $args{environ} || {};
 106         my $params = $args{params} || { do => 'prefs' };
 107
 108         my %defaults = (
 109                 SCRIPT_NAME     => '/cgi-bin/ikiwiki.cgi',
 110                 HTTP_HOST       => 'example.com',
 111         );
 112
 113         my $cgi = CGI->new($args{params});
 114         my $query_string = $cgi->query_string();
 115
 116         if ($method eq 'POST') {
 117                 $defaults{REQUEST_METHOD} = 'POST';
 118                 $in = $query_string;
 119                 $defaults{CONTENT_LENGTH} = length $in;
 120         } else {
 121                 $defaults{REQUEST_METHOD} = 'GET';
 122                 $defaults{QUERY_STRING} = $query_string;
 123         }
 124
 125         my %envvars = (
 126                 %defaults,
 127                 %$environ,
 128         );
 129         run(["./t/tmp/ikiwiki.cgi"], \$in, \$out, init => sub {
 130                 map {
 131                         $ENV{$_} = $envvars{$_}
 132                 } keys(%envvars);
 133         });
 134
 135         return $out;
 136 }
 137
 138 sub run_git {
 139         my (undef, $filename, $line) = caller;
 140         my $args = shift;
 141         my $desc = shift || join(' ', 'git', @$args);
 142         my ($in, $out);
 143         ok(run(['git', @$args], \$in, \$out, init => sub {
 144                 chdir 't/tmp/in' or die $!;
 145                 $ENV{EMAIL} = 'nobody@ikiwiki-tests.invalid';
 146         }), "$desc at $filename:$line");
 147         return $out;
 148 }
 149
 150 sub test {
 151         my $content;
 152         my $status;
 153
 154         ok(! system(qw(rm -rf t/tmp)));
 155         ok(! system(qw(mkdir t/tmp)));
 156
 157         write_old_file('.gitignore', 't/tmp/in', "/doc/.ikiwiki/\n");
 158         write_old_file('doc/writable/one.mdwn', 't/tmp/in', 'This is the first test page');
 159         write_old_file('doc/writable/two.mdwn', 't/tmp/in', 'This is the second test page');
 160         write_old_file('doc/writable/three.mdwn', 't/tmp/in', 'This is the third test page');
 161         write_old_file('doc/writable/three.bin', 't/tmp/in', 'An attachment');
 162
 163         unless ($installed) {
 164                 ok(! system(qw(cp -pRL doc/wikiicons t/tmp/in/doc/)));
 165                 ok(! system(qw(cp -pRL doc/recentchanges.mdwn t/tmp/in/doc/)));
 166         }
 167
 168         run_git(['init']);
 169         run_git(['add', '.']);
 170         run_git(['commit', '-m', 'Initial commit']);
 171
 172         write_setup_file();
 173         thoroughly_rebuild();
 174         check_cgi_mode_bits();
 175
 176         ok(-e 't/tmp/out/writable/one/index.html');
 177         $content = readfile('t/tmp/out/writable/one/index.html');
 178         like($content, qr{This is the first test page});
 179         my $orig_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 180
 181         # We have to wait 1 second here so that new writes are guaranteed
 182         # to have a strictly larger mtime.
 183         sleep 1;
 184
 185         # Test the git hook, which accepts git commits
 186         writefile('doc/writable/one.mdwn', 't/tmp/in',
 187                 'This is new content for the first test page');
 188         run_git(['add', '.']);
 189         run_git(['commit', '-m', 'Git commit']);
 190         my $first_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 191         isnt($orig_sha1, $first_revertable_sha1);
 192
 193         ok(-e 't/tmp/out/writable/one/index.html');
 194         $content = readfile('t/tmp/out/writable/one/index.html');
 195         like($content, qr{This is new content for the first test page});
 196
 197         # Test a web commit
 198         $content = run_cgi(method => 'POST',
 199                 params => {
 200                         do => 'edit',
 201                         page => 'writable/two',
 202                         type => 'mdwn',
 203                         editmessage => 'Web commit',
 204                         editcontent => 'Here is new content for the second page',
 205                         _submit => 'Save Page',
 206                         _submitted => '1',
 207                 },
 208         );
 209         like($content, qr{^Status:\s*302\s}m);
 210         like($content, qr{^Location:\s*http://example\.com/writable/two/\?updated}m);
 211         my $second_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 212         isnt($orig_sha1, $second_revertable_sha1);
 213         isnt($first_revertable_sha1, $second_revertable_sha1);
 214
 215         ok(-e 't/tmp/out/writable/two/index.html');
 216         $content = readfile('t/tmp/out/writable/two/index.html');
 217         like($content, qr{Here is new content for the second page});
 218
 219         # Another edit
 220         writefile('doc/writable/three.mdwn', 't/tmp/in',
 221                 'Also new content for the third page');
 222         unlink('t/tmp/in/doc/writable/three.bin');
 223         writefile('doc/writable/three.bin', 't/tmp/in',
 224                 'Changed attachment');
 225         run_git(['add', '.']);
 226         run_git(['commit', '-m', 'Git commit']);
 227         ok(-e 't/tmp/out/writable/three/index.html');
 228         $content = readfile('t/tmp/out/writable/three/index.html');
 229         like($content, qr{Also new content for the third page});
 230         $content = readfile('t/tmp/out/writable/three.bin');
 231         like($content, qr{Changed attachment});
 232         my $third_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 233         isnt($orig_sha1, $third_revertable_sha1);
 234         isnt($second_revertable_sha1, $third_revertable_sha1);
 235
 236         run_git(['mv', 'doc/writable/one.mdwn', 'doc/one.mdwn']);
 237         run_git(['mv', 'doc/writable/two.mdwn', 'two.mdwn']);
 238         run_git(['commit', '-m', 'Rename files to test CVE-2016-10026']);
 239         ok(! -e 't/tmp/out/writable/two/index.html');
 240         ok(! -e 't/tmp/out/writable/one/index.html');
 241         ok(-e 't/tmp/out/one/index.html');
 242         my $sha1_before_revert = run_git(['rev-list', '--max-count=1', 'HEAD']);
 243         isnt($sha1_before_revert, $third_revertable_sha1);
 244
 245         $content = run_cgi(method => 'post',
 246                 params => {
 247                         do => 'revert',
 248                         revertmessage => 'CVE-2016-10026',
 249                         rev => $first_revertable_sha1,
 250                         _submit => 'Revert',
 251                         _submitted_revert => '1',
 252                 },
 253         );
 254         like($content, qr{is locked and cannot be edited});
 255         # The tree is left clean
 256         run_git(['diff', '--exit-code']);
 257         run_git(['diff', '--cached', '--exit-code']);
 258         my $sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 259         is($sha1, $sha1_before_revert);
 260
 261         ok(-e 't/tmp/out/one/index.html');
 262         ok(! -e 't/tmp/in/doc/writable/one.mdwn');
 263         ok(-e 't/tmp/in/doc/one.mdwn');
 264         $content = readfile('t/tmp/out/one/index.html');
 265         like($content, qr{This is new content for the first test page});
 266
 267         $content = run_cgi(method => 'post',
 268                 params => {
 269                         do => 'revert',
 270                         revertmessage => 'CVE-2016-10026',
 271                         rev => $second_revertable_sha1,
 272                         _submit => 'Revert',
 273                         _submitted_revert => '1',
 274                 },
 275         );
 276         like($content, qr{you are not allowed to change two\.mdwn});
 277         run_git(['diff', '--exit-code']);
 278         run_git(['diff', '--cached', '--exit-code']);
 279         $sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 280         is($sha1, $sha1_before_revert);
 281
 282         ok(! -e 't/tmp/out/writable/two/index.html');
 283         ok(! -e 't/tmp/out/two/index.html');
 284         ok(! -e 't/tmp/in/doc/writable/two.mdwn');
 285         ok(-e 't/tmp/in/two.mdwn');
 286         $content = readfile('t/tmp/in/two.mdwn');
 287         like($content, qr{Here is new content for the second page});
 288
 289         # This one can legitimately be reverted
 290         $content = run_cgi(method => 'post',
 291                 params => {
 292                         do => 'revert',
 293                         revertmessage => 'not CVE-2016-10026',
 294                         rev => $third_revertable_sha1,
 295                         _submit => 'Revert',
 296                         _submitted_revert => '1',
 297                 },
 298         );
 299         like($content, qr{^Status:\s*302\s}m);
 300         like($content, qr{^Location:\s*http://example\.com/recentchanges/}m);
 301         run_git(['diff', '--exit-code']);
 302         run_git(['diff', '--cached', '--exit-code']);
 303         ok(-e 't/tmp/out/writable/three/index.html');
 304         $content = readfile('t/tmp/out/writable/three/index.html');
 305         like($content, qr{This is the third test page});
 306         $content = readfile('t/tmp/out/writable/three.bin');
 307         like($content, qr{An attachment});
 308 }
 309
 310 test();
 311
 312 done_testing();