IkiWiki/Rcs/svn.pm

   1 #!/usr/bin/perl
   2 # For subversion support.
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7
   8 package IkiWiki;
   9
  10 my $svn_webcommit=qr/^web commit by (\w+):?(.*)/;
  11
  12 sub svn_info ($$) { #{{{
  13         my $field=shift;
  14         my $file=shift;
  15
  16         my $info=`LANG=C svn info $file`;
  17         my ($ret)=$info=~/^$field: (.*)$/m;
  18         return $ret;
  19 } #}}}
  20
  21 sub rcs_update () { #{{{
  22         if (-d "$config{srcdir}/.svn") {
  23                 if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
  24                         warn("svn update failed\n");
  25                 }
  26         }
  27 } #}}}
  28
  29 sub rcs_prepedit ($) { #{{{
  30         # Prepares to edit a file under revision control. Returns a token
  31         # that must be passed into rcs_commit when the file is ready
  32         # for committing.
  33         # The file is relative to the srcdir.
  34         my $file=shift;
  35
  36         if (-d "$config{srcdir}/.svn") {
  37                 # For subversion, return the revision of the file when
  38                 # editing begins.
  39                 my $rev=svn_info("Revision", "$config{srcdir}/$file");
  40                 return defined $rev ? $rev : "";
  41         }
  42 } #}}}
  43
  44 sub rcs_commit ($$$) { #{{{
  45         # Tries to commit the page; returns undef on _success_ and
  46         # a version of the page with the rcs's conflict markers on failure.
  47         # The file is relative to the srcdir.
  48         my $file=shift;
  49         my $message=shift;
  50         my $rcstoken=shift;
  51
  52         if (-d "$config{srcdir}/.svn") {
  53                 # Check to see if the page has been changed by someone
  54                 # else since rcs_prepedit was called.
  55                 my ($oldrev)=$rcstoken=~/^([0-9]+)$/; # untaint
  56                 my $rev=svn_info("Revision", "$config{srcdir}/$file");
  57                 if (defined $rev && defined $oldrev && $rev != $oldrev) {
  58                         # Merge their changes into the file that we've
  59                         # changed.
  60                         chdir($config{srcdir}); # svn merge wants to be here
  61                         if (system("svn", "merge", "--quiet", "-r$oldrev:$rev",
  62                                    "$config{srcdir}/$file") != 0) {
  63                                 warn("svn merge -r$oldrev:$rev failed\n");
  64                         }
  65                 }
  66
  67                 if (system("svn", "commit", "--quiet",
  68                            "--encoding", "UTF-8", "-m",
  69                            possibly_foolish_untaint($message),
  70                            "$config{srcdir}") != 0) {
  71                         my $conflict=readfile("$config{srcdir}/$file");
  72                         if (system("svn", "revert", "--quiet", "$config{srcdir}/$file") != 0) {
  73                                 warn("svn revert failed\n");
  74                         }
  75                         return $conflict;
  76                 }
  77         }
  78         return undef # success
  79 } #}}}
  80
  81 sub rcs_add ($) { #{{{
  82         # filename is relative to the root of the srcdir
  83         my $file=shift;
  84
  85         if (-d "$config{srcdir}/.svn") {
  86                 my $parent=dirname($file);
  87                 while (! -d "$config{srcdir}/$parent/.svn") {
  88                         $file=$parent;
  89                         $parent=dirname($file);
  90                 }
  91
  92                 if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
  93                         warn("svn add failed\n");
  94                 }
  95         }
  96 } #}}}
  97
  98 sub rcs_recentchanges ($) { #{{{
  99         my $num=shift;
 100         my @ret;
 101
 102         return unless -d "$config{srcdir}/.svn";
 103
 104         eval q{use CGI 'escapeHTML'};
 105         eval q{use Date::Parse};
 106         eval q{use Time::Duration};
 107         eval q{use XML::Simple};
 108
 109         my $svn_url=svn_info("URL", $config{srcdir});
 110         my $xml = XMLin(scalar `svn --xml -v log '$svn_url'`,
 111                 ForceArray => [ 'logentry', 'path' ],
 112                 GroupTags => { paths => 'path' },
 113                 KeyAttr => { path => 'content' },
 114         );
 115         foreach my $logentry (@{$xml->{logentry}}) {
 116                 my (@pages, @message);
 117
 118                 my $rev = $logentry->{revision};
 119                 my $user = $logentry->{author};
 120
 121                 my $date = $logentry->{date};
 122                 $date =~ s/T/ /;
 123                 $date =~ s/\.\d+Z$//;
 124                 my $when=concise(ago(time - str2time($date, 'UTC')));
 125
 126                 foreach my $msgline (split(/\n/, $logentry->{msg})) {
 127                         push @message, { line => escapeHTML($msgline) };
 128                 }
 129                 unshift @message, { line => "\n" } if @message > 1;
 130
 131                 my $committype="web";
 132                 if (defined $message[0] &&
 133                     $message[0]->{line}=~/$svn_webcommit/) {
 134                         $user="$1";
 135                         $message[0]->{line}=$2;
 136                 }
 137                 else {
 138                         $committype="svn";
 139                 }
 140
 141                 foreach (keys %{$logentry->{paths}}) {
 142                         next unless /^\/\Q$config{svnpath}\E\/([^ ]+)(?:$|\s)/;
 143                         my $file=$1;
 144                         my $diffurl=$config{diffurl};
 145                         $diffurl=~s/\[\[file\]\]/$file/g;
 146                         $diffurl=~s/\[\[r1\]\]/$rev - 1/eg;
 147                         $diffurl=~s/\[\[r2\]\]/$rev/g;
 148                         push @pages, {
 149                                 link => htmllink("", "", pagename($file), 1),
 150                                 diffurl => $diffurl,
 151                         } if length $file;
 152                 }
 153                 push @ret, { rev => $rev,
 154                         user => htmllink("", "", $user, 1),
 155                         committype => $committype,
 156                         when => $when,
 157                         message => [@message],
 158                         pages => [@pages],
 159                 } if @pages;
 160                 return @ret if @ret >= $num;
 161         }
 162
 163         return @ret;
 164 } #}}}
 165
 166 sub rcs_notify () { #{{{
 167         if (! exists $ENV{REV}) {
 168                 error("REV is not set, not running from svn post-commit hook, cannot send notifications");
 169         }
 170         my $rev=int(possibly_foolish_untaint($ENV{REV}));
 171
 172         my $user=`svnlook author $config{svnrepo} -r $rev`;
 173         chomp $user;
 174         my $message=`svnlook log $config{svnrepo} -r $rev`;
 175         if ($message=~/$svn_webcommit/) {
 176                 $user="$1";
 177                 $message=$2;
 178         }
 179
 180         my @changed_pages;
 181         foreach my $change (`svnlook changed $config{svnrepo} -r $rev`) {
 182                 chomp $change;
 183                 if ($change =~ /^[A-Z]+\s+\Q$config{svnpath}\E\/(.*)/) {
 184                         push @changed_pages, $1;
 185                 }
 186         }
 187
 188         require IkiWiki::UserInfo;
 189         my @email_recipients=commit_notify_list($user, @changed_pages);
 190         if (@email_recipients) {
 191                 # TODO: if a commit spans multiple pages, this will send
 192                 # subscribers a diff that might contain pages they did not
 193                 # sign up for. Should separate the diff per page and
 194                 # reassemble into one mail with just the pages subscribed to.
 195                 my $diff=`svnlook diff $config{svnrepo} -r $rev --no-diff-deleted`;
 196
 197                 my $subject="$config{wikiname} update of ";
 198                 if (@changed_pages > 2) {
 199                         $subject.="$changed_pages[0] $changed_pages[1] etc";
 200                 }
 201                 else {
 202                         $subject.=join(" ", @changed_pages);
 203                 }
 204                 $subject.=" by $user";
 205
 206                 my $template=template("notifymail.tmpl");
 207                 $template->param(
 208                         wikiname => $config{wikiname},
 209                         diff => $diff,
 210                         user => $user,
 211                         message => $message,
 212                 );
 213
 214                 eval q{use Mail::Sendmail};
 215                 foreach my $email (@email_recipients) {
 216                         sendmail(
 217                                 To => $email,
 218                                 From => "$config{wikiname} <$config{adminemail}>",
 219                                 Subject => $subject,
 220                                 Message => $template->output,
 221                         ) or error("Failed to send update notification mail");
 222                 }
 223         }
 224 } #}}}
 225
 226 sub rcs_getctime ($) { #{{{
 227         my $file=shift;
 228         eval q{use Date::Parse};
 229
 230         my $svn_log_infoline=qr/^r\d+\s+\|\s+[^\s]+\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 231
 232         my $child = open(SVNLOG, "-|");
 233         if (! $child) {
 234                 exec("svn", "log", $file) || error("svn log $file failed to run");
 235         }
 236
 237         my $date;
 238         while (<SVNLOG>) {
 239                 if (/$svn_log_infoline/) {
 240                         $date=$1;
 241                 }
 242         }
 243         close SVNLOG || warn "svn log $file exited $?";
 244
 245         if (! defined $date) {
 246                 warn "failed to parse svn log for $file\n";
 247                 return 0;
 248         }
 249
 250         $date=str2time($date);
 251         debug("found ctime ".localtime($date)." for $file");
 252         return $date;
 253 } #}}}
 254
 255 1