IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 2.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13
  14 sub import { #{{{
  15         hook(type => "getopt", id => "inline", call => \&getopt);
  16         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  17         hook(type => "sessioncgi", id => "skeleton", call => \&sessioncgi);
  18         hook(type => "preprocess", id => "inline",
  19                 call => \&IkiWiki::preprocess_inline);
  20         hook(type => "pagetemplate", id => "inline",
  21                 call => \&IkiWiki::pagetemplate_inline);
  22         # Hook to change to do pinging since it's called late.
  23         # This ensures each page only pings once and prevents slow
  24         # pings interrupting page builds.
  25         hook(type => "change", id => "inline",
  26                 call => \&IkiWiki::pingurl);
  27
  28 } # }}}
  29
  30 sub getopt () { #{{{
  31         eval q{use Getopt::Long};
  32         error($@) if $@;
  33         Getopt::Long::Configure('pass_through');
  34         GetOptions(
  35                 "rss!" => \$config{rss},
  36                 "atom!" => \$config{atom},
  37         );
  38 }
  39
  40 sub checkconfig () { #{{{
  41         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  42                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  43         }
  44         if ($config{rss}) {
  45                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  46         }
  47         if ($config{atom}) {
  48                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  49         }
  50 } #}}}
  51
  52 sub sessioncgi () { #{{{
  53         my $q=shift;
  54         my $session=shift;
  55
  56         if ($q->param('do') eq 'blog') {
  57                 my $page=decode_utf8($q->param('title'));
  58                 $page=~s/\///g; # no slashes in blog posts
  59                 # if the page already exists, munge it to be unique
  60                 my $from=$q->param('from');
  61                 my $add="";
  62                 while (exists $IkiWiki::pagecase{lc($from."/".IkiWiki::titlepage($page).$add)}) {
  63                         $add=1 unless length $add;
  64                         $add++;
  65                 }
  66                 $q->param('page', $page.$add);
  67                 # now go create the page
  68                 $q->param('do', 'create');
  69                 IkiWiki::cgi_editpage($q, $session);
  70                 exit;
  71         }
  72 }
  73
  74 # Back to ikiwiki namespace for the rest, this code is very much
  75 # internal to ikiwiki even though it's separated into a plugin.
  76 package IkiWiki;
  77
  78 my %toping;
  79 my %feedlinks;
  80
  81 sub yesno ($) { #{{{
  82         my $val=shift;
  83         return (defined $val && lc($val) eq "yes");
  84 } #}}}
  85
  86 sub preprocess_inline (@) { #{{{
  87         my %params=@_;
  88
  89         if (! exists $params{pages}) {
  90                 return "";
  91         }
  92         my $raw=yesno($params{raw});
  93         my $archive=yesno($params{archive});
  94         my $rss=($config{rss} && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
  95         my $atom=($config{atom} && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
  96         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
  97         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
  98         $feeds=0 if $params{preview};
  99         my $feedonly=yesno($params{feedonly});
 100         if (! exists $params{show} && ! $archive) {
 101                 $params{show}=10;
 102         }
 103         my $desc;
 104         if (exists $params{description}) {
 105                 $desc = $params{description}
 106         } else {
 107                 $desc = $config{wikiname};
 108         }
 109         my $actions=yesno($params{actions});
 110         if (exists $params{template}) {
 111                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 112         }
 113         else {
 114                 $params{template} = $archive ? "archivepage" : "inlinepage";
 115         }
 116
 117         my @list;
 118         foreach my $page (keys %pagesources) {
 119                 next if $page eq $params{page};
 120                 if (pagespec_match($page, $params{pages}, location => $params{page})) {
 121                         push @list, $page;
 122                 }
 123         }
 124
 125         if (exists $params{sort} && $params{sort} eq 'title') {
 126                 @list=sort @list;
 127         }
 128         elsif (exists $params{sort} && $params{sort} eq 'mtime') {
 129                 @list=sort { $pagemtime{$b} <=> $pagemtime{$a} } @list;
 130         }
 131         elsif (! exists $params{sort} || $params{sort} eq 'age') {
 132                 @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
 133         }
 134         else {
 135                 return sprintf(gettext("unknown sort type %s"), $params{sort});
 136         }
 137
 138         if (yesno($params{reverse})) {
 139                 @list=reverse(@list);
 140         }
 141
 142         if (exists $params{skip}) {
 143                 @list=@list[$params{skip} .. scalar @list - 1];
 144         }
 145
 146         if ($params{show} && @list > $params{show}) {
 147                 @list=@list[0..$params{show} - 1];
 148         }
 149
 150         add_depends($params{page}, $params{pages});
 151         # Explicitly add all currently displayed pages as dependencies, so
 152         # that if they are removed or otherwise changed, the inline will be
 153         # sure to be updated.
 154         add_depends($params{page}, join(" or ", @list));
 155
 156         my $feednum="";
 157
 158         my $feedid=join("\0", map { $_."\0".$params{$_} } sort keys %params);
 159         if (exists $knownfeeds{$feedid}) {
 160                 $feednum=$knownfeeds{$feedid};
 161         }
 162         else {
 163                 if (exists $page_numfeeds{$params{destpage}}) {
 164                         if ($feeds) {
 165                                 $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}};
 166                         }
 167                 }
 168                 else {
 169                         $feednum=$knownfeeds{$feedid}="";
 170                         if ($feeds) {
 171                                 $page_numfeeds{$params{destpage}}=1;
 172                         }
 173                 }
 174         }
 175
 176         my $rssurl=basename(rsspage($params{destpage}).$feednum);
 177         my $atomurl=basename(atompage($params{destpage}).$feednum);
 178         my $ret="";
 179
 180         if ($config{cgiurl} && (exists $params{rootpage} ||
 181                         (exists $params{postform} && yesno($params{postform})))) {
 182                 # Add a blog post form, with feed buttons.
 183                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 184                 $formtemplate->param(cgiurl => $config{cgiurl});
 185                 $formtemplate->param(rootpage =>
 186                         exists $params{rootpage} ? $params{rootpage} : $params{page});
 187                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 188                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 189                 if (exists $params{postformtext}) {
 190                         $formtemplate->param(postformtext =>
 191                                 $params{postformtext});
 192                 }
 193                 else {
 194                         $formtemplate->param(postformtext =>
 195                                 gettext("Add a new post titled:"));
 196                 }
 197                 $ret.=$formtemplate->output;
 198         }
 199         elsif ($feeds) {
 200                 # Add feed buttons.
 201                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 202                 $linktemplate->param(rssurl => $rssurl) if $rss;
 203                 $linktemplate->param(atomurl => $atomurl) if $atom;
 204                 $ret.=$linktemplate->output;
 205         }
 206
 207         if (! $feedonly) {
 208                 require HTML::Template;
 209                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 210                 if (! @params) {
 211                         return sprintf(gettext("nonexistant template %s"), $params{template});
 212                 }
 213                 my $template=HTML::Template->new(@params) unless $raw;
 214
 215                 foreach my $page (@list) {
 216                         my $file = $pagesources{$page};
 217                         my $type = pagetype($file);
 218                         if (! $raw || ($raw && ! defined $type)) {
 219                                 unless ($archive && $quick) {
 220                                         # Get the content before populating the
 221                                         # template, since getting the content uses
 222                                         # the same template if inlines are nested.
 223                                         my $content=get_inline_content($page, $params{destpage});
 224                                         $template->param(content => $content);
 225                                 }
 226                                 $template->param(pageurl => urlto(bestlink($params{page}, $page), $params{destpage}));
 227                                 $template->param(title => pagetitle(basename($page)));
 228                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 229
 230                                 if ($actions) {
 231                                         my $file = $pagesources{$page};
 232                                         my $type = pagetype($file);
 233                                         if ($config{discussion}) {
 234                                                 my $discussionlink=gettext("discussion");
 235                                                 if ($page !~ /.*\/\Q$discussionlink\E$/ &&
 236                                                     (length $config{cgiurl} ||
 237                                                      exists $links{$page."/".$discussionlink})) {
 238                                                         $template->param(have_actions => 1);
 239                                                         $template->param(discussionlink =>
 240                                                                 htmllink($page,
 241                                                                         $params{destpage},
 242                                                                         gettext("Discussion"),
 243                                                                         noimageinline => 1,
 244                                                                         forcesubpage => 1));
 245                                                 }
 246                                         }
 247                                         if (length $config{cgiurl} && defined $type) {
 248                                                 $template->param(have_actions => 1);
 249                                                 $template->param(editurl => cgiurl(do => "edit", page => pagetitle($page, 1)));
 250                                         }
 251                                 }
 252
 253                                 run_hooks(pagetemplate => sub {
 254                                         shift->(page => $page, destpage => $params{destpage},
 255                                                 template => $template,);
 256                                 });
 257
 258                                 $ret.=$template->output;
 259                                 $template->clear_params;
 260                         }
 261                         else {
 262                                 if (defined $type) {
 263                                         $ret.="\n".
 264                                               linkify($page, $params{destpage},
 265                                               preprocess($page, $params{destpage},
 266                                               filter($page, $params{destpage},
 267                                               readfile(srcfile($file)))));
 268                                 }
 269                         }
 270                 }
 271         }
 272
 273         if ($feeds) {
 274                 if (exists $params{feedshow} && @list > $params{feedshow}) {
 275                         @list=@list[0..$params{feedshow} - 1];
 276                 }
 277                 if (exists $params{feedpages}) {
 278                         @list=grep { pagespec_match($_, $params{feedpages}, location => $params{page}) } @list;
 279                 }
 280
 281                 if ($rss) {
 282                         my $rssp=rsspage($params{destpage}).$feednum;
 283                         will_render($params{destpage}, $rssp);
 284                         writefile($rssp, $config{destdir},
 285                                 genfeed("rss", $rssurl, $desc, $params{destpage}, @list));
 286                         $toping{$params{destpage}}=1 unless $config{rebuild};
 287                         $feedlinks{$params{destpage}}=qq{<link rel="alternate" type="application/rss+xml" title="RSS" href="$rssurl" />};
 288                 }
 289                 if ($atom) {
 290                         my $atomp=atompage($params{destpage}).$feednum;
 291                         will_render($params{destpage}, $atomp);
 292                         writefile($atomp, $config{destdir},
 293                                 genfeed("atom", $atomurl, $desc, $params{destpage}, @list));
 294                         $toping{$params{destpage}}=1 unless $config{rebuild};
 295                         $feedlinks{$params{destpage}}=qq{<link rel="alternate" type="application/atom+xml" title="Atom" href="$atomurl" />};
 296                 }
 297         }
 298
 299         return $ret;
 300 } #}}}
 301
 302 sub pagetemplate_inline (@) { #{{{
 303         my %params=@_;
 304         my $page=$params{page};
 305         my $template=$params{template};
 306
 307         $template->param(feedlinks => $feedlinks{$page})
 308                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 309 } #}}}
 310
 311 sub get_inline_content ($$) { #{{{
 312         my $page=shift;
 313         my $destpage=shift;
 314
 315         my $file=$pagesources{$page};
 316         my $type=pagetype($file);
 317         if (defined $type) {
 318                 return htmlize($page, $type,
 319                        linkify($page, $destpage,
 320                        preprocess($page, $destpage,
 321                        filter($page, $destpage,
 322                        readfile(srcfile($file))))));
 323         }
 324         else {
 325                 return "";
 326         }
 327 } #}}}
 328
 329 sub date_822 ($) { #{{{
 330         my $time=shift;
 331
 332         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 333         POSIX::setlocale(&POSIX::LC_TIME, "C");
 334         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 335         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 336         return $ret;
 337 } #}}}
 338
 339 sub date_3339 ($) { #{{{
 340         my $time=shift;
 341
 342         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 343         POSIX::setlocale(&POSIX::LC_TIME, "C");
 344         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 345         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 346         return $ret;
 347 } #}}}
 348
 349 sub absolute_urls ($$) { #{{{
 350         # sucky sub because rss sucks
 351         my $content=shift;
 352         my $baseurl=shift;
 353
 354         my $url=$baseurl;
 355         $url=~s/[^\/]+$//;
 356
 357         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 358         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:\/\/)([^"]+)"/$1 href="$url$2"/mig;
 359         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:\/\/)([^"]+)"/$1 src="$url$2"/mig;
 360         return $content;
 361 } #}}}
 362
 363 sub rsspage ($) { #{{{
 364         return targetpage(shift, "rss");
 365 } #}}}
 366
 367 sub atompage ($) { #{{{
 368         return targetpage(shift, "atom");
 369 } #}}}
 370
 371 sub genfeed ($$$$@) { #{{{
 372         my $feedtype=shift;
 373         my $feedurl=shift;
 374         my $feeddesc=shift;
 375         my $page=shift;
 376         my @pages=@_;
 377
 378         my $url=URI->new(encode_utf8($config{url}."/".urlto($page,"")));
 379
 380         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 381         my $content="";
 382         my $lasttime = 0;
 383         foreach my $p (@pages) {
 384                 my $u=URI->new(encode_utf8($config{url}."/".urlto($p, "")));
 385                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 386
 387                 $itemtemplate->param(
 388                         title => pagetitle(basename($p)),
 389                         url => $u,
 390                         permalink => $u,
 391                         cdate_822 => date_822($pagectime{$p}),
 392                         mdate_822 => date_822($pagemtime{$p}),
 393                         cdate_3339 => date_3339($pagectime{$p}),
 394                         mdate_3339 => date_3339($pagemtime{$p}),
 395                 );
 396
 397                 if ($itemtemplate->query(name => "enclosure")) {
 398                         my $file=$pagesources{$p};
 399                         my $type=pagetype($file);
 400                         if (defined $type) {
 401                                 $itemtemplate->param(content => $pcontent);
 402                         }
 403                         else {
 404                                 my ($a, $b, $c, $d, $e, $f, $g, $size) = stat(srcfile($file));
 405                                 my $mime="unknown";
 406                                 eval q{use File::MimeInfo};
 407                                 if (! $@) {
 408                                         $mime = mimetype($file);
 409                                 }
 410                                 $itemtemplate->param(
 411                                         enclosure => $u,
 412                                         type => $mime,
 413                                         length => $size,
 414                                 );
 415                         }
 416                 }
 417                 else {
 418                         $itemtemplate->param(content => $pcontent);
 419                 }
 420
 421                 run_hooks(pagetemplate => sub {
 422                         shift->(page => $p, destpage => $page,
 423                                 template => $itemtemplate);
 424                 });
 425
 426                 $content.=$itemtemplate->output;
 427                 $itemtemplate->clear_params;
 428
 429                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 430         }
 431
 432         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 433         $template->param(
 434                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 435                 wikiname => $config{wikiname},
 436                 pageurl => $url,
 437                 content => $content,
 438                 feeddesc => $feeddesc,
 439                 feeddate => date_3339($lasttime),
 440                 feedurl => $feedurl,
 441                 version => $IkiWiki::version,
 442         );
 443         run_hooks(pagetemplate => sub {
 444                 shift->(page => $page, destpage => $page,
 445                         template => $template);
 446         });
 447
 448         return $template->output;
 449 } #}}}
 450
 451 sub pingurl (@) { #{{{
 452         return unless @{$config{pingurl}} && %toping;
 453
 454         eval q{require RPC::XML::Client};
 455         if ($@) {
 456                 debug(gettext("RPC::XML::Client not found, not pinging"));
 457                 return;
 458         }
 459
 460         # daemonize here so slow pings don't slow down wiki updates
 461         defined(my $pid = fork) or error("Can't fork: $!");
 462         return if $pid;
 463         chdir '/';
 464         setsid() or error("Can't start a new session: $!");
 465         open STDIN, '/dev/null';
 466         open STDOUT, '>/dev/null';
 467         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 468
 469         # Don't need to keep a lock on the wiki as a daemon.
 470         IkiWiki::unlockwiki();
 471
 472         foreach my $page (keys %toping) {
 473                 my $title=pagetitle(basename($page), 0);
 474                 my $url="$config{url}/".urlto($page, "");
 475                 foreach my $pingurl (@{$config{pingurl}}) {
 476                         debug("Pinging $pingurl for $page");
 477                         eval {
 478                                 my $client = RPC::XML::Client->new($pingurl);
 479                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 480                                         $title, $url);
 481                                 my $res = $client->send_request($req);
 482                                 if (! ref $res) {
 483                                         debug("Did not receive response to ping");
 484                                 }
 485                                 my $r=$res->value;
 486                                 if (! exists $r->{flerror} || $r->{flerror}) {
 487                                         debug("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 488                                 }
 489                         };
 490                         if ($@) {
 491                                 debug "Ping failed: $@";
 492                         }
 493                 }
 494         }
 495
 496         exit 0; # daemon done
 497 } #}}}
 498
 499 1