IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my %backlinks;
  11 my $backlinks_calculated=0;
  12
  13 sub calculate_backlinks () { #{{{
  14         return if $backlinks_calculated;
  15         %backlinks=();
  16         foreach my $page (keys %links) {
  17                 foreach my $link (@{$links{$page}}) {
  18                         my $bestlink=bestlink($page, $link);
  19                         if (length $bestlink && $bestlink ne $page) {
  20                                 $backlinks{$bestlink}{$page}=1;
  21                         }
  22                 }
  23         }
  24         $backlinks_calculated=1;
  25 } #}}}
  26
  27 sub backlinks ($) { #{{{
  28         my $page=shift;
  29
  30         calculate_backlinks();
  31
  32         my @links;
  33         return unless $backlinks{$page};
  34         foreach my $p (keys %{$backlinks{$page}}) {
  35                 my $href=abs2rel(htmlpage($p), dirname($page));
  36
  37                 # Trim common dir prefixes from both pages.
  38                 my $p_trimmed=$p;
  39                 my $page_trimmed=$page;
  40                 my $dir;
  41                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  42                         defined $dir &&
  43                         $p_trimmed=~s/^\Q$dir\E// &&
  44                         $page_trimmed=~s/^\Q$dir\E//;
  45
  46                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  47         }
  48
  49         return sort { $a->{page} cmp $b->{page} } @links;
  50 } #}}}
  51
  52 sub parentlinks ($) { #{{{
  53         my $page=shift;
  54
  55         my @ret;
  56         my $pagelink="";
  57         my $path="";
  58         my $skip=1;
  59         return if $page eq 'index'; # toplevel
  60         foreach my $dir (reverse split("/", $page)) {
  61                 if (! $skip) {
  62                         $path.="../";
  63                         unshift @ret, { url => $path.htmlpage($dir), page => pagetitle($dir) };
  64                 }
  65                 else {
  66                         $skip=0;
  67                 }
  68         }
  69         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
  70         return @ret;
  71 } #}}}
  72
  73 sub genpage ($$$) { #{{{
  74         my $page=shift;
  75         my $content=shift;
  76         my $mtime=shift;
  77
  78         my $template=template("page.tmpl", blind_cache => 1);
  79         my $actions=0;
  80
  81         if (length $config{cgiurl}) {
  82                 $template->param(editurl => cgiurl(do => "edit", page => $page));
  83                 $template->param(prefsurl => cgiurl(do => "prefs"));
  84                 if ($config{rcs}) {
  85                         $template->param(recentchangesurl => cgiurl(do => "recentchanges"));
  86                 }
  87                 $actions++;
  88         }
  89
  90         if (length $config{historyurl}) {
  91                 my $u=$config{historyurl};
  92                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  93                 $template->param(historyurl => $u);
  94                 $actions++;
  95         }
  96         if ($config{discussion}) {
  97                 $template->param(discussionlink => htmllink($page, $page, "Discussion", 1, 1));
  98                 $actions++;
  99         }
 100
 101         if ($actions) {
 102                 $template->param(have_actions => 1);
 103         }
 104
 105         $template->param(
 106                 title => $page eq 'index'
 107                         ? $config{wikiname}
 108                         : pagetitle(basename($page)),
 109                 wikiname => $config{wikiname},
 110                 parentlinks => [parentlinks($page)],
 111                 content => $content,
 112                 backlinks => [backlinks($page)],
 113                 mtime => displaytime($mtime),
 114                 baseurl => baseurl($page),
 115         );
 116
 117         run_hooks(pagetemplate => sub {
 118                 shift->(page => $page, destpage => $page, template => $template);
 119         });
 120
 121         $content=$template->output;
 122
 123         run_hooks(format => sub {
 124                 $content=shift->(
 125                         page => $page,
 126                         content => $content,
 127                 );
 128         });
 129
 130         return $content;
 131 } #}}}
 132
 133 sub mtime ($) { #{{{
 134         my $file=shift;
 135
 136         return (stat($file))[9];
 137 } #}}}
 138
 139 sub scan ($) { #{{{
 140         my $file=shift;
 141
 142         my $type=pagetype($file);
 143         if (defined $type) {
 144                 my $srcfile=srcfile($file);
 145                 my $content=readfile($srcfile);
 146                 my $page=pagename($file);
 147                 will_render($page, htmlpage($page), 1);
 148
 149                 # Always needs to be done, since filters might add links
 150                 # to the content.
 151                 $content=filter($page, $content);
 152
 153                 my @links;
 154                 while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 155                         push @links, titlepage($2);
 156                 }
 157                 if ($config{discussion}) {
 158                         # Discussion links are a special case since they're not in the
 159                         # text of the page, but on its template.
 160                         push @links, "$page/discussion";
 161                 }
 162                 $links{$page}=\@links;
 163
 164                 # Preprocess in scan-only mode.
 165                 preprocess($page, $page, $content, 1);
 166         }
 167         else {
 168                 will_render($file, $file, 1);
 169         }
 170 } #}}}
 171
 172 sub render ($) { #{{{
 173         my $file=shift;
 174
 175         my $type=pagetype($file);
 176         my $srcfile=srcfile($file);
 177         if (defined $type) {
 178                 my $content=readfile($srcfile);
 179                 my $page=pagename($file);
 180                 delete $depends{$page};
 181                 will_render($page, htmlpage($page), 1);
 182
 183                 $content=filter($page, $content);
 184                 $content=preprocess($page, $page, $content);
 185                 $content=linkify($page, $page, $content);
 186                 $content=htmlize($page, $type, $content);
 187
 188                 writefile(htmlpage($page), $config{destdir},
 189                         genpage($page, $content, mtime($srcfile)));
 190                 $oldpagemtime{$page}=time;
 191         }
 192         else {
 193                 my $content=readfile($srcfile, 1);
 194                 delete $depends{$file};
 195                 will_render($file, $file, 1);
 196                 writefile($file, $config{destdir}, $content, 1);
 197                 $oldpagemtime{$file}=time;
 198         }
 199 } #}}}
 200
 201 sub prune ($) { #{{{
 202         my $file=shift;
 203
 204         unlink($file);
 205         my $dir=dirname($file);
 206         while (rmdir($dir)) {
 207                 $dir=dirname($dir);
 208         }
 209 } #}}}
 210
 211 sub refresh () { #{{{
 212         # find existing pages
 213         my %exists;
 214         my @files;
 215         eval q{use File::Find};
 216         find({
 217                 no_chdir => 1,
 218                 wanted => sub {
 219                         $_=decode_utf8($_);
 220                         if (/$config{wiki_file_prune_regexp}/) {
 221                                 $File::Find::prune=1;
 222                         }
 223                         elsif (! -d $_ && ! -l $_) {
 224                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 225                                 if (! defined $f) {
 226                                         warn("skipping bad filename $_\n");
 227                                 }
 228                                 else {
 229                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 230                                         push @files, $f;
 231                                         $exists{pagename($f)}=1;
 232                                 }
 233                         }
 234                 },
 235         }, $config{srcdir});
 236         find({
 237                 no_chdir => 1,
 238                 wanted => sub {
 239                         $_=decode_utf8($_);
 240                         if (/$config{wiki_file_prune_regexp}/) {
 241                                 $File::Find::prune=1;
 242                         }
 243                         elsif (! -d $_ && ! -l $_) {
 244                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 245                                 if (! defined $f) {
 246                                         warn("skipping bad filename $_\n");
 247                                 }
 248                                 else {
 249                                         # Don't add files that are in the
 250                                         # srcdir.
 251                                         $f=~s/^\Q$config{underlaydir}\E\/?//;
 252                                         if (! -e "$config{srcdir}/$f" &&
 253                                             ! -l "$config{srcdir}/$f") {
 254                                                 push @files, $f;
 255                                                 $exists{pagename($f)}=1;
 256                                         }
 257                                 }
 258                         }
 259                 },
 260         }, $config{underlaydir});
 261
 262         my %rendered;
 263
 264         # check for added or removed pages
 265         my @add;
 266         foreach my $file (@files) {
 267                 my $page=pagename($file);
 268                 if (! $oldpagemtime{$page}) {
 269                         push @add, $file;
 270                         $pagecase{lc $page}=$page;
 271                         $pagesources{$page}=$file;
 272                         if ($config{getctime} && -e "$config{srcdir}/$file") {
 273                                 $pagectime{$page}=rcs_getctime("$config{srcdir}/$file");
 274                         }
 275                         elsif (! exists $pagectime{$page}) {
 276                                 $pagectime{$page}=mtime(srcfile($file));
 277                         }
 278                 }
 279         }
 280         my @del;
 281         foreach my $page (keys %oldpagemtime) {
 282                 if (! $exists{$page}) {
 283                         debug("removing old page $page");
 284                         push @del, $pagesources{$page};
 285                         $links{$page}=[];
 286                         $renderedfiles{$page}=[];
 287                         $oldpagemtime{$page}=0;
 288                         prune($config{destdir}."/".$_)
 289                                 foreach @{$oldrenderedfiles{$page}};
 290                         delete $pagesources{$page};
 291                 }
 292         }
 293
 294         # scan changed and new files
 295         my @changed;
 296         foreach my $file (@files) {
 297                 my $page=pagename($file);
 298
 299                 if (! exists $oldpagemtime{$page} ||
 300                     mtime(srcfile($file)) > $oldpagemtime{$page} ||
 301                     $forcerebuild{$page}) {
 302                         debug("scanning $file");
 303                         push @changed, $file;
 304                         scan($file);
 305                 }
 306         }
 307         calculate_backlinks();
 308
 309         # render changed and new pages
 310         foreach my $file (@changed) {
 311                 debug("rendering $file");
 312                 render($file);
 313                 $rendered{$file}=1;
 314         }
 315
 316         # rebuild pages that link to added or removed pages
 317         if (@add || @del) {
 318                 foreach my $f (@add, @del) {
 319                         my $p=pagename($f);
 320                         foreach my $page (keys %{$backlinks{$p}}) {
 321                                 my $file=$pagesources{$page};
 322                                 next if $rendered{$file};
 323                                 debug("rendering $file, which links to $p");
 324                                 render($file);
 325                                 $rendered{$file}=1;
 326                         }
 327                 }
 328         }
 329
 330         if (%rendered || @del) {
 331                 # rebuild dependant pages
 332                 foreach my $f (@files) {
 333                         next if $rendered{$f};
 334                         my $p=pagename($f);
 335                         if (exists $depends{$p}) {
 336                                 foreach my $file (keys %rendered, @del) {
 337                                         next if $f eq $file;
 338                                         my $page=pagename($file);
 339                                         if (pagespec_match($page, $depends{$p})) {
 340                                                 debug("rendering $f, which depends on $page");
 341                                                 render($f);
 342                                                 $rendered{$f}=1;
 343                                                 last;
 344                                         }
 345                                 }
 346                         }
 347                 }
 348
 349                 # handle backlinks; if a page has added/removed links,
 350                 # update the pages it links to
 351                 my %linkchanged;
 352                 foreach my $file (keys %rendered, @del) {
 353                         my $page=pagename($file);
 354
 355                         if (exists $links{$page}) {
 356                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 357                                         if (length $link &&
 358                                             (! exists $oldlinks{$page} ||
 359                                              ! grep { bestlink($page, $_) eq $link } @{$oldlinks{$page}})) {
 360                                                 $linkchanged{$link}=1;
 361                                         }
 362                                 }
 363                         }
 364                         if (exists $oldlinks{$page}) {
 365                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 366                                         if (length $link &&
 367                                             (! exists $links{$page} ||
 368                                              ! grep { bestlink($page, $_) eq $link } @{$links{$page}})) {
 369                                                 $linkchanged{$link}=1;
 370                                         }
 371                                 }
 372                         }
 373                 }
 374                 foreach my $link (keys %linkchanged) {
 375                         my $linkfile=$pagesources{$link};
 376                         if (defined $linkfile) {
 377                                 next if $rendered{$linkfile};
 378                                 debug("rendering $linkfile, to update its backlinks");
 379                                 render($linkfile);
 380                                 $rendered{$linkfile}=1;
 381                         }
 382                 }
 383         }
 384
 385         # remove no longer rendered files
 386         foreach my $src (keys %rendered) {
 387                 my $page=pagename($src);
 388                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 389                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 390                                 debug("removing $file, no longer rendered by $page");
 391                                 prune($config{destdir}."/".$file);
 392                         }
 393                 }
 394         }
 395
 396         if (@del) {
 397                 run_hooks(delete => sub { shift->(@del) });
 398         }
 399         if (%rendered) {
 400                 run_hooks(change => sub { shift->(keys %rendered) });
 401         }
 402 } #}}}
 403
 404 sub commandline_render () { #{{{
 405         loadplugins();
 406         checkconfig();
 407         lockwiki();
 408         loadindex();
 409         unlockwiki();
 410
 411         my $srcfile=possibly_foolish_untaint($config{render});
 412         my $file=$srcfile;
 413         $file=~s/\Q$config{srcdir}\E\/?//;
 414
 415         my $type=pagetype($file);
 416         die "ikiwiki: cannot render $srcfile\n" unless defined $type;
 417         my $content=readfile($srcfile);
 418         my $page=pagename($file);
 419         $pagesources{$page}=$file;
 420         $content=filter($page, $content);
 421         $content=preprocess($page, $page, $content);
 422         $content=linkify($page, $page, $content);
 423         $content=htmlize($page, $type, $content);
 424
 425         print genpage($page, $content, mtime($srcfile));
 426         exit 0;
 427 } #}}}
 428
 429 1