IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub showform ($$$$) { #{{{
  25         my $form=shift;
  26         my $buttons=shift;
  27         my $session=shift;
  28         my $cgi=shift;
  29
  30         if (exists $hooks{formbuilder}) {
  31                 run_hooks(formbuilder => sub {
  32                         shift->(form => $form, cgi => $cgi, session => $session,
  33                                 buttons => $buttons);
  34                 });
  35         }
  36
  37         printheader($session);
  38         print misctemplate($form->title, $form->render(submit => $buttons));
  39 }
  40
  41 sub redirect ($$) { #{{{
  42         my $q=shift;
  43         my $url=shift;
  44         if (! $config{w3mmode}) {
  45                 print $q->redirect($url);
  46         }
  47         else {
  48                 print "Content-type: text/plain\n";
  49                 print "W3m-control: GOTO $url\n\n";
  50         }
  51 } #}}}
  52
  53 sub check_canedit ($$$;$) { #{{{
  54         my $page=shift;
  55         my $q=shift;
  56         my $session=shift;
  57         my $nonfatal=shift;
  58
  59         my $canedit;
  60         run_hooks(canedit => sub {
  61                 return if defined $canedit;
  62                 my $ret=shift->($page, $q, $session);
  63                 if (defined $ret && $ret eq "") {
  64                         $canedit=1;
  65                 }
  66                 elsif (defined $ret) {
  67                         $canedit=0;
  68                         error($ret) unless $nonfatal;
  69                 }
  70         });
  71         return $canedit;
  72 } #}}}
  73
  74 sub decode_form_utf8 ($) { #{{{
  75         my $form = shift;
  76         foreach my $f ($form->field) {
  77                 next if Encode::is_utf8(scalar $form->field($f));
  78                 $form->field(name  => $f,
  79                              value => decode_utf8($form->field($f)),
  80                              force => 1,
  81                             );
  82         }
  83 } #}}}
  84
  85 sub cgi_recentchanges ($) { #{{{
  86         my $q=shift;
  87
  88         # Optimisation: building recentchanges means calculating lots of
  89         # links. Memoizing htmllink speeds it up a lot (can't be memoized
  90         # during page builds as the return values may change, but they
  91         # won't here.)
  92         eval q{use Memoize};
  93         error($@) if $@;
  94         memoize("htmllink");
  95
  96         eval q{use Time::Duration};
  97         error($@) if $@;
  98
  99         my $changelog=[rcs_recentchanges(100)];
 100         foreach my $change (@$changelog) {
 101                 $change->{when} = concise(ago($change->{when}));
 102
 103                 $change->{user} = userlink($change->{user});
 104
 105                 my $is_excess = exists $change->{pages}[10]; # limit pages to first 10
 106                 delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
 107                 $change->{pages} = [
 108                         map {
 109                                 $_->{link} = htmllink("", "", $_->{page},
 110                                         noimageinline => 1,
 111                                         linktext => pagetitle($_->{page}));
 112                                 $_;
 113                         } @{$change->{pages}}
 114                 ];
 115                 push @{$change->{pages}}, { link => '...' } if $is_excess;
 116         }
 117
 118         my $template=template("recentchanges.tmpl");
 119         $template->param(
 120                 title => "RecentChanges",
 121                 indexlink => indexlink(),
 122                 wikiname => $config{wikiname},
 123                 changelog => $changelog,
 124                 baseurl => baseurl(),
 125         );
 126         run_hooks(pagetemplate => sub {
 127                 shift->(page => "", destpage => "", template => $template);
 128         });
 129         print $q->header(-charset => 'utf-8'), $template->output;
 130 } #}}}
 131
 132 # Check if the user is signed in. If not, redirect to the signin form and
 133 # save their place to return to later.
 134 sub needsignin ($$) { #{{{
 135         my $q=shift;
 136         my $session=shift;
 137
 138         if (! defined $session->param("name") ||
 139             ! userinfo_get($session->param("name"), "regdate")) {
 140                 if (! defined $session->param("postsignin")) {
 141                         $session->param(postsignin => $ENV{QUERY_STRING});
 142                 }
 143                 cgi_signin($q, $session);
 144                 cgi_savesession($session);
 145                 exit;
 146         }
 147 } #}}}
 148
 149 sub cgi_signin ($$) { #{{{
 150         my $q=shift;
 151         my $session=shift;
 152
 153         eval q{use CGI::FormBuilder};
 154         error($@) if $@;
 155         my $form = CGI::FormBuilder->new(
 156                 title => "signin",
 157                 name => "signin",
 158                 charset => "utf-8",
 159                 method => 'POST',
 160                 required => 'NONE',
 161                 javascript => 0,
 162                 params => $q,
 163                 action => $config{cgiurl},
 164                 header => 0,
 165                 template => {type => 'div'},
 166                 stylesheet => baseurl()."style.css",
 167         );
 168         my $buttons=["Login"];
 169
 170         if ($q->param("do") ne "signin" && !$form->submitted) {
 171                 $form->text(gettext("You need to log in first."));
 172         }
 173         $form->field(name => "do", type => "hidden", value => "signin",
 174                 force => 1);
 175
 176         decode_form_utf8($form);
 177
 178         run_hooks(formbuilder_setup => sub {
 179                 shift->(form => $form, cgi => $q, session => $session,
 180                         buttons => $buttons);
 181         });
 182
 183         if ($form->submitted) {
 184                 $form->validate;
 185         }
 186
 187         showform($form, $buttons, $session, $q);
 188 } #}}}
 189
 190 sub cgi_postsignin ($$) { #{{{
 191         my $q=shift;
 192         my $session=shift;
 193
 194         # Continue with whatever was being done before the signin process.
 195         if (defined $session->param("postsignin")) {
 196                 my $postsignin=CGI->new($session->param("postsignin"));
 197                 $session->clear("postsignin");
 198                 cgi($postsignin, $session);
 199                 cgi_savesession($session);
 200                 exit;
 201         }
 202         else {
 203                 # This can occur, for example, if a user went to the signin
 204                 # url via a bookmark.
 205                 redirect($q, $config{url});
 206         }
 207 } #}}}
 208
 209 sub cgi_prefs ($$) { #{{{
 210         my $q=shift;
 211         my $session=shift;
 212
 213         needsignin($q, $session);
 214
 215         eval q{use CGI::FormBuilder};
 216         error($@) if $@;
 217         my $form = CGI::FormBuilder->new(
 218                 title => "preferences",
 219                 name => "preferences",
 220                 header => 0,
 221                 charset => "utf-8",
 222                 method => 'POST',
 223                 validate => {
 224                         email => 'EMAIL',
 225                 },
 226                 required => 'NONE',
 227                 javascript => 0,
 228                 params => $q,
 229                 action => $config{cgiurl},
 230                 template => {type => 'div'},
 231                 stylesheet => baseurl()."style.css",
 232                 fieldsets => [
 233                         [login => gettext("Login")],
 234                         [preferences => gettext("Preferences")],
 235                         [admin => gettext("Admin")]
 236                 ],
 237         );
 238         my $buttons=["Save Preferences", "Logout", "Cancel"];
 239
 240         decode_form_utf8($form);
 241
 242         run_hooks(formbuilder_setup => sub {
 243                 shift->(form => $form, cgi => $q, session => $session,
 244                         buttons => $buttons);
 245         });
 246
 247         $form->field(name => "do", type => "hidden");
 248         $form->field(name => "email", size => 50, fieldset => "preferences");
 249         $form->field(name => "subscriptions", size => 50,
 250                 fieldset => "preferences",
 251                 comment => "(".htmllink("", "", "ikiwiki/PageSpec", noimageinline => 1).")");
 252         $form->field(name => "banned_users", size => 50,
 253                 fieldset => "admin");
 254
 255         my $user_name=$session->param("name");
 256         if (! is_admin($user_name)) {
 257                 $form->field(name => "banned_users", type => "hidden");
 258         }
 259
 260         if (! $form->submitted) {
 261                 $form->field(name => "email", force => 1,
 262                         value => userinfo_get($user_name, "email"));
 263                 $form->field(name => "subscriptions", force => 1,
 264                         value => userinfo_get($user_name, "subscriptions"));
 265                 if (is_admin($user_name)) {
 266                         $form->field(name => "banned_users", force => 1,
 267                                 value => join(" ", get_banned_users()));
 268                 }
 269         }
 270
 271         if ($form->submitted eq 'Logout') {
 272                 $session->delete();
 273                 redirect($q, $config{url});
 274                 return;
 275         }
 276         elsif ($form->submitted eq 'Cancel') {
 277                 redirect($q, $config{url});
 278                 return;
 279         }
 280         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 281                 foreach my $field (qw(email subscriptions)) {
 282                         if (defined $form->field($field) && length $form->field($field)) {
 283                                 userinfo_set($user_name, $field, $form->field($field)) ||
 284                                         error("failed to set $field");
 285                         }
 286                 }
 287                 if (is_admin($user_name)) {
 288                         set_banned_users(grep { ! is_admin($_) }
 289                                         split(' ',
 290                                                 $form->field("banned_users"))) ||
 291                                 error("failed saving changes");
 292                 }
 293                 $form->text(gettext("Preferences saved."));
 294         }
 295
 296         showform($form, $buttons, $session, $q);
 297 } #}}}
 298
 299 sub cgi_editpage ($$) { #{{{
 300         my $q=shift;
 301         my $session=shift;
 302
 303         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 304         my @buttons=("Save Page", "Preview", "Cancel");
 305
 306         eval q{use CGI::FormBuilder};
 307         error($@) if $@;
 308         my $form = CGI::FormBuilder->new(
 309                 title => "editpage",
 310                 fields => \@fields,
 311                 charset => "utf-8",
 312                 method => 'POST',
 313                 validate => {
 314                         editcontent => '/.+/',
 315                 },
 316                 required => [qw{editcontent}],
 317                 javascript => 0,
 318                 params => $q,
 319                 action => $config{cgiurl},
 320                 header => 0,
 321                 table => 0,
 322                 template => scalar template_params("editpage.tmpl"),
 323                 wikiname => $config{wikiname},
 324         );
 325
 326         decode_form_utf8($form);
 327
 328         run_hooks(formbuilder_setup => sub {
 329                 shift->(form => $form, cgi => $q, session => $session,
 330                         buttons => \@buttons);
 331         });
 332
 333         # This untaint is safe because titlepage removes any problematic
 334         # characters.
 335         my ($page)=$form->field('page');
 336         $page=titlepage(possibly_foolish_untaint($page));
 337         if (! defined $page || ! length $page ||
 338             file_pruned($page, $config{srcdir}) || $page=~/^\//) {
 339                 error("bad page name");
 340         }
 341
 342         my $from;
 343         if (defined $form->field('from')) {
 344                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 345         }
 346
 347         my $file;
 348         my $type;
 349         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 350                 $file=$pagesources{$page};
 351                 $type=pagetype($file);
 352                 if (! defined $type) {
 353                         error(sprintf(gettext("%s is not an editable page"), $page));
 354                 }
 355                 if (! $form->submitted) {
 356                         $form->field(name => "rcsinfo",
 357                                 value => rcs_prepedit($file), force => 1);
 358                 }
 359         }
 360         else {
 361                 $type=$form->param('type');
 362                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 363                         $type=possibly_foolish_untaint($type);
 364                 }
 365                 elsif (defined $from) {
 366                         # favor the type of linking page
 367                         $type=pagetype($pagesources{$from});
 368                 }
 369                 $type=$config{default_pageext} unless defined $type;
 370                 $file=$page.".".$type;
 371                 if (! $form->submitted) {
 372                         $form->field(name => "rcsinfo", value => "", force => 1);
 373                 }
 374         }
 375
 376         $form->field(name => "do", type => 'hidden');
 377         $form->field(name => "from", type => 'hidden');
 378         $form->field(name => "rcsinfo", type => 'hidden');
 379         $form->field(name => "subpage", type => 'hidden');
 380         $form->field(name => "page", value => pagetitle($page, 1), force => 1);
 381         $form->field(name => "type", value => $type, force => 1);
 382         $form->field(name => "comments", type => "text", size => 80);
 383         $form->field(name => "editcontent", type => "textarea", rows => 20,
 384                 cols => 80);
 385         $form->tmpl_param("can_commit", $config{rcs});
 386         $form->tmpl_param("indexlink", indexlink());
 387         $form->tmpl_param("helponformattinglink",
 388                 htmllink("", "", "ikiwiki/formatting",
 389                         noimageinline => 1,
 390                         linktext => "FormattingHelp"));
 391         $form->tmpl_param("baseurl", baseurl());
 392
 393         if ($form->submitted eq "Cancel") {
 394                 if ($form->field("do") eq "create" && defined $from) {
 395                         redirect($q, "$config{url}/".htmlpage($from));
 396                 }
 397                 elsif ($form->field("do") eq "create") {
 398                         redirect($q, $config{url});
 399                 }
 400                 else {
 401                         redirect($q, "$config{url}/".htmlpage($page));
 402                 }
 403                 return;
 404         }
 405         elsif ($form->submitted eq "Preview") {
 406                 my $content=$form->field('editcontent');
 407                 run_hooks(editcontent => sub {
 408                         $content=shift->(
 409                                 content => $content,
 410                                 page => $page,
 411                                 cgi => $q,
 412                                 session => $session,
 413                         );
 414                 });
 415                 $form->tmpl_param("page_preview",
 416                         htmlize($page, $type,
 417                         linkify($page, "",
 418                         preprocess($page, $page,
 419                         filter($page, $page, $content), 0, 1))));
 420         }
 421         elsif ($form->submitted eq "Save Page") {
 422                 $form->tmpl_param("page_preview", "");
 423         }
 424         $form->tmpl_param("page_conflict", "");
 425
 426         if ($form->submitted ne "Save Page" || ! $form->validate) {
 427                 if ($form->field("do") eq "create") {
 428                         my @page_locs;
 429                         my $best_loc;
 430                         if (! defined $from || ! length $from ||
 431                             $from ne $form->field('from') ||
 432                             file_pruned($from, $config{srcdir}) ||
 433                             $from=~/^\// ||
 434                             $form->submitted eq "Preview") {
 435                                 @page_locs=$best_loc=$page;
 436                         }
 437                         else {
 438                                 my $dir=$from."/";
 439                                 $dir=~s![^/]+/+$!!;
 440
 441                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 442                                     $page eq gettext('discussion')) {
 443                                         $best_loc="$from/$page";
 444                                 }
 445                                 else {
 446                                         $best_loc=$dir.$page;
 447                                 }
 448
 449                                 push @page_locs, $dir.$page;
 450                                 push @page_locs, "$from/$page";
 451                                 while (length $dir) {
 452                                         $dir=~s![^/]+/+$!!;
 453                                         push @page_locs, $dir.$page;
 454                                 }
 455                         }
 456                         push @page_locs, "$config{userdir}/$page"
 457                                 if length $config{userdir};
 458
 459                         @page_locs = grep {
 460                                 ! exists $pagecase{lc $_}
 461                         } @page_locs;
 462                         if (! @page_locs) {
 463                                 # hmm, someone else made the page in the
 464                                 # meantime?
 465                                 redirect($q, "$config{url}/".htmlpage($page));
 466                                 return;
 467                         }
 468
 469                         my @editable_locs = grep {
 470                                 check_canedit($_, $q, $session, 1)
 471                         } @page_locs;
 472                         if (! @editable_locs) {
 473                                 # let it throw an error this time
 474                                 map { check_canedit($_, $q, $session) } @page_locs;
 475                         }
 476
 477                         my @page_types;
 478                         if (exists $hooks{htmlize}) {
 479                                 @page_types=keys %{$hooks{htmlize}};
 480                         }
 481
 482                         $form->tmpl_param("page_select", 1);
 483                         $form->field(name => "page", type => 'select',
 484                                 options => [ map { pagetitle($_, 1) } @editable_locs ],
 485                                 value => pagetitle($best_loc, 1));
 486                         $form->field(name => "type", type => 'select',
 487                                 options => \@page_types);
 488                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 489
 490                 }
 491                 elsif ($form->field("do") eq "edit") {
 492                         check_canedit($page, $q, $session);
 493                         if (! defined $form->field('editcontent') ||
 494                             ! length $form->field('editcontent')) {
 495                                 my $content="";
 496                                 if (exists $pagesources{$page}) {
 497                                         $content=readfile(srcfile($pagesources{$page}));
 498                                         $content=~s/\n/\r\n/g;
 499                                 }
 500                                 $form->field(name => "editcontent", value => $content,
 501                                         force => 1);
 502                         }
 503                         $form->tmpl_param("page_select", 0);
 504                         $form->field(name => "page", type => 'hidden');
 505                         $form->field(name => "type", type => 'hidden');
 506                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 507                 }
 508
 509                 showform($form, \@buttons, $session, $q);
 510                 saveindex();
 511         }
 512         else {
 513                 # save page
 514                 check_canedit($page, $q, $session);
 515
 516                 my $exists=-e "$config{srcdir}/$file";
 517
 518                 if ($form->field("do") ne "create" && ! $exists &&
 519                     ! eval { srcfile($file) }) {
 520                         $form->tmpl_param("page_gone", 1);
 521                         $form->field(name => "do", value => "create", force => 1);
 522                         $form->tmpl_param("page_select", 0);
 523                         $form->field(name => "page", type => 'hidden');
 524                         $form->field(name => "type", type => 'hidden');
 525                         $form->title(sprintf(gettext("editing %s"), $page));
 526                         showform($form, \@buttons, $session, $q);
 527                         return;
 528                 }
 529                 elsif ($form->field("do") eq "create" && $exists) {
 530                         $form->tmpl_param("creation_conflict", 1);
 531                         $form->field(name => "do", value => "edit", force => 1);
 532                         $form->tmpl_param("page_select", 0);
 533                         $form->field(name => "page", type => 'hidden');
 534                         $form->field(name => "type", type => 'hidden');
 535                         $form->title(sprintf(gettext("editing %s"), $page));
 536                         $form->field("editcontent",
 537                                 value => readfile("$config{srcdir}/$file").
 538                                          "\n\n\n".$form->field("editcontent"),
 539                                 force => 1);
 540                         showform($form, \@buttons, $session, $q);
 541                         return;
 542                 }
 543
 544                 my $content=$form->field('editcontent');
 545                 run_hooks(editcontent => sub {
 546                         $content=shift->(
 547                                 content => $content,
 548                                 page => $page,
 549                                 cgi => $q,
 550                                 session => $session,
 551                         );
 552                 });
 553                 $content=~s/\r\n/\n/g;
 554                 $content=~s/\r/\n/g;
 555                 $content.="\n" if $content !~ /\n$/;
 556
 557                 $config{cgi}=0; # avoid cgi error message
 558                 eval { writefile($file, $config{srcdir}, $content) };
 559                 $config{cgi}=1;
 560                 if ($@) {
 561                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 562                                 force => 1);
 563                         $form->tmpl_param("failed_save", 1);
 564                         $form->tmpl_param("error_message", $@);
 565                         $form->field("editcontent", value => $content, force => 1);
 566                         $form->tmpl_param("page_select", 0);
 567                         $form->field(name => "page", type => 'hidden');
 568                         $form->field(name => "type", type => 'hidden');
 569                         $form->title(sprintf(gettext("editing %s"), $page));
 570                         showform($form, \@buttons, $session, $q);
 571                         return;
 572                 }
 573
 574                 my $conflict;
 575                 if ($config{rcs}) {
 576                         my $message="";
 577                         if (defined $form->field('comments') &&
 578                             length $form->field('comments')) {
 579                                 $message=$form->field('comments');
 580                         }
 581
 582                         if (! $exists) {
 583                                 rcs_add($file);
 584                         }
 585
 586                         # Prevent deadlock with post-commit hook by
 587                         # signaling to it that it should not try to
 588                         # do anything (except send commit mails).
 589                         disable_commit_hook();
 590                         $conflict=rcs_commit($file, $message,
 591                                 $form->field("rcsinfo"),
 592                                 $session->param("name"), $ENV{REMOTE_ADDR});
 593                         enable_commit_hook();
 594                         rcs_update();
 595                 }
 596
 597                 # Refresh even if there was a conflict, since other changes
 598                 # may have been committed while the post-commit hook was
 599                 # disabled.
 600                 require IkiWiki::Render;
 601                 # Reload index, since the first time it's loaded is before
 602                 # the wiki is locked, and things may have changed in the
 603                 # meantime.
 604                 loadindex();
 605                 refresh();
 606                 saveindex();
 607
 608                 if (defined $conflict) {
 609                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 610                                 force => 1);
 611                         $form->tmpl_param("page_conflict", 1);
 612                         $form->field("editcontent", value => $conflict, force => 1);
 613                         $form->field("do", "edit", force => 1);
 614                         $form->tmpl_param("page_select", 0);
 615                         $form->field(name => "page", type => 'hidden');
 616                         $form->field(name => "type", type => 'hidden');
 617                         $form->title(sprintf(gettext("editing %s"), $page));
 618                         showform($form, \@buttons, $session, $q);
 619                         return;
 620                 }
 621                 else {
 622                         # The trailing question mark tries to avoid broken
 623                         # caches and get the most recent version of the page.
 624                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 625                 }
 626         }
 627 } #}}}
 628
 629 sub cgi_getsession ($) { #{{{
 630         my $q=shift;
 631
 632         eval q{use CGI::Session};
 633         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 634
 635         my $oldmask=umask(077);
 636         my $session = CGI::Session->new("driver:DB_File", $q,
 637                 { FileName => "$config{wikistatedir}/sessions.db" });
 638         umask($oldmask);
 639
 640         return $session;
 641 } #}}}
 642
 643 sub cgi_savesession ($) { #{{{
 644         my $session=shift;
 645
 646         # Force session flush with safe umask.
 647         my $oldmask=umask(077);
 648         $session->flush;
 649         umask($oldmask);
 650 } #}}}
 651
 652 sub cgi (;$$) { #{{{
 653         my $q=shift;
 654         my $session=shift;
 655
 656         if (! $q) {
 657                 eval q{use CGI};
 658                 error($@) if $@;
 659
 660                 $q=CGI->new;
 661
 662                 run_hooks(cgi => sub { shift->($q) });
 663         }
 664
 665         my $do=$q->param('do');
 666         if (! defined $do || ! length $do) {
 667                 my $error = $q->cgi_error;
 668                 if ($error) {
 669                         error("Request not processed: $error");
 670                 }
 671                 else {
 672                         error("\"do\" parameter missing");
 673                 }
 674         }
 675
 676         # Things that do not need a session.
 677         if ($do eq 'recentchanges') {
 678                 cgi_recentchanges($q);
 679                 return;
 680         }
 681
 682         # Need to lock the wiki before getting a session.
 683         lockwiki();
 684
 685         if (! $session) {
 686                 $session=cgi_getsession($q);
 687         }
 688
 689         # Auth hooks can sign a user in.
 690         if ($do ne 'signin' && ! defined $session->param("name")) {
 691                 run_hooks(auth => sub {
 692                         shift->($q, $session)
 693                 });
 694                 if (defined $session->param("name")) {
 695                         # Make sure whatever user was authed is in the
 696                         # userinfo db.
 697                         if (! userinfo_get($session->param("name"), "regdate")) {
 698                                 userinfo_setall($session->param("name"), {
 699                                         email => "",
 700                                         password => "",
 701                                         regdate => time,
 702                                 }) || error("failed adding user");
 703                         }
 704                 }
 705         }
 706
 707         if (defined $session->param("name") &&
 708             userinfo_get($session->param("name"), "banned")) {
 709                 print $q->header(-status => "403 Forbidden");
 710                 $session->delete();
 711                 print gettext("You are banned.");
 712                 cgi_savesession($session);
 713         }
 714
 715         run_hooks(sessioncgi => sub { shift->($q, $session) });
 716
 717         if ($do eq 'signin') {
 718                 cgi_signin($q, $session);
 719                 cgi_savesession($session);
 720         }
 721         elsif (defined $session->param("postsignin")) {
 722                 cgi_postsignin($q, $session);
 723         }
 724         elsif ($do eq 'prefs') {
 725                 cgi_prefs($q, $session);
 726         }
 727         elsif ($do eq 'create' || $do eq 'edit') {
 728                 cgi_editpage($q, $session);
 729         }
 730         elsif ($do eq 'postsignin') {
 731                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 732         }
 733         else {
 734                 error("unknown do parameter");
 735         }
 736 } #}}}
 737
 738 sub userlink ($) { #{{{
 739         my $user=shift;
 740
 741         eval q{use CGI 'escapeHTML'};
 742         error($@) if $@;
 743         if ($user =~ m!^https?://! &&
 744             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
 745                 # Munge user-urls, as used by eg, OpenID.
 746                 my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
 747                 my $display=$oid->display;
 748                 # Convert "user.somehost.com" to "user [somehost.com]".
 749                 if ($display !~ /\[/) {
 750                         $display=~s/^(.*?)\.([^.]+\.[a-z]+)$/$1 [$2]/;
 751                 }
 752                 # Convert "http://somehost.com/user" to "user [somehost.com]".
 753                 if ($display !~ /\[/) {
 754                         $display=~s/^https?:\/\/(.+)\/([^\/]+)$/$2 [$1]/;
 755                 }
 756                 $display=~s!^https?://!!; # make sure this is removed
 757                 return "<a href=\"$user\">".escapeHTML($display)."</a>";
 758         }
 759         else {
 760                 return htmllink("", "", escapeHTML(
 761                         length $config{userdir} ? $config{userdir}."/".$user : $user
 762                 ), noimageinline => 1);
 763         }
 764 } #}}}
 765
 766 1