IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use open qw{:utf8 :std};
  10
  11 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  12 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  29         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  30         hook(type => "rcs", id => "rcs_preprevert", call => \&rcs_preprevert);
  31         hook(type => "rcs", id => "rcs_revert", call => \&rcs_revert);
  32         hook(type => "rcs", id => "rcs_find_changes", call => \&rcs_find_changes);
  33         hook(type => "rcs", id => "rcs_get_current_rev", call => \&rcs_get_current_rev);
  34 }
  35
  36 sub checkconfig () {
  37         if (! defined $config{gitorigin_branch}) {
  38                 $config{gitorigin_branch}="origin";
  39         }
  40         if (! defined $config{gitmaster_branch}) {
  41                 $config{gitmaster_branch}="master";
  42         }
  43         if (defined $config{git_wrapper} &&
  44             length $config{git_wrapper}) {
  45                 push @{$config{wrappers}}, {
  46                         wrapper => $config{git_wrapper},
  47                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  48                         wrapper_background_command => $config{git_wrapper_background_command},
  49                 };
  50         }
  51
  52         if (defined $config{git_test_receive_wrapper} &&
  53             length $config{git_test_receive_wrapper} &&
  54             defined $config{untrusted_committers} &&
  55             @{$config{untrusted_committers}}) {
  56                 push @{$config{wrappers}}, {
  57                         test_receive => 1,
  58                         wrapper => $config{git_test_receive_wrapper},
  59                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  60                 };
  61         }
  62
  63         # Avoid notes, parser does not handle and they only slow things down.
  64         $ENV{GIT_NOTES_REF}="";
  65
  66         # Run receive test only if being called by the wrapper, and not
  67         # when generating same.
  68         if ($config{test_receive} && ! exists $config{wrapper}) {
  69                 require IkiWiki::Receive;
  70                 IkiWiki::Receive::test();
  71         }
  72 }
  73
  74 sub getsetup () {
  75         return
  76                 plugin => {
  77                         safe => 0, # rcs plugin
  78                         rebuild => undef,
  79                         section => "rcs",
  80                 },
  81                 git_wrapper => {
  82                         type => "string",
  83                         example => "/git/wiki.git/hooks/post-update",
  84                         description => "git hook to generate",
  85                         safe => 0, # file
  86                         rebuild => 0,
  87                 },
  88                 git_wrapper_background_command => {
  89                         type => "string",
  90                         example => "git push github",
  91                         description => "shell command for git_wrapper to run, in the background",
  92                         safe => 0, # command
  93                         rebuild => 0,
  94                 },
  95                 git_wrappermode => {
  96                         type => "string",
  97                         example => '06755',
  98                         description => "mode for git_wrapper (can safely be made suid)",
  99                         safe => 0,
 100                         rebuild => 0,
 101                 },
 102                 git_test_receive_wrapper => {
 103                         type => "string",
 104                         example => "/git/wiki.git/hooks/pre-receive",
 105                         description => "git pre-receive hook to generate",
 106                         safe => 0, # file
 107                         rebuild => 0,
 108                 },
 109                 untrusted_committers => {
 110                         type => "string",
 111                         example => [],
 112                         description => "unix users whose commits should be checked by the pre-receive hook",
 113                         safe => 0,
 114                         rebuild => 0,
 115                 },
 116                 historyurl => {
 117                         type => "string",
 118                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]];hb=HEAD",
 119                         description => "gitweb url to show file history ([[file]] substituted)",
 120                         safe => 1,
 121                         rebuild => 1,
 122                 },
 123                 diffurl => {
 124                         type => "string",
 125                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 126                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 127                         safe => 1,
 128                         rebuild => 1,
 129                 },
 130                 gitorigin_branch => {
 131                         type => "string",
 132                         example => "origin",
 133                         description => "where to pull and push changes (set to empty string to disable)",
 134                         safe => 0, # paranoia
 135                         rebuild => 0,
 136                 },
 137                 gitmaster_branch => {
 138                         type => "string",
 139                         example => "master",
 140                         description => "branch that the wiki is stored in",
 141                         safe => 0, # paranoia
 142                         rebuild => 0,
 143                 },
 144 }
 145
 146 sub genwrapper {
 147         if ($config{test_receive}) {
 148                 require IkiWiki::Receive;
 149                 return IkiWiki::Receive::genwrapper();
 150         }
 151         else {
 152                 return "";
 153         }
 154 }
 155
 156 my $git_dir=undef;
 157 my $prefix=undef;
 158
 159 sub in_git_dir ($$) {
 160         $git_dir=shift;
 161         my @ret=shift->();
 162         $git_dir=undef;
 163         $prefix=undef;
 164         return @ret;
 165 }
 166
 167 sub safe_git (&@) {
 168         # Start a child process safely without resorting to /bin/sh.
 169         # Returns command output (in list content) or success state
 170         # (in scalar context), or runs the specified data handler.
 171
 172         my ($error_handler, $data_handler, @cmdline) = @_;
 173
 174         my $pid = open my $OUT, "-|";
 175
 176         error("Cannot fork: $!") if !defined $pid;
 177
 178         if (!$pid) {
 179                 # In child.
 180                 # Git commands want to be in wc.
 181                 if (! defined $git_dir) {
 182                         chdir $config{srcdir}
 183                             or error("cannot chdir to $config{srcdir}: $!");
 184                 }
 185                 else {
 186                         chdir $git_dir
 187                             or error("cannot chdir to $git_dir: $!");
 188                 }
 189                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 190         }
 191         # In parent.
 192
 193         # git output is probably utf-8 encoded, but may contain
 194         # other encodings or invalidly encoded stuff. So do not rely
 195         # on the normal utf-8 IO layer, decode it by hand.
 196         binmode($OUT);
 197
 198         my @lines;
 199         while (<$OUT>) {
 200                 $_=decode_utf8($_, 0);
 201
 202                 chomp;
 203
 204                 if (! defined $data_handler) {
 205                         push @lines, $_;
 206                 }
 207                 else {
 208                         last unless $data_handler->($_);
 209                 }
 210         }
 211
 212         close $OUT;
 213
 214         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 215
 216         return wantarray ? @lines : ($? == 0);
 217 }
 218 # Convenient wrappers.
 219 sub run_or_die ($@) { safe_git(\&error, undef, @_) }
 220 sub run_or_cry ($@) { safe_git(sub { warn @_ }, undef, @_) }
 221 sub run_or_non ($@) { safe_git(undef, undef, @_) }
 222
 223 sub ensure_committer {
 224         if (! length $ENV{GIT_AUTHOR_NAME} || ! length $ENV{GIT_COMMITTER_NAME}) {
 225                 my $name = join('', run_or_non("git", "config", "user.name"));
 226                 if (! length $name) {
 227                         run_or_die("git", "config", "user.name", "IkiWiki");
 228                 }
 229         }
 230
 231         if (! length $ENV{GIT_AUTHOR_EMAIL} || ! length $ENV{GIT_COMMITTER_EMAIL}) {
 232                 my $email = join('', run_or_non("git", "config", "user.email"));
 233                 if (! length $email) {
 234                         run_or_die("git", "config", "user.email", "ikiwiki.info");
 235                 }
 236         }
 237 }
 238
 239 sub merge_past ($$$) {
 240         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 241         # Git merge commands work with the committed changes, except in the
 242         # implicit case of '-m' of git checkout(1).  So we should invent a
 243         # kludge here.  In principle, we need to create a throw-away branch
 244         # in preparing for the merge itself.  Since branches are cheap (and
 245         # branching is fast), this shouldn't cost high.
 246         #
 247         # The main problem is the presence of _uncommitted_ local changes.  One
 248         # possible approach to get rid of this situation could be that we first
 249         # make a temporary commit in the master branch and later restore the
 250         # initial state (this is possible since Git has the ability to undo a
 251         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 252         # as follows:
 253         #
 254         #       - create a diff of HEAD:current-sha1
 255         #       - dummy commit
 256         #       - create a dummy branch and switch to it
 257         #       - rewind to past (reset --hard to the current-sha1)
 258         #       - apply the diff and commit
 259         #       - switch to master and do the merge with the dummy branch
 260         #       - make a soft reset (undo the last commit of master)
 261         #
 262         # The above method has some drawbacks: (1) it needs a redundant commit
 263         # just to get rid of local changes, (2) somewhat slow because of the
 264         # required system forks.  Until someone points a more straight method
 265         # (which I would be grateful) I have implemented an alternative method.
 266         # In this approach, we hide all the modified files from Git by renaming
 267         # them (using the 'rename' builtin) and later restore those files in
 268         # the throw-away branch (that is, we put the files themselves instead
 269         # of applying a patch).
 270
 271         my ($sha1, $file, $message) = @_;
 272
 273         my @undo;      # undo stack for cleanup in case of an error
 274         my $conflict;  # file content with conflict markers
 275
 276         ensure_committer();
 277
 278         eval {
 279                 # Hide local changes from Git by renaming the modified file.
 280                 # Relative paths must be converted to absolute for renaming.
 281                 my ($target, $hidden) = (
 282                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 283                 );
 284                 rename($target, $hidden)
 285                     or error("rename '$target' to '$hidden' failed: $!");
 286                 # Ensure to restore the renamed file on error.
 287                 push @undo, sub {
 288                         return if ! -e "$hidden"; # already renamed
 289                         rename($hidden, $target)
 290                             or warn "rename '$hidden' to '$target' failed: $!";
 291                 };
 292
 293                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 294
 295                 # Create a throw-away branch and rewind backward.
 296                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 297                 run_or_die('git', 'branch', $branch, $sha1);
 298
 299                 # Switch to throw-away branch for the merge operation.
 300                 push @undo, sub {
 301                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 302                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 303                         }
 304                 };
 305                 run_or_die('git', 'checkout', $branch);
 306
 307                 # Put the modified file in _this_ branch.
 308                 rename($hidden, $target)
 309                     or error("rename '$hidden' to '$target' failed: $!");
 310
 311                 # _Silently_ commit all modifications in the current branch.
 312                 run_or_non('git', 'commit', '-m', $message, '-a');
 313                 # ... and re-switch to master.
 314                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 315
 316                 # Attempt to merge without complaining.
 317                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 318                         $conflict = readfile($target);
 319                         run_or_die('git', 'reset', '--hard');
 320                 }
 321         };
 322         my $failure = $@;
 323
 324         # Process undo stack (in reverse order).  By policy cleanup
 325         # actions should normally print a warning on failure.
 326         while (my $handle = pop @undo) {
 327                 $handle->();
 328         }
 329
 330         error("Git merge failed!\n$failure\n") if $failure;
 331
 332         return $conflict;
 333 }
 334
 335 sub decode_git_file ($) {
 336         my $file=shift;
 337
 338         # git does not output utf-8 filenames, but instead
 339         # double-quotes them with the utf-8 characters
 340         # escaped as \nnn\nnn.
 341         if ($file =~ m/^"(.*)"$/) {
 342                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 343         }
 344
 345         # strip prefix if in a subdir
 346         if (! defined $prefix) {
 347                 ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 348                 if (! defined $prefix) {
 349                         $prefix="";
 350                 }
 351         }
 352         $file =~ s/^\Q$prefix\E//;
 353
 354         return decode("utf8", $file);
 355 }
 356
 357 sub parse_diff_tree ($) {
 358         # Parse the raw diff tree chunk and return the info hash.
 359         # See git-diff-tree(1) for the syntax.
 360         my $dt_ref = shift;
 361
 362         # End of stream?
 363         return if ! @{ $dt_ref } ||
 364                   !defined $dt_ref->[0] || !length $dt_ref->[0];
 365
 366         my %ci;
 367         # Header line.
 368         while (my $line = shift @{ $dt_ref }) {
 369                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 370
 371                 my $sha1 = $2;
 372                 $ci{'sha1'} = $sha1;
 373                 last;
 374         }
 375
 376         # Identification lines for the commit.
 377         while (my $line = shift @{ $dt_ref }) {
 378                 # Regexps are semi-stolen from gitweb.cgi.
 379                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 380                         $ci{'tree'} = $1;
 381                 }
 382                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 383                         # XXX: collecting in reverse order
 384                         push @{ $ci{'parents'} }, $1;
 385                 }
 386                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 387                         my ($who, $name, $epoch, $tz) =
 388                            ($1,   $2,    $3,     $4 );
 389
 390                         $ci{  $who          } = $name;
 391                         $ci{ "${who}_epoch" } = $epoch;
 392                         $ci{ "${who}_tz"    } = $tz;
 393
 394                         if ($name =~ m/^([^<]+)\s+<([^@>]+)/) {
 395                                 $ci{"${who}_name"} = $1;
 396                                 $ci{"${who}_username"} = $2;
 397                         }
 398                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 399                                 $ci{"${who}_username"} = $1;
 400                         }
 401                         else {
 402                                 $ci{"${who}_username"} = $name;
 403                         }
 404                 }
 405                 elsif ($line =~ m/^$/) {
 406                         # Trailing empty line signals next section.
 407                         last;
 408                 }
 409         }
 410
 411         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 412
 413         if (defined $ci{'parents'}) {
 414                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 415         }
 416         else {
 417                 $ci{'parent'} = 0 x 40;
 418         }
 419
 420         # Commit message (optional).
 421         while ($dt_ref->[0] =~ /^    /) {
 422                 my $line = shift @{ $dt_ref };
 423                 $line =~ s/^    //;
 424                 push @{ $ci{'comment'} }, $line;
 425         }
 426         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 427
 428         # Modified files.
 429         while (my $line = shift @{ $dt_ref }) {
 430                 if ($line =~ m{^
 431                         (:+)       # number of parents
 432                         ([^\t]+)\t # modes, sha1, status
 433                         (.*)       # file names
 434                 $}xo) {
 435                         my $num_parents = length $1;
 436                         my @tmp = split(" ", $2);
 437                         my ($file, $file_to) = split("\t", $3);
 438                         my @mode_from = splice(@tmp, 0, $num_parents);
 439                         my $mode_to = shift(@tmp);
 440                         my @sha1_from = splice(@tmp, 0, $num_parents);
 441                         my $sha1_to = shift(@tmp);
 442                         my $status = shift(@tmp);
 443
 444                         if (length $file) {
 445                                 push @{ $ci{'details'} }, {
 446                                         'file'      => decode_git_file($file),
 447                                         'sha1_from' => $sha1_from[0],
 448                                         'sha1_to'   => $sha1_to,
 449                                         'mode_from' => $mode_from[0],
 450                                         'mode_to'   => $mode_to,
 451                                         'status'    => $status,
 452                                 };
 453                         }
 454                         next;
 455                 };
 456                 last;
 457         }
 458
 459         return \%ci;
 460 }
 461
 462 sub git_commit_info ($;$) {
 463         # Return an array of commit info hashes of num commits
 464         # starting from the given sha1sum.
 465         my ($sha1, $num) = @_;
 466
 467         my @opts;
 468         push @opts, "--max-count=$num" if defined $num;
 469
 470         my @raw_lines = run_or_die('git', 'log', @opts,
 471                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 472                 '-r', $sha1, '--no-renames', '--', '.');
 473
 474         my @ci;
 475         while (my $parsed = parse_diff_tree(\@raw_lines)) {
 476                 push @ci, $parsed;
 477         }
 478
 479         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 480
 481         return wantarray ? @ci : $ci[0];
 482 }
 483
 484 sub rcs_find_changes ($) {
 485         my $oldrev=shift;
 486
 487         # Note that git log will sometimes show files being added that
 488         # don't exist. Particularly, git merge -s ours can result in a
 489         # merge commit where some files were not really added.
 490         # This is why the code below verifies that the files really
 491         # exist.
 492         my @raw_lines = run_or_die('git', 'log',
 493                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 494                 '--no-renames', , '--reverse',
 495                 '-r', "$oldrev..HEAD", '--', '.');
 496
 497         # Due to --reverse, we see changes in chronological order.
 498         my %changed;
 499         my %deleted;
 500         my $nullsha = 0 x 40;
 501         my $newrev=$oldrev;
 502         while (my $ci = parse_diff_tree(\@raw_lines)) {
 503                 $newrev=$ci->{sha1};
 504                 foreach my $i (@{$ci->{details}}) {
 505                         my $file=$i->{file};
 506                         if ($i->{sha1_to} eq $nullsha) {
 507                                 if (! -e "$config{srcdir}/$file") {
 508                                         delete $changed{$file};
 509                                         $deleted{$file}=1;
 510                                 }
 511                         }
 512                         else {
 513                                 if (-e "$config{srcdir}/$file") {
 514                                         delete $deleted{$file};
 515                                         $changed{$file}=1;
 516                                 }
 517                         }
 518                 }
 519         }
 520
 521         return (\%changed, \%deleted, $newrev);
 522 }
 523
 524 sub git_sha1_file ($) {
 525         my $file=shift;
 526         git_sha1("--", $file);
 527 }
 528
 529 sub git_sha1 (@) {
 530         # Ignore error since a non-existing file might be given.
 531         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 532                 '--', @_);
 533         if (defined $sha1) {
 534                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 535         }
 536         return defined $sha1 ? $sha1 : '';
 537 }
 538
 539 sub rcs_get_current_rev () {
 540         git_sha1();
 541 }
 542
 543 sub rcs_update () {
 544         # Update working directory.
 545
 546         ensure_committer();
 547
 548         if (length $config{gitorigin_branch}) {
 549                 run_or_cry('git', 'pull', '--prune', $config{gitorigin_branch});
 550         }
 551 }
 552
 553 sub rcs_prepedit ($) {
 554         # Return the commit sha1sum of the file when editing begins.
 555         # This will be later used in rcs_commit if a merge is required.
 556         my ($file) = @_;
 557
 558         return git_sha1_file($file);
 559 }
 560
 561 sub rcs_commit (@) {
 562         # Try to commit the page; returns undef on _success_ and
 563         # a version of the page with the rcs's conflict markers on
 564         # failure.
 565         my %params=@_;
 566
 567         # Check to see if the page has been changed by someone else since
 568         # rcs_prepedit was called.
 569         my $cur    = git_sha1_file($params{file});
 570         my $prev;
 571         if (defined $params{token}) {
 572                 ($prev) = $params{token} =~ /^($sha1_pattern)$/; # untaint
 573         }
 574
 575         if (defined $cur && defined $prev && $cur ne $prev) {
 576                 my $conflict = merge_past($prev, $params{file}, $dummy_commit_msg);
 577                 return $conflict if defined $conflict;
 578         }
 579
 580         return rcs_commit_helper(@_);
 581 }
 582
 583 sub rcs_commit_staged (@) {
 584         # Commits all staged changes. Changes can be staged using rcs_add,
 585         # rcs_remove, and rcs_rename.
 586         return rcs_commit_helper(@_);
 587 }
 588
 589 sub rcs_commit_helper (@) {
 590         my %params=@_;
 591
 592         my %env=%ENV;
 593
 594         if (defined $params{session}) {
 595                 # Set the commit author and email based on web session info.
 596                 my $u;
 597                 if (defined $params{session}->param("name")) {
 598                         $u=$params{session}->param("name");
 599                 }
 600                 elsif (defined $params{session}->remote_addr()) {
 601                         $u=$params{session}->remote_addr();
 602                 }
 603                 if (defined $u) {
 604                         $u=encode_utf8($u);
 605                         $ENV{GIT_AUTHOR_NAME}=$u;
 606                 }
 607                 if (defined $params{session}->param("nickname")) {
 608                         $u=encode_utf8($params{session}->param("nickname"));
 609                         $u=~s/\s+/_/g;
 610                         $u=~s/[^-_0-9[:alnum:]]+//g;
 611                 }
 612                 if (defined $u) {
 613                         $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 614                 }
 615         }
 616
 617         ensure_committer();
 618
 619         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 620         my @opts;
 621         if ($params{message} !~ /\S/) {
 622                 # Force git to allow empty commit messages.
 623                 # (If this version of git supports it.)
 624                 my ($version)=`git --version` =~ /git version (.*)/;
 625                 if ($version ge "1.7.8") {
 626                         push @opts, "--allow-empty-message", "--no-edit";
 627                 }
 628                 if ($version ge "1.7.2") {
 629                         push @opts, "--allow-empty-message";
 630                 }
 631                 elsif ($version ge "1.5.4") {
 632                         push @opts, '--cleanup=verbatim';
 633                 }
 634                 else {
 635                         $params{message}.=".";
 636                 }
 637         }
 638         if (exists $params{file}) {
 639                 push @opts, '--', $params{file};
 640         }
 641         # git commit returns non-zero if nothing really changed.
 642         # So we should ignore its exit status (hence run_or_non).
 643         if (run_or_non('git', 'commit', '-m', $params{message}, '-q', @opts)) {
 644                 if (length $config{gitorigin_branch}) {
 645                         run_or_cry('git', 'push', $config{gitorigin_branch}, $config{gitmaster_branch});
 646                 }
 647         }
 648
 649         %ENV=%env;
 650         return undef; # success
 651 }
 652
 653 sub rcs_add ($) {
 654         # Add file to archive.
 655
 656         my ($file) = @_;
 657
 658         ensure_committer();
 659
 660         run_or_cry('git', 'add', '--', $file);
 661 }
 662
 663 sub rcs_remove ($) {
 664         # Remove file from archive.
 665
 666         my ($file) = @_;
 667
 668         ensure_committer();
 669
 670         run_or_cry('git', 'rm', '-f', '--', $file);
 671 }
 672
 673 sub rcs_rename ($$) {
 674         my ($src, $dest) = @_;
 675
 676         ensure_committer();
 677
 678         run_or_cry('git', 'mv', '-f', '--', $src, $dest);
 679 }
 680
 681 sub rcs_recentchanges ($) {
 682         # List of recent changes.
 683
 684         my ($num) = @_;
 685
 686         eval q{use Date::Parse};
 687         error($@) if $@;
 688
 689         my @rets;
 690         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 691                 # Skip redundant commits.
 692                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 693
 694                 my ($sha1, $when) = (
 695                         $ci->{'sha1'},
 696                         $ci->{'author_epoch'}
 697                 );
 698
 699                 my @pages;
 700                 foreach my $detail (@{ $ci->{'details'} }) {
 701                         my $file = $detail->{'file'};
 702                         my $efile = join('/',
 703                                 map { uri_escape_utf8($_) } split('/', $file)
 704                         );
 705
 706                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 707                         $diffurl =~ s/\[\[file\]\]/$efile/go;
 708                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 709                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 710                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 711                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 712
 713                         push @pages, {
 714                                 page => pagename($file),
 715                                 diffurl => $diffurl,
 716                         };
 717                 }
 718
 719                 my @messages;
 720                 my $pastblank=0;
 721                 foreach my $line (@{$ci->{'comment'}}) {
 722                         $pastblank=1 if $line eq '';
 723                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 724                         push @messages, { line => $line };
 725                 }
 726
 727                 my $user=$ci->{'author_username'};
 728                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 729                 my $nickname;
 730
 731                 # Set nickname only if a non-url author_username is available,
 732                 # and author_name is an url.
 733                 if ($user !~ /:\/\// && defined $ci->{'author_name'} &&
 734                     $ci->{'author_name'} =~ /:\/\//) {
 735                         $nickname=$user;
 736                         $user=$ci->{'author_name'};
 737                 }
 738
 739                 # compatability code for old web commit messages
 740                 if (! $web_commit &&
 741                       defined $messages[0] &&
 742                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 743                         $user = defined $2 ? "$2" : "$3";
 744                         $messages[0]->{line} = $4;
 745                         $web_commit=1;
 746                 }
 747
 748                 push @rets, {
 749                         rev        => $sha1,
 750                         user       => $user,
 751                         nickname   => $nickname,
 752                         committype => $web_commit ? "web" : "git",
 753                         when       => $when,
 754                         message    => [@messages],
 755                         pages      => [@pages],
 756                 } if @pages;
 757
 758                 last if @rets >= $num;
 759         }
 760
 761         return @rets;
 762 }
 763
 764 sub rcs_diff ($;$) {
 765         my $rev=shift;
 766         my $maxlines=shift;
 767         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 768         my @lines;
 769         my $addlines=sub {
 770                 my $line=shift;
 771                 return if defined $maxlines && @lines == $maxlines;
 772                 push @lines, $line."\n"
 773                         if (@lines || $line=~/^diff --git/);
 774                 return 1;
 775         };
 776         safe_git(undef, $addlines, "git", "show", $sha1);
 777         if (wantarray) {
 778                 return @lines;
 779         }
 780         else {
 781                 return join("", @lines);
 782         }
 783 }
 784
 785 {
 786 my %time_cache;
 787
 788 sub findtimes ($$) {
 789         my $file=shift;
 790         my $id=shift; # 0 = mtime ; 1 = ctime
 791
 792         if (! keys %time_cache) {
 793                 my $date;
 794                 foreach my $line (run_or_die('git', 'log',
 795                                 '--pretty=format:%at',
 796                                 '--name-only', '--relative')) {
 797                         if (! defined $date && $line =~ /^(\d+)$/) {
 798                                 $date=$line;
 799                         }
 800                         elsif (! length $line) {
 801                                 $date=undef;
 802                         }
 803                         else {
 804                                 my $f=decode_git_file($line);
 805
 806                                 if (! $time_cache{$f}) {
 807                                         $time_cache{$f}[0]=$date; # mtime
 808                                 }
 809                                 $time_cache{$f}[1]=$date; # ctime
 810                         }
 811                 }
 812         }
 813
 814         return exists $time_cache{$file} ? $time_cache{$file}[$id] : 0;
 815 }
 816
 817 }
 818
 819 sub rcs_getctime ($) {
 820         my $file=shift;
 821
 822         return findtimes($file, 1);
 823 }
 824
 825 sub rcs_getmtime ($) {
 826         my $file=shift;
 827
 828         return findtimes($file, 0);
 829 }
 830
 831 {
 832 my $ret;
 833 sub git_find_root {
 834         # The wiki may not be the only thing in the git repo.
 835         # Determine if it is in a subdirectory by examining the srcdir,
 836         # and its parents, looking for the .git directory.
 837
 838         return @$ret if defined $ret;
 839
 840         my $subdir="";
 841         my $dir=$config{srcdir};
 842         while (! -d "$dir/.git") {
 843                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 844                 $dir=IkiWiki::dirname($dir);
 845                 if (! length $dir) {
 846                         error("cannot determine root of git repo");
 847                 }
 848         }
 849
 850         $ret=[$subdir, $dir];
 851         return @$ret;
 852 }
 853
 854 }
 855
 856 sub git_parse_changes {
 857         my $reverted = shift;
 858         my @changes = @_;
 859
 860         my ($subdir, $rootdir) = git_find_root();
 861         my @rets;
 862         foreach my $ci (@changes) {
 863                 foreach my $detail (@{ $ci->{'details'} }) {
 864                         my $file = $detail->{'file'};
 865
 866                         # check that all changed files are in the subdir
 867                         if (length $subdir &&
 868                             ! ($file =~ s/^\Q$subdir\E//)) {
 869                                 error sprintf(gettext("you are not allowed to change %s"), $file);
 870                         }
 871
 872                         my ($action, $mode, $path);
 873                         if ($detail->{'status'} =~ /^[M]+\d*$/) {
 874                                 $action="change";
 875                                 $mode=$detail->{'mode_to'};
 876                         }
 877                         elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 878                                 $action= $reverted ? "remove" : "add";
 879                                 $mode=$detail->{'mode_to'};
 880                         }
 881                         elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 882                                 $action= $reverted ? "add" : "remove";
 883                                 $mode=$detail->{'mode_from'};
 884                         }
 885                         else {
 886                                 error "unknown status ".$detail->{'status'};
 887                         }
 888
 889                         # test that the file mode is ok
 890                         if ($mode !~ /^100[64][64][64]$/) {
 891                                 error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 892                         }
 893                         if ($action eq "change") {
 894                                 if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 895                                         error gettext("you are not allowed to change file modes");
 896                                 }
 897                         }
 898
 899                         # extract attachment to temp file
 900                         if (($action eq 'add' || $action eq 'change') &&
 901                             ! pagetype($file)) {
 902                                 eval q{use File::Temp};
 903                                 die $@ if $@;
 904                                 my $fh;
 905                                 ($fh, $path)=File::Temp::tempfile(undef, UNLINK => 1);
 906                                 my $cmd = "cd $git_dir && ".
 907                                           "git show $detail->{sha1_to} > '$path'";
 908                                 if (system($cmd) != 0) {
 909                                         error("failed writing temp file '$path'.");
 910                                 }
 911                         }
 912
 913                         push @rets, {
 914                                 file => $file,
 915                                 action => $action,
 916                                 path => $path,
 917                         };
 918                 }
 919         }
 920
 921         return @rets;
 922 }
 923
 924 sub rcs_receive () {
 925         my @rets;
 926         while (<>) {
 927                 chomp;
 928                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 929
 930                 # only allow changes to gitmaster_branch
 931                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 932                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 933                 }
 934
 935                 # Avoid chdir when running git here, because the changes
 936                 # are in the master git repo, not the srcdir repo.
 937                 # (Also, if a subdir is involved, we don't want to chdir to
 938                 # it and only see changes in it.)
 939                 # The pre-receive hook already puts us in the right place.
 940                 in_git_dir(".", sub {
 941                         push @rets, git_parse_changes(0, git_commit_info($oldrev."..".$newrev));
 942                 });
 943         }
 944
 945         return reverse @rets;
 946 }
 947
 948 sub rcs_preprevert ($) {
 949         my $rev=shift;
 950         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 951
 952         # Examine changes from root of git repo, not from any subdir,
 953         # in order to see all changes.
 954         my ($subdir, $rootdir) = git_find_root();
 955         in_git_dir($rootdir, sub {
 956                 my @commits=git_commit_info($sha1, 1);
 957
 958                 if (! @commits) {
 959                         error "unknown commit"; # just in case
 960                 }
 961
 962                 # git revert will fail on merge commits. Add a nice message.
 963                 if (exists $commits[0]->{parents} &&
 964                     @{$commits[0]->{parents}} > 1) {
 965                         error gettext("you are not allowed to revert a merge");
 966                 }
 967
 968                 git_parse_changes(1, @commits);
 969         });
 970 }
 971
 972 sub rcs_revert ($) {
 973         # Try to revert the given rev; returns undef on _success_.
 974         my $rev = shift;
 975         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 976
 977         ensure_committer();
 978
 979         if (run_or_non('git', 'revert', '--no-commit', $sha1)) {
 980                 return undef;
 981         }
 982         else {
 983                 run_or_die('git', 'reset', '--hard');
 984                 return sprintf(gettext("Failed to revert commit %s"), $sha1);
 985         }
 986 }
 987
 988 1