IkiWiki/Plugin/remove.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::remove;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "remove", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "remove", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "remove", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "remove", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                         section => "web",
  22                 },
  23 }
  24
  25 sub check_canremove ($$$) {
  26         my $page=shift;
  27         my $q=shift;
  28         my $session=shift;
  29
  30         # Must be a known source file.
  31         if (! exists $pagesources{$page}) {
  32                 error(sprintf(gettext("%s does not exist"),
  33                         htmllink("", "", $page, noimageinline => 1)));
  34         }
  35
  36         # Must exist on disk, and be a regular file.
  37         my $file=$pagesources{$page};
  38         if (! -e "$config{srcdir}/$file") {
  39                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
  40         }
  41         elsif (-l "$config{srcdir}/$file" && ! -f _) {
  42                 error(sprintf(gettext("%s is not a file"), $file));
  43         }
  44
  45         # If a user can't upload an attachment, don't let them delete it.
  46         # This is sorta overkill, but better safe than sorry.
  47         if (! defined pagetype($pagesources{$page})) {
  48                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  49                         IkiWiki::Plugin::attachment::check_canattach($session, $page, "$config{srcdir}/$file");
  50                 }
  51                 else {
  52                         error("removal of attachments is not allowed");
  53                 }
  54         }
  55
  56         my $canremove;
  57         IkiWiki::run_hooks(canremove => sub {
  58                 return if defined $canremove;
  59                 my $ret=shift->(page => $page, cgi => $q, session => $session);
  60                 if (defined $ret) {
  61                         if ($ret eq "") {
  62                                 $canremove=1;
  63                         }
  64                         elsif (ref $ret eq 'CODE') {
  65                                 $ret->();
  66                                 $canremove=0;
  67                         }
  68                         elsif (defined $ret) {
  69                                 error($ret);
  70                                 $canremove=0;
  71                         }
  72                 }
  73         });
  74         return defined $canremove ? $canremove : 1;
  75 }
  76
  77 sub formbuilder_setup (@) {
  78         my %params=@_;
  79         my $form=$params{form};
  80         my $q=$params{cgi};
  81
  82         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  83             $form->field("do") eq "create")) {
  84                 # Removal button for the page, and also for attachments.
  85                 push @{$params{buttons}}, "Remove" if $form->field("do") eq "edit";
  86                 $form->tmpl_param("field-remove" => '<input name="_submit" type="submit" value="Remove Attachments" />');
  87         }
  88 }
  89
  90 sub confirmation_form ($$) {
  91         my $q=shift;
  92         my $session=shift;
  93
  94         eval q{use CGI::FormBuilder};
  95         error($@) if $@;
  96         my $f = CGI::FormBuilder->new(
  97                 name => "remove",
  98                 header => 0,
  99                 charset => "utf-8",
 100                 method => 'POST',
 101                 javascript => 0,
 102                 params => $q,
 103                 action => IkiWiki::cgiurl(),
 104                 stylesheet => 1,
 105                 fields => [qw{do page}],
 106         );
 107
 108         $f->field(name => "sid", type => "hidden", value => $session->id,
 109                 force => 1);
 110         $f->field(name => "do", type => "hidden", value => "remove", force => 1);
 111
 112         return $f, ["Remove", "Cancel"];
 113 }
 114
 115 sub removal_confirm ($$@) {
 116         my $q=shift;
 117         my $session=shift;
 118         my $attachment=shift;
 119         my @pages=@_;
 120
 121         # Special case for unsaved attachments.
 122         @pages=grep {
 123                 ! (IkiWiki::Plugin::attachment->can("remove_held_attachment") &&
 124                    IkiWiki::Plugin::attachment::remove_held_attachment($_))
 125         } @pages;
 126         return unless @pages;
 127
 128         foreach my $page (@pages) {
 129                 IkiWiki::check_canedit($page, $q, $session);
 130                 check_canremove($page, $q, $session);
 131         }
 132
 133         # Save current form state to allow returning to it later
 134         # without losing any edits.
 135         # (But don't save what button was submitted, to avoid
 136         # looping back to here.)
 137         # Note: "_submit" is CGI::FormBuilder internals.
 138         $q->param(-name => "_submit", -value => "");
 139         $session->param(postremove => scalar $q->Vars);
 140         IkiWiki::cgi_savesession($session);
 141
 142         my ($f, $buttons)=confirmation_form($q, $session);
 143         $f->title(sprintf(gettext("confirm removal of %s"),
 144                 join(", ", map { pagetitle($_) } @pages)));
 145         $f->field(name => "page", type => "hidden", value => \@pages, force => 1);
 146         if (defined $attachment) {
 147                 $f->field(name => "attachment", type => "hidden",
 148                         value => $attachment, force => 1);
 149         }
 150
 151         IkiWiki::showform($f, $buttons, $session, $q);
 152         exit 0;
 153 }
 154
 155 sub postremove ($) {
 156         my $session=shift;
 157
 158         # Load saved form state and return to edit form.
 159         my $postremove=CGI->new($session->param("postremove"));
 160         $session->clear("postremove");
 161         IkiWiki::cgi_savesession($session);
 162         IkiWiki::cgi($postremove, $session);
 163 }
 164
 165 sub formbuilder (@) {
 166         my %params=@_;
 167         my $form=$params{form};
 168
 169         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 170             $form->field("do") eq "create")) {
 171                 my $q=$params{cgi};
 172                 my $session=$params{session};
 173
 174                 if ($form->submitted eq "Remove" && $form->field("do") eq "edit") {
 175                         removal_confirm($q, $session, 0, $form->field("page"));
 176                 }
 177                 elsif ($form->submitted eq "Remove Attachments") {
 178                         my @selected=map { Encode::decode_utf8($_) } $q->param("attachment_select");
 179                         if (! @selected) {
 180                                 error(gettext("Please select the attachments to remove."));
 181                         }
 182                         removal_confirm($q, $session, 1, @selected);
 183                 }
 184         }
 185 }
 186
 187 sub sessioncgi ($$) {
 188         my $q=shift;
 189
 190         if ($q->param("do") eq 'remove') {
 191                 my $session=shift;
 192                 my ($form, $buttons)=confirmation_form($q, $session);
 193                 IkiWiki::decode_form_utf8($form);
 194
 195                 if ($form->submitted eq 'Cancel') {
 196                         postremove($session);
 197                 }
 198                 elsif ($form->submitted eq 'Remove' && $form->validate) {
 199                         IkiWiki::checksessionexpiry($q, $session, $q->param('sid'));
 200
 201                         my @pages=$form->field("page");
 202
 203                         # Validate removal by checking that the page exists,
 204                         # and that the user is allowed to edit(/remove) it.
 205                         my @files;
 206                         foreach my $page (@pages) {
 207                                 IkiWiki::check_canedit($page, $q, $session);
 208                                 check_canremove($page, $q, $session);
 209
 210                                 # This untaint is safe because of the
 211                                 # checks performed above, which verify the
 212                                 # page is a normal file, etc.
 213                                 push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
 214                         }
 215
 216                         # Do removal, and update the wiki.
 217                         require IkiWiki::Render;
 218                         if ($config{rcs}) {
 219                                 IkiWiki::disable_commit_hook();
 220                                 foreach my $file (@files) {
 221                                         IkiWiki::rcs_remove($file);
 222                                 }
 223                                 IkiWiki::rcs_commit_staged(
 224                                         message => gettext("removed"),
 225                                         session => $session,
 226                                 );
 227                                 IkiWiki::enable_commit_hook();
 228                                 IkiWiki::rcs_update();
 229                         }
 230                         else {
 231                                 foreach my $file (@files) {
 232                                         IkiWiki::prune("$config{srcdir}/$file");
 233                                 }
 234                         }
 235                         IkiWiki::refresh();
 236                         IkiWiki::saveindex();
 237
 238                         if ($q->param("attachment")) {
 239                                 # Attachments were deleted, so redirect
 240                                 # back to the edit form.
 241                                 postremove($session);
 242                         }
 243                         else {
 244                                 # The page is gone, so redirect to parent
 245                                 # of the page.
 246                                 my $parent=IkiWiki::dirname($pages[0]);
 247                                 if (! exists $pagesources{$parent}) {
 248                                         $parent="index";
 249                                 }
 250                                 IkiWiki::redirect($q, urlto($parent));
 251                         }
 252                 }
 253                 else {
 254                         removal_confirm($q, $session, 0, $form->field("page"));
 255                 }
 256
 257                 exit 0;
 258         }
 259 }
 260
 261 1