IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use Cwd q{abs_path};
   6 use Data::Dumper;
   7
   8 package IkiWiki;
   9
  10 sub gen_wrapper () { #{{{
  11         $config{srcdir}=abs_path($config{srcdir});
  12         $config{destdir}=abs_path($config{destdir});
  13         my $this=abs_path($0);
  14         if (! -x $this) {
  15                 error("$this doesn't seem to be executable");
  16         }
  17
  18         if ($config{setup}) {
  19                 error("cannot create a wrapper that uses a setup file");
  20         }
  21         my $wrapper=possibly_foolish_untaint($config{wrapper});
  22         if (! defined $wrapper || ! length $wrapper) {
  23                 error("wrapper filename not specified");
  24         }
  25         delete $config{wrapper};
  26
  27         my @envsave;
  28         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  29                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  30                        HTTP_COOKIE} if $config{cgi};
  31         push @envsave, qw{REV} if $config{svn};
  32         my $envsave="";
  33         foreach my $var (@envsave) {
  34                 $envsave.=<<"EOF"
  35         if ((s=getenv("$var")))
  36                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
  37 EOF
  38         }
  39
  40         $Data::Dumper::Indent=0; # no newlines
  41         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  42         $configstring=~s/\\/\\\\/g;
  43         $configstring=~s/"/\\"/g;
  44
  45         open(OUT, ">$wrapper.c") || error("failed to write $wrapper.c: $!");;
  46         print OUT <<"EOF";
  47 /* A wrapper for ikiwiki, can be safely made suid. */
  48 #define _GNU_SOURCE
  49 #include <stdio.h>
  50 #include <unistd.h>
  51 #include <stdlib.h>
  52 #include <string.h>
  53
  54 extern char **environ;
  55
  56 int main (int argc, char **argv) {
  57         /* Sanitize environment. */
  58         char *s;
  59         char *newenviron[$#envsave+4];
  60         int i=0;
  61 $envsave
  62         newenviron[i++]="HOME=$ENV{HOME}";
  63         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
  64         newenviron[i]=NULL;
  65         environ=newenviron;
  66
  67         execl("$this", "$this", NULL);
  68         perror("failed to run $this");
  69         exit(1);
  70 }
  71 EOF
  72         close OUT;
  73         if (system("gcc", "$wrapper.c", "-o", $wrapper) != 0) {
  74                 error("failed to compile $wrapper.c");
  75         }
  76         unlink("$wrapper.c");
  77         if (defined $config{wrappermode} &&
  78             ! chmod(oct($config{wrappermode}), $wrapper)) {
  79                 error("chmod $wrapper: $!");
  80         }
  81         print "successfully generated $wrapper\n";
  82 } #}}}
  83
  84 1