t/img.t

   1 #!/usr/bin/perl
   2 #
   3 # unit test that creates test images (png, svg, multi-page pdf), runs ikiwiki
   4 # on them, checks the resulting images for plausibility based on their image
   5 # sizes, and checks if they vanish when not required in the build process any
   6 # more
   7 #
   8 # if you have trouble here, be aware that there are three debian packages that
   9 # can provide Image::Magick: perlmagick, libimage-magick-perl and
  10 # graphicsmagick-libmagick-dev-compat
  11 #
  12 package IkiWiki;
  13
  14 use warnings;
  15 use strict;
  16 use Test::More;
  17
  18 BEGIN { use_ok("IkiWiki"); }
  19 BEGIN { use_ok("Image::Magick"); }
  20
  21 my $installed = $ENV{INSTALLED_TESTS};
  22
  23 my @command;
  24 if ($installed) {
  25         @command = qw(ikiwiki);
  26 }
  27 else {
  28         ok(! system("make -s ikiwiki.out"));
  29         @command = qw(perl -I. ./ikiwiki.out
  30                 --underlaydir=underlays/basewiki
  31                 --set underlaydirbase=underlays
  32                 --templatedir=templates);
  33 }
  34
  35 push @command, qw(--set usedirs=0 --plugin img t/tmp/in t/tmp/out --verbose);
  36
  37 my $magick = new Image::Magick;
  38 my $SVGS_WORK = defined $magick->QueryFormat("svg");
  39
  40 $magick->Read("t/img/twopages.pdf");
  41 my $PDFS_WORK = defined $magick->Get("width");
  42
  43 ok(! system("rm -rf t/tmp; mkdir -p t/tmp/in"));
  44
  45 ok(! system("cp t/img/redsquare.png t/tmp/in/redsquare.png"));
  46 ok(! system("cp t/img/redsquare.jpg t/tmp/in/redsquare.jpg"));
  47 ok(! system("cp t/img/redsquare.jpg t/tmp/in/redsquare.jpeg"));
  48 # colons in filenames are a corner case for img
  49 ok(! system("cp t/img/redsquare.png t/tmp/in/hello:world.png"));
  50 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c.png"));
  51 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c:d.png"));
  52 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c:d:e:f:g:h:i:j.png"));
  53
  54 writefile("bluesquare.svg", "t/tmp/in",
  55         '<svg width="30" height="30"><rect x="0" y="0" width="30" height="30" fill="blue"/></svg>');
  56 ok(! system("cp t/tmp/in/bluesquare.svg t/tmp/in/really-svg.png"));
  57 ok(! system("cp t/tmp/in/bluesquare.svg t/tmp/in/really-svg.bmp"));
  58 ok(! system("cp t/tmp/in/bluesquare.svg t/tmp/in/really-svg.pdf"));
  59
  60 # using different image sizes for different pages, so the pagenumber selection can be tested easily
  61 ok(! system("cp t/img/twopages.pdf t/tmp/in/twopages.pdf"));
  62 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.jpeg"));
  63 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.jpg"));
  64 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.png"));
  65 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.svg"));
  66
  67 my $maybe_svg_img = "";
  68 if ($SVGS_WORK) {
  69         $maybe_svg_img = "[[!img bluesquare.svg size=10x]]";
  70 }
  71
  72 my $maybe_pdf_img = "";
  73 if ($PDFS_WORK) {
  74         $maybe_pdf_img = <<EOF;
  75 [[!img twopages.pdf size=12x]]
  76 [[!img twopages.pdf size=16x pagenumber=1]]
  77 EOF
  78 }
  79
  80 writefile("imgconversions.mdwn", "t/tmp/in", <<EOF
  81 [[!img redsquare.png]]
  82 [[!img redsquare.jpg size=11x]]
  83 [[!img redsquare.jpeg size=12x]]
  84 [[!img redsquare.png size=10x]]
  85 [[!img redsquare.png size=30x50]] expecting 30x30
  86 [[!img hello:world.png size=x8]] expecting 8x8
  87 [[!img a:b:c.png size=x4]]
  88 [[!img a:b:c:d:e:f:g:h:i:j.png size=x6]]
  89 $maybe_svg_img
  90 $maybe_pdf_img
  91
  92 # bad ideas
  93 [[!img really-svg.png size=666x]]
  94 [[!img really-svg.bmp size=666x]]
  95 [[!img really-svg.pdf size=666x]]
  96 [[!img really-pdf.jpeg size=666x]]
  97 [[!img really-pdf.jpg size=666x]]
  98 [[!img really-pdf.png size=666x]]
  99 [[!img really-pdf.svg size=666x]]
 100 EOF
 101 );
 102 ok(utime(333333333, 333333333, "t/tmp/in/imgconversions.mdwn"));
 103
 104 ok(! system(@command, '--set-yaml', 'img_allowed_formats=[jpeg, png, svg, pdf]'));
 105
 106 sub size($) {
 107         my $filename = shift;
 108         my $im = Image::Magick->new();
 109         my $r = $im->Read(":$filename");
 110         return "no image" if $r;
 111         my $w = $im->Get("width");
 112         my $h = $im->Get("height");
 113         return "${w}x${h}";
 114 }
 115
 116 my $outpath = "t/tmp/out/imgconversions";
 117 my $outhtml = readfile("$outpath.html");
 118
 119 is(size("$outpath/10x-redsquare.png"), "10x10");
 120 ok(! -e "$outpath/30x-redsquare.png");
 121 ok($outhtml =~ /width="30" height="30".*expecting 30x30/);
 122
 123 SKIP: {
 124         skip "SVG support not installed (try libmagickcore-extra)", 1
 125                 unless $SVGS_WORK;
 126         # if this fails, you need libmagickcore-6.q16-2-extra installed
 127         is(size("$outpath/10x-bluesquare.png"), "10x10");
 128 }
 129
 130 SKIP: {
 131         skip "PDF support not installed (try ghostscript)", 2
 132                 unless $PDFS_WORK;
 133         is(size("$outpath/12x-twopages.png"), "12x12");
 134         is(size("$outpath/16x-p1-twopages.png"), "16x2");
 135 }
 136
 137 ok($outhtml =~ /width="8" height="8".*expecting 8x8/);
 138 is(size("$outpath/x8-hello:world.png"), "8x8");
 139 is(size("$outpath/x4-a:b:c.png"), "4x4");
 140 is(size("$outpath/x6-a:b:c:d:e:f:g:h:i:j.png"), "6x6");
 141
 142 is(size("$outpath/11x-redsquare.jpg"), "11x11");
 143 is(size("$outpath/12x-redsquare.jpeg"), "12x12");
 144 like($outhtml, qr{src="(\./)?imgconversions/11x-redsquare\.jpg" width="11" height="11"});
 145 like($outhtml, qr{src="(\./)?imgconversions/12x-redsquare\.jpeg" width="12" height="12"});
 146
 147 # We do not misinterpret images
 148 ok(! -e "$outpath/666x-really-svg.png");
 149 ok(! -e "$outpath/666x-really-svg.bmp");
 150 ok(! -e "$outpath/666x-really-pdf.jpeg");
 151 ok(! -e "$outpath/666x-really-pdf.jpg");
 152 ok(! -e "$outpath/666x-really-pdf.png");
 153
 154 # disable support for uncommon formats and try again
 155 ok(! system(@command, "--rebuild"));
 156 ok(! -e "$outpath/10x-bluesquare.png");
 157 ok(! -e "$outpath/12x-twopages.png");
 158 ok(! -e "$outpath/16x-p1-twopages.png");
 159
 160 # now let's remove them again
 161
 162 if (1) { # for easier testing
 163         writefile("imgconversions.mdwn", "t/tmp/in", "nothing to see here");
 164
 165         ok(! system(@command, "--refresh"));
 166
 167         ok(! -e "$outpath/10x-redsquare.png");
 168         ok(! -e "$outpath/10x-bluesquare.png");
 169         ok(! -e "$outpath/12x-twopages.png");
 170         ok(! -e "$outpath/16x-p1-twopages.png");
 171         ok(! -e "$outpath/x8-hello:world.png");
 172         ok(! -e "$outpath/x4-a:b:c.png");
 173         ok(! -e "$outpath/x6-a:b:c:d:e:f:g:h:i:j.png");
 174
 175         # cleanup
 176         ok(! system("rm -rf t/tmp"));
 177 }
 178 done_testing;
 179
 180 1;